Débogage d'un Code

**EAU24** · 17/08/2019, 11h20

Bonjour à tous,
j'ai écris le code suivant :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Sub Connaitremontant()
    Dim Numligne As Variant
    Dim Montant As Double
    Dim Trouve As Range
    Numligne = InputBox("Entrez un numéro de ligne")
    Sheets("Feuil1").Activate
    Montant = WorksheetFunction.VLookup(Numligne, Range(" Montant"), 2, False)
    MsgBox "Le montant de la ligne " & Numligne & " est de " & Format(Montant, "# ##0" & "€")
End Sub

mais si j'indique dans mon InputBox une ligne qui n'existe pas il me fais un bog.
Je voudrais rajouter une ligne de Code qui me dise que si la ligne n'existe pas alors un message MsgBox dise "La ligne n'existe pas" et ne me fasse pas un bog.
Merci à tous de m'aider.
EAU

Invité · 17/08/2019, 12h03

Envoyé par EAU24

Bonjour,

A tester :

Nb : Vous devriez retirer le caractère blanc dans la zone nommée " Montant".

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
 
Sub Connaitremontant()
 
Dim Numligne As Variant
Dim Nombredelignes As Long
Dim Montant As Double
 
   With Sheets("Feuil1")
 
        Nombredelignes = .Range("Montant").Rows.Count
        .Activate
 
        Numligne = InputBox("Entrez un numéro de ligne entre 1 et " & Nombredelignes)
        If Numligne = "" Then
           MsgBox "Entrez un numéro de ligne entre 1 et " & Nombredelignes & " !", vbCritical
           Exit Sub
        End If
        Select Case Numligne
           Case 1 To Nombredelignes
                Montant = WorksheetFunction.VLookup(CInt(Numligne), .Range("Montant"), 2, False)
                MsgBox "Le montant de la ligne " & Numligne & " est de " & Format(Montant, "# ##0" & "€")
           Case Else
                MsgBox "Le numéro de ligne n'appartient pas au tableau !", vbCritical
        End Select
 
  End With
 
End Sub

**EAU24** · 17/08/2019, 14h41

Désolé mais cela ne fonctionne pas. Je veux taper un numéro de ligne par exemple AF dans l'InputBox et que le Code Excel me donne le montant qui correspond à la ligne AF de la feuil1. Dans la feuil1 il y a 2 colonnes, une avec les numéros de lignes (AB, I8, 0R par exemple en colonne A (il s'agit des numéro CERFA des liasses fiscales des déclarations de résultat annuelles des entreprises) et en colonne B le montant figurant dans la liasse fiscale. Donc en fait il s'agit de la fonction Excel "Recherchev" mais appliquée à VBA.

Invité · 17/08/2019, 15h26

Envoyé par EAU24

Donc en fait il s'agit de la fonction Excel "Recherchev" mais appliquée à VBA.

Désolé, je n'avais pas deviné.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
 
Sub ConnaitreMontant()
 
Dim NumeroFiscal As String
Dim LigneEnCours As Long
Dim LigneTrouvee As Boolean
Dim AireMontants As Range
 
   With Sheets("Feuil1")
 
        .Activate
 
        Set AireMontants = .Range("Montant").Columns(1).Cells
        NumeroFiscal = InputBox("Entrez un numéro de ligne fiscale ex : AB, I8, 0R")
        If NumeroFiscal = "" Then
           MsgBox "Entrez un numéro de ligne fiscal ex : AB, I8, 0R !", vbCritical
           Exit Sub
        End If
 
        LigneTrouvee = False
        For LigneEnCours = 1 To AireMontants.Count
            If CStr(AireMontants(LigneEnCours)) = NumeroFiscal Then
               MsgBox "Le montant de la ligne " & NumeroFiscal & " est de " & Format(AireMontants(LigneEnCours).Offset(0, 1), "# ##0" & "€")
               LigneTrouvee = True
               Exit For
           End If
         Next LigneEnCours
 
         If LigneTrouvee = False Then
            MsgBox "Le numéro fiscal n'appartient pas au tableau !", vbCritical
         End If
 
  End With
 
End Sub