Discussion :

[essadqi]

Bonjour,

J'ai créé un classeur excel avec un bouton qui lorsque je clique dessus va récupérer des données dans un autre classeur excel.

j'obtiens ce message:

Erreur d'exécution '9' (L'indice n'appartient pas à la sélection)

Sur votre forum j'ai trouvé des personnes qui ont le même problème mais je n'ai malheureusement pas réussi à résoudre le mien. Voici mon code du bouton.

Code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
Sub MaJ_Data()
 
 
    Dim nom_fichier As String
    Dim WbkData As Workbook
 
 
    Application.DisplayAlerts = False
    Application.ScreenUpdating = False
 
 
    'chemin d'accès repertoire de la base de données
    ChDir "C:\Users\M.ES-SADQI\Desktop\Nouveau dossier\"
 
    'Recupération du nom du fichier de la base de données
    'le nom du fichier n'est pas statique
 
    nom_fichier = Application.GetOpenFilename("fichiers Excel (*.), *.")
 
    'Initialisation de la variable wbkData= => elle prend la valeur de classeur issu de la base de donnée
 
    Set WbkData = Workbooks.Open(nom_fichier)
 
    'Efface le contenu de la feuille a mettre a jour (DATA_BASE)
 
    ThisWorkbook.Activate
    Sheets("DATA_BASE").Select
    Range("A2:D34").Select
    Selection.ClearContents
    Range("A2").Select
 
    'Recupération du contenu de la nouvelle feuille excel
 
    WbkData.Activate
    Sheets("Test").Select
    Range("A2:D34").Select
    Selection.Copy ' copy des données du classeur data_base
 
 
    Windows("Rayonnage.xlsm").Activate
    Range("A2").Select
    Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks:=False, Transpose:=False
 
    WbkData.Close
 
    Application.DisplayAlerts = True
    Application.ScreenUpdating = True
 
 
 
End Sub

[Invité]

Bonjour,

A tester, mais j'ai l'impression qu'il y a confusion entre la feuille cible et la feuille source...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
 
Sub MaJ_Data()
 
Dim WbCible As Workbook, WbSource As Workbook
Dim CelluleCible As Range
Dim NomFichierSource As Variant
 
    On Error GoTo Fin
 
    ChDir "C:\Users\M.ES-SADQI\Desktop\Nouveau dossier\"
 
    NomFichierSource = Application.GetOpenFilename("fichiers Excel (*.xls*), *.xls*")
 
    If NomFichierSource = False Then GoTo Fin
 
 
    Application.DisplayAlerts = False
 
    Set WbCible = ActiveWorkbook
    With WbCible.Sheets("DATA_BASE")
         .Range("A2:D34").ClearContents
         Set CelluleCible = .Range("A2")
    End With
 
    Set WbSource = Workbooks.Open(NomFichierSource)
    With WbSource
        .Sheets("Test").Range("A2:D34").Copy
        CelluleCible.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks:=False, Transpose:=False
        .Close savechanges:=False
    End With
 
    Application.DisplayAlerts = True
 
    GoTo Fin
 
Fin:
 
 
  Set CelluleCible = Nothing
  Set WbCible = Nothing
  Set WbSource = Nothing
 
End Sub

[Menhir]

j'obtiens ce message:

Erreur d'exécution '9' (L'indice n'appartient pas à la sélection)

Quelle ligne de code est désignée par le débugage lorsque l'erreur se produit ?

[patricktoulon]

Bonjour

