Discussion :

[Menhir]

Au vu de ces échanges, comme ceux nombreux par le passé, je persiste à croire, comme l'ami Theze qu'il reste plus facile de rechercher un numéro de série.

A condition d'être sûr que la cellule contient un nombre entier.
Sinon, mieux vaut passer par un équivalent de la valeur affichée formatée.

C'est pile-ou-face.

Mais je suis d'accord que les dates sont difficilement compatibles avec les égalités.
Lorsqu'on le peut, mieux vaut utiliser des inégalités ou des bornes (ce qui n'est pas possible avec un Find).

Ne pas oublier qu'il y a d'autres solutions de recherche : sans aller jusqu'à faire une boucle, il reste la solution d'utiliser des fonctions Excel (MATCH ou VLOOKUP) qui ont plus de possibilités dans ce domaine.

[MarcelG]

A condition d'être sûr que la cellule contient un nombre entier.

C'est mon hypothèse de départ,

Le champ de recherche ne contiendrait que des nombres au format date.
Le changement de format les considérerait en Long.
Et la recherche devient alors plus facile.
Certes, la rigueur des données est, comme toujours, fondamentale.
Ce qui n'empêche pas une restitution au format initial en fin de traitement.

Je développe actuellement un planning de gestion de ressources ETP pour mon entité.
Honnêtement, je ne me plains pas de considérer ce processus.

C'est juste mon avis.
Et j'accepte, bien entendu, volontiers l'existence d'autres processus.

[Docmarti]

Bonjour.

Je viens de penser a une technique qui permettrait de trouver facilement une date avec FIND.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
 'On recherche d'abord une valeur de type Date avec xlFormulas et xlValues
   what = CDate(LaDate)
   Set Resultat = Rng.Find(what:=what, LookIn:=xlFormulas, lookat:=xlWhole)
   If Resultat Is Nothing Then Set Resultat = Rng.Find(what:=what, LookIn:=xlValues, lookat:=xlWhole)
 
  'On recherche ensuite une valeur de type String avec xlFormulas et xlValues
   what = CStr(LaDate)
   If Resultat Is Nothing Then Set Resultat = Rng.Find(what:=what, LookIn:=xlFormulas, lookat:=xlWhole)
   If Resultat Is Nothing Then Set Resultat = Rng.Find(what:=what, LookIn:=xlValues, lookat:=xlWhole)
 
   If Resultat Is Nothing Then
    MsgBox "Vraiment aucun resultat"
   Else
   Resultat.Select
   End If

Qu'en pensez-vous?

[MarcelG]

Bonjour Docmarti,

En fait, tu balaies tous les cas de figure.
Les débats, anciens comme récents, portent justement sur la méthode à préconiser.

Personnellement, je ne suis pas très fan des conditions répétées. (Pas très fun)
J'admets néanmoins que cette méthode peut aboutir.
Et c'est juste mon avis.

[Pierre Fauconnier]

Salut.

Quand je ne peux pas faire autrement qu'utiliser Find pour retrouver des dates, j'utilise Application.FindFormat

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Sub Macro1()
  Dim r As Range
  Dim d As Date
 
  d = DateSerial(2018, 4, 16)
 
  Application.FindFormat.NumberFormat = "m/d/yyyy"
  Set r = Range("b1:b38").Find(What:=Format(d, "m/d/yyyy"), After:=Range("b1"), LookIn:=xlValues, _
    LookAt:=xlWhole, SearchOrder:=xlByRows, SearchDirection:=xlNext, _
    MatchCase:=False, SearchFormat:=True)
  If Not r Is Nothing Then MsgBox r.Address
End Sub

Attention à bien préciser toutes les options, car FIND "singe" l'utilisation de la boite de dialogue de recherche d'Excel, et les options utilisées antérieurement restent actives.

[MarcelG]

Bonsoir Pierre,

Je ne connaissais pas. Bien!
Je me posais la question quant à l'adaptation de ce processus à une Textbox. Il faudrait alors considérer la fonction DateValue.
A priori, il n'y aurait pas de problème.
A l'occasion, je testerai à partir de demain.

Bonne soirée à toi. Bonne soirée au Forum.

[Theze]

Re,

comme dit MarcelG

Le champ de recherche ne contiendrait que des nombres au format date.
Le changement de format les considérerait en Long.
Et la recherche devient alors plus facile.
Certes, la rigueur des données est, comme toujours, fondamentale.
Ce qui n'empêche pas une restitution au format initial en fin de traitement.

pour moi, une date valide dans Excel ne peut être qu'un numéro de série, le reste n'est que formatage ! Mais bon, ça n'engage que moi

[MarcelG]

Bonjour le Forum,

Theze,

J'ai testé la proposition de Pierre sur un formulaire.

Code fonctionnel, avec une déclaration, comme je le pressentais, en Long

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
Dim d As Long
d = DateValue(Me.TextBox1)

