Discussion :

[Eric_le_Rouge]

Bonsoir
Voilà. J'ai réussis, grâce à l'aide bienveillante de vous autres à charger des images dynamiques ds un état. Jusque là tout OK. Maintenant j'aimerais aussi afficher des images statiques dans le même état. Pour ce, j'ai repris l'exemple de Claude Leloup https://claudeleloup.developpez.com/...onnees-access/. J'ai repris un pour un ses instruction à part le dossier image qui se nome "ETIQUETTES"
Je tourne en rond avec une erreur lorsque j'ouvre l'état. J'ai une procédure événementielle "Sur ouverture de l'état" et j'obtiens l'erreur suivante

J'ai le code suivant pour une action AmnImages

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
Public Sub AmnImages()
Dim Ctrl As Control
Dim bFond As Boolean
On Error GoTo GestionErreur
'Image de fond
bFond = True
If CodeContextObject.Picture = "(aucune)" And CodeContextObject.PictureType = 1 And CodeContextObject.Tag Like "*.*" Then
      CodeContextObject.Picture = CurrentProject.Path & "\ETIQUETTES\" & CodeContextObject.Tag
End If
ImgControles:
'Image des contrôles
bFond = False
For Each Ctrl In CodeContextObject.Controls
     If Ctrl.Picture = "(aucune)" And Ctrl.PictureType = 1 And Ctrl.Tag Like "*.*" Then
      Ctrl.Picture = CurrentProject.Path & "\ETIQUETTES\" & Ctrl.Tag
     End If
  Next Ctrl
Exit Sub
GestionErreur:
Select Case Err.Number
       Case 438   ' pas d'image dans le contrôle examiné
          Resume Next
       Case 2114 'format d'image invalide
          If bFond = True Then         'C'est l'image de fond
             MsgBox "(2114) L'image de fond de '" & CodeContextObject.Name & "', c'est-à-dire : '" _
                  & CodeContextObject.Tag & "' est d'un format invalide."
             Resume ImgControles
          Else
             MsgBox "(2114) L'image '" & Ctrl.Tag & "' est d'un format invalide pour le contrôle '" _
                  & Ctrl.Name & "' de l'objet '" & CodeContextObject.Name & "'."
             Ctrl.Picture = CurrentProject.Path & "\ETIQUETTES\Default.jpg"
             Resume Next
          End If
       Case 2220  'L'image est absente
          If bFond = True Then         'C'est l'image de fond
             MsgBox "(2220) L'image de fond de '" & CodeContextObject.Name & "', c'est-à-dire : '" _
                  & CodeContextObject.Tag & "' est absente."
             Resume ImgControles
          Else
             MsgBox "(2220) L'image '" & Ctrl.Tag & "' est absente pour le contrôle '" _
                & Ctrl.Name & "' de l'objet '" & CodeContextObject.Name & "'."
             Ctrl.Picture = CurrentProject.Path & "\ETIQUETTES\Default.jpg"
             Resume Next
          End If
       Case Else
          MsgBox "Erreur inattendue dans AmnImages" & vbLf _
               & Err.Number & " : " & Err.Description, vbCritical
End Select
End Sub

J'espère que vous avez toutes les informations pour me répondre
Est-ce que quelqu'un voit ou ça bug?
D'avance merci

[tee_grandbois]

bonsoir,

Est-ce que quelqu'un voit ou ça bug?

le nom de la procédure AmnImages a été créé plusieurs fois dans un ou plusieurs modules standards.
pour rechercher les doublons utilise la fonction Rechercher dans la fenêtre VBA en mettant sub AmnImages comme paramètre pour le champ "Rechercher" et en cochant Projet en cours pour l'option "Dans"



et cliquer sur "Suivant" pour trouver les occurrences. Si c'est le cas, il faut supprimer les doublons.
Si il n'y a qu'une occurrence trouvée, vérifie qu'un module standard ne porte pas le même nom que la procédure

[Eric_le_Rouge]

Merci tee_grandbois pour ta réponse
C'était exactement ça. J'avais un doublon et l'action n'étais pas au bon endroit.
C'est tout bon maintenant
Encore merci