la premier chose a faire est d'eviter:
les activate
select/.paste
il faut laisser le flux faire c'est plus souple

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
Sub MaJ_Data()
'
    Dim nom_fichier As String, WbkData As Workbook
    '
    Application.DisplayAlerts = False
    Application.ScreenUpdating = False
    '
    '
    'chemin d'accès repertoire de la base de données
    ChDir Environ("userprofile") & "\Desktop\Nouveau dossier\"
     '
    'Recupération du nom du fichier par le dialog getopenfilname
    'seul les fichiers excel s'afficheront dans le dialog
    nom_fichier = Application.GetOpenFilename(FileFilter:="Excel Files ( *.xlsx;*.xls;*.xlsm), ( *.xlsx;*.xls;*.xlsm), All Files, *.*", FilterIndex:=1)
    '
    If nom_fichier <> "" Then
        '
        'Efface le contenu de la feuille a mettre a jour (DATA_BASE)
        ThisWorkbook.Sheets("DATA_BASE").Range("A2:D34").ClearContents
        '
        '
        Set WbkData = Workbooks.Open(nom_fichier)    'ouverture du fichier
        '
        Range("A2:D34").Copy Destination:=ThisWorkbook.Sheets("DATA_BASE").Range("A2")    'transfert des données
        '
        WbkData.Close    'fermeture du fichier source
        '
        Application.DisplayAlerts = True
        Application.ScreenUpdating = True
        '
    End If
End Sub

éventuellement tu pourrais ne pas vouloir le formatage des cellules de la source
et toujours sans select ou activate
donc

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Set WbkData = Workbooks.Open(nom_fichier)    'ouverture du fichier
        'tout avec le formatage
        'Range("A2:D34").Copy Destination:=ThisWorkbook.Sheets("DATA_BASE").Range("A2")    'transfert des données
        ' OU JUSTE LES VALEURS
        Range("A2:D34").Copy
        ThisWorkbook.Sheets("DATA_BASE").Range("A2").PasteSpecial (xlPasteValues)
        WbkData.Close    'fermeture du fichier source

SINON TU A ADO QUI FAIT LE BOULOT SANS OUVRIR LE FICHIER DANS L'APPLICATION EXCEL

[patricktoulon]

re
comme je galéré toujours avec la syntaxe de ADO pour le fun je me suis amusé avec une formule
et quitte a me valoir un "-1"
donc sans ouvrir le fichier dans l'application Excel
j'ai bien aéré et commenté le code
testé sur 2007

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
 
