Sélection de plusieurs cellules par rapport à une cellule

**pouldom** · 16/07/2019, 14h47

Bonjour à tous,

J'ai un classeur avec 2 onglets, dans les 2 onglets 2 tableaux identiques : A1 date, B1 fournisseur. C1 montant ht, etc..
je souhaiterais que les infos du premier tableau se reportent automatiquement dans le tableau du 2ème onglet en ayant comme critère la sélection par date et par année.
j'espère m'être exprimé clairement.
Si vous pouviez m'indiquer le formule à utiliser pour sélectionner la ligne complète par rapport à une cellule , ce serait sympa.
Merci à vous.
Cordialement.
Dom

Invité · 16/07/2019, 15h00

Envoyé par pouldom

Bonjour,

Regardez ceci : advancedfilter

**pouldom** · 16/07/2019, 17h19

Bonjour,

Merci pour votre réponse,.
En fait, je souhaiterai que cette fonction se fasse automatiquement.
Est ce possible?

Merci.

Invité · 16/07/2019, 19h35

Envoyé par pouldom

J'utilise régulièrement les filtres avancés pour faire des calculs intermédiaires avec une grande quantité de cas sur des tableaux de plusieurs milliers de lignes.
Une fois mis au point, les critères et la présentation, j'automatise l'établissement, le changement des critères et le lancement de la recherche avec une macro.
L'avantage est que le résultat est quasi instantané pour chaque item.

**Rrradassse** · 16/07/2019, 20h28

Bonjour,
vous pouvez linker les 2 tableaux via une requette Query (dans l'onglet data). Ensuite ce sera automatique

**pouldom** · 16/07/2019, 20h42

Bonsoir,

Merci pour vos réponses.
Désolé, je ne sais pas faire une macro.
Et linker ?

Je suis vraiment novice, j'essaie de réaliser mais c'est parfois pas évident.

Invité · 16/07/2019, 20h47

Envoyé par pouldom

Avez-vous avez réussi à mettre au point l'extraction par filtre avancé sur un autre onglet ?
Si oui, il suffit d'enregistrer une macro qui modifie les paramètres d'extraction. Ensuite, mettez votre fichier en ligne avec la macro et indiquez ce qui doit varier.

**Rrradassse** · 16/07/2019, 21h12

Envoyé par pouldom

Et linker ?

https://support.office.com/fr-fr/art...2-7ca2616d17f9

**pouldom** · 16/07/2019, 22h41

Bonsoir,

Non, je n'ai pas réussi, mais je vais m'y pencher plus en détail.
J'ai un message qui me dit que je ne peux copier sur une autre feuille.
Merci

**pouldom** · 17/07/2019, 16h30

Rebonjour,

Je reviens vers vous car je n'arrive pas à exploiter vos conseils et là je suis vraiment perdu.

Merci de bien vouloir me conseiller.

Cordialement.

Invité · 17/07/2019, 17h02

Envoyé par pouldom

Mettez un fichier en ligne sans données confidentielles et indiquez ce que vous voulez obtenir dans votre deuxième onglet.

**pouldom** · 17/07/2019, 17h47

Merci de votre aide .

Je souhaiterais que les informations de l'onglet achats 2019 soient automatiquement copiés dans l'onglet Achats 2019 et idem pour Achats 2020.
En fait il y a 3 tableaux identiques : achats 2019 2020 qui est utilisé pour une année sportive 2019 2020 et les deux autres par année civile.
Pour éviter de ressaisir en 3 fois , il faudrait qu'en 1 seule saisie dans le premier tableau que des copies se fassent dans les deux autres par année.
J'espère avoir été clair dans mon explication.

Merci d'avance.

Cordialement.

Invité · 17/07/2019, 22h04

Envoyé par pouldom

J'ai pas mal modifié votre fichier. Pour utiliser le filtre avancé, choisissez le l'année ou le mois en cellule D7 de l'onglet année civile.

Pièce jointe 491879

**pouldom** · 17/07/2019, 22h49

Bonsoir,

C'est vraiment ce que je voulais faire.
Je vous remercie infiniment.

Quel est le principe de fonctionnement ? Car bien évidemment, le principal est d'apprendre.
Bonne soirée et encore merci.

Cordialement
Dom

Invité · 18/07/2019, 05h05

Envoyé par pouldom

Le fichier contient un onglet Paramètres contenant la table des mois avec les informations Date début et Date fin qui viendront alimenter la zone Criteres du filtre avancé présent sur l'onglet J Achats année civile :

Pièce jointe 491905

La cellule D7 est une Validation de données liée à la table des mois par cette formule :

Pièce jointe 491908

Le changement de la valeur de la cellule enclenche l'événement suivant dans le module de l'onglet "J Achats année civile" :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Private Sub Worksheet_Change(ByVal Target As Range)
 
    If Target.Count > 1 Then Exit Sub
 
    If Not Intersect(Target, Range("Annee_Mois")) Is Nothing Then
       RechercheDebutEtFinDeMois Target
       FiltrerLesAchats Sheets("J Achats année civile"), Sheets("J Achats").Range("TableDesAchats")
    End If
 
End Sub

La procédure RechercheDebutEtFinDeMois change les valeurs des dates début et fin sur l'onglet :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
 
Sub RechercheDebutEtFinDeMois(ByVal ValeurAnneeMois As String)
 
Dim I As Long
Dim AireMois As Range
 
    Set AireMois = Sheets("Paramètres").ListObjects("TableDesMois").ListColumns("Mois").DataBodyRange
    For I = 1 To AireMois.Count
        If CStr(AireMois(I)) = ValeurAnneeMois Then
           With Sheets("J Achats année civile")
                .Range("MoisDebut") = AireMois(I).Offset(0, 1)
                .Range("MoisFin") = AireMois(I).Offset(0, 2)
           End With
        End If
 
    Next I
    Set AireMois = Nothing
 
End Sub

Les valeurs, une fois modifiée, permettent le lancement du filtre avancé avec cette procédure :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
 
 
Sub FiltrerLesAchats(ByVal ShFiltreAvance2 As Worksheet, ByVal TableEnCours2 As Range)
 
Dim AireDesCodesDExtraction As Range, AireTitreExtraction As Range
 
    With ShFiltreAvance2
 
         .Activate
 
            Set AireDesCodesDExtraction = .Range("Criteres2019")
            Set AireTitreExtraction = .Range("A10:U10")
 
            TableEnCours2.AdvancedFilter Action:=xlFilterCopy, CriteriaRange:=AireDesCodesDExtraction, CopyToRange:=AireTitreExtraction, Unique:=False
 
            Set AireDesCodesDExtraction = Nothing
            Set AireTitreExtraction = Nothing
 
    End With
 
End Sub

Remarques :

L'aire d'extraction peut contenir tout ou partie des champs du tableau d'origine et l'ordre des champs peut être modifié.
La zone Criteres2019 aurait pu s'appeler autrement, au départ le fichier contenait un onglet par année civile.
Curieusement, j'ai du appliquer le format anglo-saxon pour les paramètres du filtre.
Pour l'automatisation, il faut jouer le filtre avancé manuellement auparavant pour qu'Excel définisse ses zones Criteres et Extrait sur l'onglet.

La table d'origine peut contenir plusieurs milliers d'enregistrements, la vitesse d'extraction est quasi immédiate. Lorsque je dois exécuter une boucle, j'extrais d'abord l'échantillon sur lequel la recherche doit être exécutée et je boucle sur un nombre très limité d'enregistrements plutôt que sur toute la base.