Discussion :

[jajaloic]

Bonjour à tous,

Je travaille actuellement sur une base ACCESS qui importe notamment des données issues de fichiers Excel.
Je cherche à Créer une fonction qui me permettrait d'aller piocher dans les metadonnées d'un fichier excel la date de dernière modification, et que cette donnée soit stockée dans un table.

Je ne maîtrise pas suffisamment VBA pour créer une telle fonction.

Quelqu'un pourrait-il m'aider ?

Bien cordialement

[marot_r]

Bonjour.

Je ne la connaissait pas mais il semble qu'elle existe déjà : FileDateTime .

Ici une explication un peu plus détaillée.

https://www.techonthenet.com/access/...ledatetime.php

A+

[hyperion13]

Salut
Pour compléter la réponse de marot_r il y a ceci.

[jajaloic]

Bonjour merci pour vos réponses,

J'ai essayé en l'utilisant en requête (comme indiqué dans un des liens que vous avez donné), mais j'ai un message d'erreur qui indique que la fonction n'est pas définie. (Je ne comprends pas car Microsoft reconnait bien la fonction, il la renomme même en lui donnant son petit nom français).

Je n'ai pas réussi à utiliser la fonction en VBA non plus. Je pense que j'ai oublié mes quelques notions de VBA (pour Excel en plus...).
J'ai essayé de mettre le code dans un module... ca ne marche pas
J'ai essayé de l'intégrer dans un sub()... ca ne marche pas

Quelqu'un sait-il ce que je dois faire ?

[Zekraoui_Jakani]

A défaut, voici un exemple que vous pouvez exploiter:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
 
Sub donneesDeFichier()
    Dim myPath, myFile, myFullPath As String
 
    myPath = "C:\Users\.....\"  'mettre ici votre adresse répertoire terminée par "\"
    myFile = "VotreNomDeFichier.xlsm"   'avec la bonne extension!!
    myFullPath = myPath & myFile
 
    GetFileInfo myFullPath
End Sub
 
Public Function GetFileInfo(ByVal sFile As String)
    On Error GoTo Error_Handler
    Dim fso As Object
    Dim f As Object
    Dim myMsg As String
 
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set f = fso.GetFile(sFile)
 
    myMsg = "Nom: " & f.Name & vbLf & vbLf
    myMsg = myMsg & vbTab & "Taille: " & f.Size & vbLf  'équivalent: FileLen(sFile)
    myMsg = myMsg & vbTab & "Creé: " & f.DateCreated & vbLf
    myMsg = myMsg & vbTab & "Modifié: " & f.DateLastModified & vbLf
    myMsg = myMsg & vbTab & "Traité: " & f.DateLastAccessed & vbLf
    myMsg = myMsg & vbTab & "Type: " & f.Type & vbLf
    myMsg = myMsg & vbTab & "Attributs: " & f.Attributes
 
    MsgBox myMsg, vbInformation + vbOKOnly, "Informaions du fichier " & f.Name
 
Error_Handler_Exit:
    On Error Resume Next
    Set f = Nothing
    Set fso = Nothing
    Exit Function
 
Error_Handler:
    MsgBox "L'erreur suivante s'est produite:" & vbCrLf & vbCrLf & _
           "Numéro: " & Err.Number & vbCrLf & _
           "Source: GetFileInfo" & vbCrLf & _
           "Description: " & Err.Description, _
           vbCritical, "Erreur de procédure!"
    Resume Error_Handler_Exit
 
End Function

[clementmarcotte]

Bonjour,

Regarde cette page. Je te laisse l'adaption poue Access

[marot_r]

Bonjour.

Je viens de tester en VBA (en Access 2007) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

debug.print filedatetime("C:\msdia80.dll")

Et j'ai bien obtenu la date et l'heure.

Par contre il est possible que cette fonction soit "bloquée" en SQL comme Environ$() par exemple.

Dans ce cas, il fait faire une fonction VBA qui appelle la fonction. Quelque chose comme :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
public function MonFiledatetime(prmCheminFichier as string) as date
    Monfiledatetime=Filedatetime(prmCheminFichier)
end function

A+

[jajaloic]

Bonsoir à tous,

Merci beaucoup, ca marche !

Pour récapituler :
- La méthode proposée par Zekraoui_Jakani fonctionne, mais je souhaitais idéalement avoir la réponse dans une query
- La méthode proposée par Marot fonctionne nickel :-)

Un grand merci ca m'aide énormément !

Loïc