Discussion :

[pokypok]

Bien le bonjour à toutes et tous.

J'aimerai via une macro effacer certaines colonnes d'un tableau T_2
Il comporte 13 colonnes et je ne veux effacer que les colonnes de 3 à 13
En faisant l'enregistrement de macro, et en la remaniant j'ai obtenu ceci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Range("T_2[[#All],[Groupe 1]:[Groupe 10]]").ClearContents

Ca fonctionne très bien .

Maintenant j'aimerai que ce soit défini à partir de la colonne [Groupe 1] sur x colonnes (x étant un nombre que je vais chercher sur une autre feuille) et pas que jusqu'à le colonne [Groupe 10].

Voili merci

[Daniel.C]

Bonjour,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
 
  With ActiveSheet.ListObjects("T_2")
    .ListColumns("Groupe 1").Range.Resize(, [Feuil3!A1].Value).ClearContents
  End With

Avec le nombre de colonnes en A1, Feuille "Feuil3".

(efface aussi les entêtes, comme dans ton exemple).

[pokypok]

Salut Daniel déjà merci pour la réponse.

En revanche étant un débutant en herbes j'ai mis cela

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

ActiveSheet.ListObjects("T_2").ListColumns("Groupe 1").Range.Resize(, [data!F11].Value).ClearContents

il se passe rien ...
data étant le nom de la feuille où se trouve référencé le nombre qui m'intéresse

Petite question annexe pour manier des données dans un tableau c'est bien entre [] que l'on nomme la ligne ou colonne dans mon cas?

y a t il une autre manière de la spécifier cette colonne?

[Daniel.C]

Je viens de tester ton code et il fait bien le boulot. J'ai mis 3 en Data!F11; et toi ? Pour plus de sureté, remplace "ActiveSheet" par le nom de la feuille. Quant à la syntaxe, tu peux utiliser celle donnée par l'enregistreur de macros, mais celle que j'utilise est la syntaxe VBA qui est plus souple.
Avant macro :


Après exécution :

[pokypok]

En fait oui cela fonctionne (encore un probleme interface chaise bureau) ... désolé.

[pokypok]

Donc je résume jai 10 colonnes à effacer ok je passe mon tableau à 11 colonnes la macro efface bien les 11 colonnes.
Maintenant quand je repasse à 10 colonnes cela m'efface quand même ce qu'il y a dans la colonne suivante.
En soit ce n'est pas grave mais quand même ...

Et pour finir étant officellement un cass pieds qui aime comprendre ce qu 'il fait...
je n'ai pas tout saisi sur ta ligne de code. y a t il un moyen plus "lisible" de le faire ?

[Philippe Tulliez]

Bonjour,
Personnellement, j'utilise simplement l'appel à une fonction qui contient une boucle

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Function RemoveListColumns(oList As ListObject, LabelNames As Variant)
  ' Arguments
  '  oList      ' Objet table
  '  LabelNames ' Variable tableau contenant les étiquettes de colonnes à détruire
  Dim Elem As Integer
  For Elem = 0 To UBound(LabelNames)
    On Error Resume Next
    oList.ListColumns(LabelNames(Elem)).Delete
    On Error GoTo 0
  Next
End Function

Que l'on invoque comme ceci (dans l'exemple shtDb est le CodeName de la feuille)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Sub TestRemoveListColumns()
  Dim LabelToRemove()
  Dim objTable As ListObject
  Set objTable = shtDb.ListObjects(1)
  LabelToRemove = Array("Age", "ENFANTS", "LOGEMENT")
  '
  Application.ScreenUpdating = False
  RemoveListColumns objTable, LabelToRemove ' Supprime les colonnes
  objTable.Range.Columns.AutoFit            ' Réadapte la largeur des colonnes
  '
  Set objTable = Nothing
End Sub

[Daniel.C]

Donc je résume jai 10 colonnes à effacer ok je passe mon tableau à 11 colonnes la macro efface bien les 11 colonnes.
Maintenant quand je repasse à 10 colonnes cela m'efface quand même ce qu'il y a dans la colonne suivante.
En soit ce n'est pas grave mais quand même ...

Et pour finir étant officellement un cass pieds qui aime comprendre ce qu 'il fait...
je n'ai pas tout saisi sur ta ligne de code. y a t il un moyen plus "lisible" de le faire ?

Pour éviter de dépasser les limites du tableau :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
  Dim Var As Long
  With ActiveSheet.ListObjects("T_2")
    Var = Application.Min(.ListColumns.Count, [data!F11].Value)
    .ListColumns("Groupe 1").DataBodyRange.Resize(, Var).ClearContents
  End With

Pour comprendre : "ListObject" représente un tableau; "Listcolumn" représente une colonne de ce tableau. L'instruction "Resize" redimensionne l'object Range.

[Philippe Tulliez]

Bonjour,

Et pour finir étant officellement un cass pieds qui aime comprendre ce qu 'il fait...

Je te conseille la lecture de ce tutoriel de Pierre Fauconnier titré Excel: Les tables de données en VBA

[pokypok]

Daniel et Philippe merci beaucoup.

Il est vrai que j'ai des notions mais qu'il me manque les bases et bon nombres des explications sont souvent réellement hors de portée pour moi car je n'ai que des bribes.

Le dernier lien sur le tuto va bien m'aider.

Très bonne fin de journée à vous et encore merci.

[Philippe Tulliez]

Bonjour,
J'ai vu en relisant les fils de cette discussion que finalement c'est le contenu des colonnes et non la totalité de celle-ci qu'il fallait effacer.
J'ai donc modifier la fonction en y a joutant un argument facultatif nommé IsDataOnly qui permet si sa valeur est à True de n'effacer que le contenu False ou omis efface la colonne entière.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Function RemoveListColumns(oList As ListObject, LabelNames As Variant, Optional IsDataOnly As Boolean) As Boolean
  ' Arguments
  '  oList        - Objet table
  '  LabelNames   - Variable tableau contenant les étiquettes de colonnes à supprimer
  '  [IsDataOnly] - True si l'on souhaite ne supprimer que les données de la colonne
  Dim Elem As Integer
  For Elem = 0 To UBound(LabelNames)
    On Error Resume Next
    With oList
      If IsDataOnly Then
         ' Suppression des données de la colonne
        .ListColumns(LabelNames(Elem)).DataBodyRange.ClearContents
       Else
         ' Suppresssion de la colonne complètes
        .ListColumns(LabelNames(Elem)).Delete
      End If
    End With
    On Error GoTo 0
  Next
End Function

Pour l'invoquer, (ligne 8 de la procédure TestRemoveListColumns publiée dans le Fil#7

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

RemoveListColumns oList:=objTable, LabelNames:=LabelToRemove, IsDataOnly:=True ' Supprime les colonnes

[dregniez]

Bonjour,
J'ai suivi votre publication mais j'ai une demande différente et j'ai essayé plusieurs façon mais sans résultat
Je vous explique: J'ai un tableau sur une feuille qui contient plus de 900 lignes et une 15ème de colonnes
J'ai réalisé un VBA avec un Userform avec une combobox qui permet de selectionner un nom dans la colonne 1, une fois le choix validé,
cela crée une nouvelle feuille, avec un tableau, qui normalement ne devrai contenir que les lignes ayant le nom sélectionné et qui en plus devrait n'avoir que quelques colonnes



J'ai mis 2 captures une avec l'extrait du tableau complet et l'autre le résultat escompté

Si vous pouvez m'aider je vous serai bien reconnaissant