Quelques remarques:
- Il y a inversion des formats entre le code ("m/d/yyyy") et la feuille de travail ("d/m/yyyy").
La cause en est, je pense, la gestion des dates américaines
- La fonctionnalité de la propriété FindFormat est, comme le reporte l'aide Microsoft et comme il est démontré ici, le format de recherche.
Ce qui signifie qu'elle peut servir à tous les formats de cellules (police, couleur...). Et donc, au passage, est elle affectée à l'objet Application. Je la trouve donc très utile.
- L'aide Microsoft quant à la fonction DateValue indique une

Renvoie une Variante (Date

J'aurais plutôt pensé à Long, comme d'ailleurs pour DateSerial

Conclusion: 1 élément de plus dans ma documentation, partie "Dates".
Merci.

Bonne journée à tous.

[informer]

Excel, un boulet, preuve en est, j'ai implémenté la solution de Pierre et voici le résultat


Avec
oRgFind.Address = $B$3:$D$3
dDate = 23/10/2019

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
oRgFind.Find(What:=Format(dDate, "m/d/yyyy"), LookIn:=xlValues, _
LookAt:=xlWhole, SearchOrder:=xlByColumns, SearchDirection:=xlNext, MatchCase:=False, SearchFormat:=True)

Renvoie nothing

J'ai également essayé en ajoutant After:=oRgFind.Columns(1)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
oRgFind.Find(What:=Format(dDate, "m/d/yyyy"), After:=oRgFind.Columns(1), LookIn:=xlValues, _
LookAt:=xlWhole, SearchOrder:=xlByColumns, SearchDirection:=xlNext, MatchCase:=False, SearchFormat:=True)

Toujours Nothing

[Pierre Fauconnier]

Tu as mis la ligne Application.FindFormat = "m/d/yyyy"? Je ne la vois pas dans ton code.

[informer]

Bonjour Pierre et merci pour ton aide

Si elle y est après dDate = DateSerial...

[MarcelG]

Bonsoir,

Si je peux me permettre.

La partie du code reportée me laisse perplexe.
Connais-tu la fonction DateValue?

Quand bien même.
Il faut toujours prendre un peu de recul par rapport aux codes proposés.
Tu compliques en effet.

Si tu recherches la date du jour, écrire directement

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set r = Range("b1:b38").Find(What:=Format(Date, "m/d/yyyy")........

ferait retourner le même résultat, non? (Je viens de tester)

D'autre part, l'affectation de la variable à l'objet Range m'interpelle quelque peu.
C'est justement la ligne mise ici en exergue par le debugger.

Pourrais-tu retourner ta procédure en entier.

[Theze]

Bonjour,

En partant du code de Pierre et avec les dates comme tu les présentes en B3:C3, l'adresse C3 m'est bien retournée (pour le 23/10/2019). Ici, j'utilise "NumberFormatLocal" puisque c'est ton format :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
 
Sub Test()
 
    Dim Plage As Range
    Dim Cel As Range
    Dim LaDate As Date
 
    Set Plage = Range("B3:C3")
 
    LaDate = Date
 
    'format France
    Application.FindFormat.NumberFormatLocal = "jj/mm/aaaa"
 
    Set Cel = Plage.Find(LaDate, , xlValues, xlWhole)
 
    If Not Cel Is Nothing Then MsgBox Cel.Address(0, 0)
 
End Sub

[Theze]

Hello Macel

Il n'est même pas nécessaire d'utiliser Format() dans la méthode Find() puisqu'on initialise le type de recherche souhaitée avec FindFormat !

[MarcelG]

Hello,

Sur mon poste.

La date du jour est en B3.

Ce code est bien effectif

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Sub Macro1()
  Dim r As Range
 
  Application.FindFormat.NumberFormat = "m/d/yyyy"
  Set r = Range("b1:b38").Find(What:=Date, After:=Range("b1"), LookIn:=xlValues, _
    LookAt:=xlWhole, SearchOrder:=xlByRows, SearchDirection:=xlNext, _
    MatchCase:=False, SearchFormat:=True)
  If Not r Is Nothing Then MsgBox r.Address
End Sub

Si l'on considère ton processus en intégrant le paramètre SearchFormat, le résultat est différent selon la valeur qui lui est affectée. Ce qui est logique mais le résultat n'est pas celui que j'attendrais.


Avec SearchFormat:=True, la cellule n'est pas trouvée

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Sub Macro3()
 
Dim r As Range
 
 Dim LaDate As Date
  LaDate = Date
 
  Application.FindFormat.NumberFormatLocal = "jj/mm/aaaa"
  Set r = Range("b1:b38").Find(What:=LaDate, LookIn:=xlValues, _
    LookAt:=xlWhole, SearchFormat:=True)
  If Not r Is Nothing Then MsgBox r.Address
End Sub

Avec SearchFormat:=False, la cellule est trouvée

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Sub Macro3()
 
Dim r As Range
 
 Dim LaDate As Date
  LaDate = Date
 
  Application.FindFormat.NumberFormatLocal = "jj/mm/aaaa"
  Set r = Range("b1:b38").Find(What:=LaDate, LookIn:=xlValues, _
    LookAt:=xlWhole, SearchFormat:=False)
  If Not r Is Nothing Then MsgBox r.Address
End Sub

Il y interférence entre le paramètre SearchFormat et la propriété de l'application FindFormat.
S'il est omis, le paramètre SearchFormat est considéré à False.
Alors que dans le code de Pierre, SearchFormat est précisée à True.

Je pencherais pour sa déclaration. Mais ces constatations m'interpellent.

A te lire.

[Theze]

Bonjour,

Bonjour Marcel,

La recherche par le formatage me semble bien perfectible car avec un formatage en date longue, plus moyen de la trouver !!!
Que ce soit avec "NumberFormatLocal" ou "NumberFormat" et que "SearchFormat" soit à True ou False !
Sitôt remis en date courte, elle est trouvée dans pour six des huit cas ci-dessous :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
 
Sub Test()
 
    Dim Plage As Range
    Dim Cel As Range
    Dim LaDate As Date
 
    Set Plage = Range("B3:C3")
    LaDate = Date
 
    Application.FindFormat.Clear
    Application.FindFormat.NumberFormat = "m/d/yyyy"
 
    Set Cel = Plage.Find(Format(LaDate, "m/d/yyyy"), , xlValues, xlWhole, , , , , True)
    If Not Cel Is Nothing Then MsgBox "Test 1 : " & Cel.Address(0, 0)
 
    Set Cel = Plage.Find(Format(LaDate, "m/d/yyyy"), , xlValues, xlWhole, , , , , False)
    If Not Cel Is Nothing Then MsgBox "Test 2 : " & Cel.Address(0, 0)
 
    Set Cel = Plage.Find(LaDate, , xlValues, xlWhole, , , , , True)
    If Not Cel Is Nothing Then MsgBox "Test 3 : " & Cel.Address(0, 0)
 
    Set Cel = Plage.Find(LaDate, , xlValues, xlWhole, , , , , False)
    If Not Cel Is Nothing Then MsgBox "Test 4 : " & Cel.Address(0, 0)
 
    Application.FindFormat.Clear
    Application.FindFormat.NumberFormatLocal = "jj/mm/aaaa"
 
    Set Cel = Plage.Find(Format(LaDate, "m/d/yyyy"), , xlValues, xlWhole, , , , , True) 'pas trouvée !
    If Not Cel Is Nothing Then MsgBox "Test 5 : " & Cel.Address(0, 0)
 
    Set Cel = Plage.Find(Format(LaDate, "m/d/yyyy"), , xlValues, xlWhole, , , , , False)
    If Not Cel Is Nothing Then MsgBox "Test 6 : " & Cel.Address(0, 0)
 
    Set Cel = Plage.Find(LaDate, , xlValues, xlWhole, , , , , True) 'par trouvée !
    If Not Cel Is Nothing Then MsgBox "Test 7 : " & Cel.Address(0, 0)
 
    Set Cel = Plage.Find(LaDate, , xlValues, xlWhole, , , , , False)
    If Not Cel Is Nothing Then MsgBox "Test 8 : " & Cel.Address(0, 0)
 
End Sub

Résultat des courses, je préfère la méthode que j'ai présentée dans ma première intervention, celle que nous utilisons tous les deux :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
 
Sub Test()
 
    Dim Plage As Range
    Dim Cel As Range
    Dim LaDate As Date
    Dim F As String
 
    Set Plage = Range("B3:C3")
 
    F = Plage.NumberFormat
    Plage.NumberFormat = "General"
 
    LaDate = Date
 
    Set Cel = Plage.Find(CLng(LaDate), , xlValues, xlWhole)
    If Not Cel Is Nothing Then MsgBox Cel.Address(0, 0)
 
    Plage.NumberFormat = F
 
End Sub

[MarcelG]

Bonjour Theze, Bonjour le Forum,

Même constat sur mon poste ce matin.
OK

Passe une bonne journée, Bonne journée au Forum.

[informer]

Merci à tous pour votre aide mais définitivement Excel n'est pas mon copain

Cette fois, c'est NumberFormat qui fait des siennes puisqu'il ne fait pas son job sur toutes les dates

[MarcelG]

Salut,

c'est NumberFormat qui fait des siennes puisqu'il ne fait pas son job sur toutes les dates

Et pour cause, D3 est une chaine de caractères.

Si les données dates sont en B1:B4, sur mon poste ce code est effectif

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
Sub Test2()
 
Dim Plage As Range
Dim leformat As String
Dim C As Range
 
Set Plage = Range("B1:B4")
 
With Plage
        leformat = .NumberFormat
        .NumberFormat = "General"
        Set C = .Find(what:=CLng(Date), LookIn:=xlValues, lookat:=xlWhole)
        .NumberFormat = leformat
End With
 
If Not C Is Nothing Then
        MsgBox C.Address(0, 0)
        Set C = Nothing
End If
 
Set Plage = Nothing
 
End Sub

[informer]

MarcelG,
Je ne parle pas de D3 mais de C3 qui reste au format date au contraire de B3 qui lui passe en Long.