Discussion :

[paule1997]

Bonsoir ma procédure compile mais ne produit rien comme résultat.

Il s'afit de creer une procédure qui ouvre un compte bancaire : OuvrirCompte(NumCli in number, Montant in number) Cette procédure crée un nouveau compte pour un client (NumCli) avec un premier solde (Montant) : -NumCompte est attribué automatiquement par une séquence ; -DateOuverture est la date système ; -Montant > 0 ; -PMVR est initialisée à 0 ; -Si le client n’existe pas, il y a erreur.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
CREATE OR REPLACE PROCEDURE OuvrirCompte(NumCli IN NUMBER, Montant in NUMBER)
IS
   	client_inexistant  EXCEPTION;
   PRAGMA EXCEPTION_INIT (	client_inexistant, -2291);
BEGIN
   IF (Montant < 0)
   THEN
      RAISE_APPLICATION_ERROR (-20002, 'the amount must be greater than 0');
   ELSE
      INSERT INTO Compte (NumCompte,
                           NumClient,
                           DateOuverture,
                           Solde,
                           PMVR)
           VALUES (seqCompte.NEXTVAL,
                   NumCli,
                   TO_DATE (sysdate, 'DD.MM.YY'),
                   Montant,
                   0);
   END IF;
EXCEPTION
   WHEN 
   	client_inexistant
   THEN
      DBMS_OUTPUT.PUT_LINE (
         'Client No' || TO_CHAR (NumCli) || ' non-existent');
   WHEN OTHERS
   THEN
      DBMS_OUTPUT.PUT_LINE (
         'Oracle error:' || SQLCODE || '; Oracle message: ' || SQLERRM);
END;
 
 execute OuvrirCompte(101,1600);

[JeanYvette]

Bonjour,

J'ai comme l'impression que ça manque de COMMIT et de ROLLBACK non ?

Bisous bisous

[McM]

Bonjour,

1/ Merci d'éditer votre post en encadrant le code PLSQL de la balise CODE (le # dans les icônes).
2/ Jamais de to_date sur une date : Une date est une date, un to_date transforme une chaîne de caractère en date, un to_char transforme une date en chaîne de caractère
3/ Si rien ne se passe c'est que la procédure s'est exécutée dans problème. Vu qu'il y a des exceptions qui font du dbms_output, il s'agit probablement de ça.
4/ Pour debuger, il suffit de mettre en commentaire tout le code sauf le minimum, tester, puis remettre une partie supplémentaire, tester, etc...


exemple

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
CREATE OR REPLACE PROCEDURE OuvrirCompte(NumCli IN NUMBER, Montant IN NUMBER)
IS
BEGIN
    INSERT INTO Compte (NumCompte, NumClient, DateOuverture, Solde, PMVR)
    VALUES (seqCompte.NEXTVAL, NumCli, TRUNC(SYSDATE), Montant, 0);
END;

puis

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
CREATE OR REPLACE PROCEDURE OuvrirCompte(NumCli IN NUMBER, Montant IN NUMBER)
IS
BEGIN
	IF Montant < 0
  THEN
    RAISE_APPLICATION_ERROR (-20002, 'the amount must be greater than 0');
  END IF;
 
  INSERT INTO Compte (NumCompte, NumClient, DateOuverture, Solde, PMVR)
  VALUES (seqCompte.NEXTVAL, NumCli, TRUNC(SYSDATE), Montant, 0);
END;

etc..

[skuatamad]

Supprimez le bloc WHEN OTHERS
Utilisez raise_application_error dans le bloc client_inexistant
Pour activer l'affichage de dbms_output faites un set serveroutput on dans sqlplus (ou sqldeveloper) avant d'exécuter la procédure.

[Ikebukuro]

Pour activer l'affichage de dbms_output faites un set serveroutput on dans sqlplus (ou sqldeveloper) avant d'exécuter la procédure.

Je dirais d'une autre façon que, pour afficher quelque chose à l'écran en PL/SQL, il faut effectivement faire un set serveroutput on sous SQL*Plus.

Après, si tu es le seul à manipuler cette table, tu peux faire un SELECT count(*) AVANT de lancer la procédure, lancer celle-ci puis refaire un SELECT count(*) après pour voir si on a +1 ou non.

skuatamad, pourquoi supprimer le WHEN OTHERS? Si une erreur du genre "Table en mode Read Only" arrive, on la verra avec cette instruction.

[skuatamad]

skuatamad, pourquoi supprimer le WHEN OTHERS? Si une erreur du genre "Table en mode Read Only" arrive, on la verra avec cette instruction.

Ben non, car si l'affichage n'est pas activé on aura seulement "procédure exécutée avec succès"

Sans bloc WHEN OTHERS le programme plante et l'erreur remonte à l'appelant (par exemple s'affiche à l'écran sqlplus).

Si on utilise WHEN OTHERS, il faut au moins faire quelque chose d'utile avec comme logguer l'erreur, et bien sûr ne pas oublier de la renvoyer (raise) l'erreur.
Mais le problème c'est qu'on perd la ligne exact en erreur, la ligne indiquée dans le message devient la ligne du raise.

[McM]

Exactement je suis avec Skuatamad, et c'est ce que j'ai dit :

3/ Si rien ne se passe c'est que la procédure s'est exécutée dans problème. Vu qu'il y a des exceptions qui font du dbms_output, il s'agit probablement de ça.

De plus je pense que le code est un code de dev, et donc pour avoir l'erreur, il faut épurer tout afin de comprendre ce qui arrive.

[Mahdois]

Bonjour, déjà il y a un petit problème sur la ligne TO_DATE (sysdate, 'DD.MM.YY').
Sysdate est déjà de type DATE donc si votre colonne COMPTE.DateOuverture est déclarée de type DATE, il faut juste remplacer TO_DATE (sysdate, 'DD.MM.YY') par sysdate et si votre colonne est de type VARCHAR2 il faut mettre TO_CHAR(sysdate, 'DD.MM.YY')

Pour la fonction To_Date, le premier paramètre devrait être de type VARCHAR2 donc il faut pas lui passer un paramètre de type DATE. ça génère l'erreur ORA-01861 - Literal does not match format string