Discussion :

[JPJOLY]

Bonjour,

Je veux faire un programme de mailing.
Pour cela j'utilise une fonction dans laquelle j'ai l'ordre:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

DOcmd.SendObject AcSendNoObject , , acformatPDF, Adrmail, , , Object, Corpsmessage, Modif

Si je mets Modif=True je n'ai aucun problème je vois le mail et je l'envoie.
Si je mets Modif=False J'ai un message d'Outlook me demandant de confirmer mon envoi. C'est ce message que je voudrais ne plus voir apparaître.
Je suis en Office 365. Je démarre Outlook en mode administrateur et je peux ainsi 'théoriquement' agir sur les options d'Outlook/Centre de gestion de la confidentialité/paramètre.../Accès par programme.
Je peux alors choisir notamment "Ne jamais m'avertit des actions douteuses" ou "M'avertir des actions douteuses lorsque logiciel de sécurité n'est pas à jour".
Que je choisisse n'importe laquelle des options je reçois alors le message:

Microsoft Visual Basic Erreur d'exécution 2293 'NomapplicationAccess' ne peut envoyer ce courrier.

Mon antivirus est Windows Defender et il est OK.
Comment éviter ce message et pouvoir enchaîner mes envois de mail de manière totalement automatique ??
Merci par avance de votre aide.

[Zekraoui_Jakani]

C'est une des limitations de l'instruction "SendObject": la sécurité MAPI demande à l'utilisateur de vérifier chaque email pour voir si okay avant l'envoi (si "modif"=False).
A ma connaissance SendOject ne fonctionne qu'avec Outlook, Outlook Express ou Exchange (sauf si de nouveaux développements ont corrigé le tir).

Pour ma part, j'ai contourné le problème en utilisant:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
 
Function EnvoiAttestation(fichier, personne, yr, Adresse)
 
    Dim appOutLook As Object    'Outlook.Application
    Dim MailOutLook As Object    'Outlook.MailItem
    Dim myTxt As String
    Dim NewLine: NewLine = "<br>"
 
    myTxt = "Cher(e) membre," & NewLine & NewLine
    myTxt = myTxt & "Veuillez trouver, en annexe, votre reçu de don pour l'année " & yr & "." & NewLine & NewLine
    myTxt = myTxt & "Nous vous en souhaitons bonne réception, et vous remercions pour votre générosité ....blabla."
    myTxt = myTxt & NewLine & NewLine & "Cordialement," & NewLine & NewLine
    myTxt = myTxt & "L'association ....," & NewLine & NewLine & NewLine
    myTxt = myTxt & "N.B.: Au cas où vous constatez une différence avec les montants réellement versés," & NewLine
    myTxt = myTxt & vbTab & "merci de nous en faire part via la messagerie PRIVEE sur 'WhatsApp'."
 
    If fichier <> "" Then
 
        Set appOutLook = CreateObject("Outlook.Application")
        Set MailOutLook = appOutLook.CreateItem(olMailItem)
 
        With MailOutLook
'            .BodyFormat = olFormatRichText
            .To = IIf(Adresse = "" Or IsNull(Adresse), "", Adresse)
            '.cc = ""
            '.bcc = ""
            .Subject = "Reçu de Don - " & personne
            .HTMLBody = myTxt
            .Attachments.Add (fichier)
'            .send
            .display    'utilisé pour le test (désactiver si vous voulez envoyer et activer ".Send")
        End With
    Else
        MsgBox "Le fichier " & strPath & strFilter & vbCrLf & _
                "n'existe pas ! - Processus arrêté.", vbOKOnly, "Fichier inexistant"
        Exit Function
    End If
 
End Function

[JPJOLY]

Remarquable de clarté et de précision. Cela fonctionne parfaitement. Merci pour votre aide.