Jouer un son toute les x secondes

**skysool** · 26/01/2020, 01h32

Bonjour tout le monde,

est-ce que quelqu'un aurait l'amabilité de me dire comment je peux faire pour faire boucler mon son toute les x secondes ?

Mon cas est le suivant :
J'ai programmer mon action de sorte à ce que si j'appuie sur la touche "V" de mon clavier cela fasse appel à une Case qui executera l'appel à un son.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
 
Case "jouerunson"
Call JouerSFX(index, "valid.wav")
Exit Sub

Probleme si je maintien la touche V le son se répete et joue à l'infini sans pause ni interval
Je souhaite que si je maintien la touche V, le son se répete mais toutes les x secondes.

Cela est possible ?
merci

**DAUDET78** · 26/01/2020, 09h50

Tu as le contrôle "Timer" pour faire ça
Controle TIMER VB6.pdf

**DAUDET78** · 26/01/2020, 11h10

Je ne sais pas si ça correspond à ton problème, mais voici une élucubration qui, tant que tu tapes des "v", émet un Beep toutes les 3 secondes. Si tu ne tapes pas de "v" pendant 10 secondes, les Beep s’arrêtent

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
Dim AttenteV%
Const ValAttenteV% = 10 ' sans touche "v" pendant 10 secondes, c'est terminé
Dim AttenteInterBeep%
Const ValAttenteInterBeep% = 3 ' 3 secondes entre Beep
Private Sub Form_KeyPress(KeyAscii As Integer)
If KeyAscii <> Asc("v") Then Exit Sub ' sans intéret
 
    Print Chr$(KeyAscii);
    AttenteV% = ValAttenteV%
    If Timer1.Enabled = False Then  ' on lance la séquence
        Timer1.Enabled = True
        AttenteInterBeep% = ValAttenteInterBeep%
        Beep ' on lance la séquence
    End If
End Sub
 
Private Sub Form_Load()
Timer1.Enabled = False
Timer1.Interval = 1000  ' une seconde pour le timer
Form1.KeyPreview = True
Form1.Caption = "taper un ""v"" pour faire des Beep"
End Sub
 
Private Sub Timer1_Timer()
' Gestion absence touche "v"
If AttenteV% > 0 Then
    AttenteV% = AttenteV% - 1
Else
    Timer1.Enabled = False: Exit Sub
End If
' Tempo entre Beep
If AttenteInterBeep% > 0 Then
    AttenteInterBeep% = AttenteInterBeep% - 1
Else
    AttenteInterBeep% = ValAttenteInterBeep%
    Beep
End If
End Sub

Tu crées une feuille Form1 , tu places un contrôle Timer1, tu copies le code et tu exécutes le programme
Tu tapes un ou plusieurs "v" ( pas des "V" !)