Option Explicit
'exemple formule de base
'"=IF('C:\Users\polux\DeskTop\Nouveau Dossier\[source.xlsm]Feuil1'!A1<>"""",'C:\Users\polux\DeskTop\Nouveau Dossier\[source.xlsm]Feuil1'!A1,"""")"
Sub test()
    Dim Cel As Range, formule$, chemin$, Pls As Range, feuille$, fichier$
    chemin = Environ("userprofile") & "\DeskTop\Nouveau Dossier\"
    ChDir chemin
 
    'la source
    Set Pls = Range("A1:D34") 'plage de la source
    feuille = "Feuil1" ' feuille de la source
    'fichier de la source par getopenfilename
    fichier = Application.GetOpenFilename(FileFilter:="Excel Files ( *.xlsx;*.xls;*.xlsm), ( *.xlsx;*.xls;*.xlsm), All Files, *.*", FilterIndex:=1)
 
    ' si on annule pas le dialog
    If fichier <> "" Then
        fichier = Mid(fichier, InStrRev(fichier, "\") + 1) 'nom cout du fichier source pour la formule
        'creation de la formule pour la premiere cellule
        formule = "'" & chemin & "[" & fichier & "]" & feuille & "'!" & Pls.Cells(1).Address(0, 0)
        formule = "=IF(" & formule & "<>""""," & formule & ","""")"
        Debug.Print formule ' pour verif
        'DESTINATION
        With Sheets(1).Range("A1") 'feuille et 1ere cellule de destination( c'est pas obligé que se soit la même que la source )
 
            'inscription de la formule dans la 1 ère cellule
            .Formula = formule
 
            'on étend la formule vers le bas au même nombre de ligne que la plage source
            .AutoFill Destination:=.Resize(Pls.Rows.Count, 1), Type:=xlFillDefault
 
            'on étend la formule vers la droite au même nombre de colonnes que la plage source
            .Resize(Pls.Rows.Count, 1).AutoFill Destination:=.Resize(Pls.Rows.Count, Pls.Columns.Count), Type:=xlFillDefault
 
            'on remplace les formules par les valeurs
            .Resize(Pls.Rows.Count, Pls.Columns.Count).Value = .Resize(Pls.Rows.Count, Pls.Columns.Count).Value
        End With
    End If
End Sub

résultat instantané

[essadqi]

aucune ligne, que les données ne s'importent pas

[essadqi]

merci beaucoup c'est réglé

[Invité]

Pouvez-vous être plus clair ?

[Pierre Fauconnier]

Si tu as l'affichage d'une erreur 9, c'est forcément sur une ligne de code.

Désactive temporairement la gestion des erreurs en allant dans Outils/Options/Général et coche "Arrêt sur toutes les erreurs"... Ce sera moins radical que de supprimer tes lignes de gestion d'erreur...

Si, après cela, tu relances le code, il va surligner en jaune la ligne qui pose problème. D'une façon habituelle, une erreur 9 provient d'une erreur de nommage de feuille, d'objet, etc...

[Pierre Fauconnier]

Pouvez-vous être plus clair ?

Oui, en effet. Pour les personnes qui ont aidé comme pour les prochaines qui liront la discussion, il me semble correct de publier la solution trouvée...

[essadqi]

à l'aide Mr patricktoulon, j'ai testé ce code, il a donné des bonnes resultats

Merci beaucoup pour votre intérêt,

le code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
Option Explicit
'exemple formule de base
'"=IF('C:\Users\polux\DeskTop\Nouveau Dossier\[source.xlsm]Feuil1'!A1<>"""",'C:\Users\polux\DeskTop\Nouveau Dossier\[source.xlsm]Feuil1'!A1,"""")"
Sub test()
    Dim Cel As Range, formule$, chemin$, Pls As Range, feuille$, fichier$
    chemin = Environ("userprofile") & "\DeskTop\Nouveau Dossier\"
    ChDir chemin
 
    'la source
    Set Pls = Range("A1:D34") 'plage de la source
    feuille = "Feuil1" ' feuille de la source
    'fichier de la source par getopenfilename
    fichier = Application.GetOpenFilename(FileFilter:="Excel Files ( *.xlsx;*.xls;*.xlsm), ( *.xlsx;*.xls;*.xlsm), All Files, *.*", FilterIndex:=1)
 
    ' si on annule pas le dialog
    If fichier <> "" Then
        fichier = Mid(fichier, InStrRev(fichier, "\") + 1) 'nom cout du fichier source pour la formule
        'creation de la formule pour la premiere cellule
        formule = "'" & chemin & "[" & fichier & "]" & feuille & "'!" & Pls.Cells(1).Address(0, 0)
        formule = "=IF(" & formule & "<>""""," & formule & ","""")"
        Debug.Print formule ' pour verif
        'DESTINATION
        With Sheets(1).Range("A1") 'feuille et 1ere cellule de destination( c'est pas obligé que se soit la même que la source )
 
            'inscription de la formule dans la 1 ère cellule
            .Formula = formule
 
            'on étend la formule vers le bas au même nombre de ligne que la plage source
            .AutoFill Destination:=.Resize(Pls.Rows.Count, 1), Type:=xlFillDefault
 
            'on étend la formule vers la droite au même nombre de colonnes que la plage source
            .Resize(Pls.Rows.Count, 1).AutoFill Destination:=.Resize(Pls.Rows.Count, Pls.Columns.Count), Type:=xlFillDefault
 
            'on remplace les formules par les valeurs
            .Resize(Pls.Rows.Count, Pls.Columns.Count).Value = .Resize(Pls.Rows.Count, Pls.Columns.Count).Value
        End With
    End If
End Sub