Discussion :

[kedas]

Bonjour,
étant un novice en VBA je souhaite faire une opération qui me semble complexe.
un précédent sujet ici m'avait déjà permis de pouvoir faire des synthèses sur plusieurs feuilles, mais aujourd’hui je n'arrive pas à l'adapter à mon nouveau cas.

En Fait j'ai un classeur qui contient plusieurs feuilles crées avec le code dont voici un extrait :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
Sheets("Article").Copy After:=Sheets(ThisWorkbook.Sheets.Count)
   Sheets(Worksheets.Count).Name = TextBox1.Value

ceci génère progressivement des feuilles avec des CodeName de la forme Article1, Article2, Article3, .... Article*n, et les noms des feuilles à mon choix via une userform
jusque là tout va bien.
j'ai également dans mon classeur une feuille synthèse et ;
j'aimerai par macro via un bouton récupérer le nom de toutes les feuilles articles et les mettre dans la colonne A (à partir de A7) de ma feuille Synthèse ensuite sur la même ligne de cet article, j'aimerai également récupérer les valeurs de différentes cellules de la dernière ligne non vide de ces différentes feuilles Article1, Article2, Article3, .... Article*n .

Ci-dessous le code (pris d'un sujet Résolu par ARTURO83) que j'ai essayé d'adapté sans résultat :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
Private Sub CmdValider_Click()
Dim a As Long
    Dim i As Long
    Dim Rep As Byte
    Dim Feuille As Long
    Dim DerLig_F1 As Long, DerLig_F2 As Long
 
    Application.ScreenUpdating = False
    Set f1 = Sheets("Synthèse")
    Rep = MsgBox(" Voulez-vous vraiment faire la Synthèse", vbCritical + vbYesNo + 256, "Attention")
 
    If Rep = vbNo Then
        TxtDateIni.SetFocus
        Exit Sub
     End If
    DerLig_F1 = f1.[B1000000].End(xlUp).Row
    Feuille = 1
    For i = 7 To DerLig_F1
        If Sheets(Feuille).Name <> "Synthèse" Then
            DerLig_F2 = Sheets(Feuille).[B1000000].End(xlUp).Row
 
                f1.Range("A" & i).FormulaLocal = "=Ligne()-6"
                f1.Range("B" & i).Value = Sheets(Feuille).Name
                f1.Range("C" & i).Value = Sheets(Feuille).Cells(DerLig_F2, "C")
                f1.Range("D" & i).Value = Sheets(Feuille).Cells(DerLig_F2, "D")
                f1.Range("E" & i).Value = CDate(Sheets(Feuille).Cells(DerLig_F2, "E"))
                f1.Range("F" & i).Value = Sheets(Feuille).Cells(DerLig_F2, "F")
                f1.Range("G" & i).Value = Sheets(Feuille).Cells(DerLig_F2, "I")
                f1.Range("H" & i).Value = Sheets(Feuille).Cells(DerLig_F2, "B")
                f1.Range("I" & i).Value = Sheets(Feuille).Cells(4, "J")
                f1.Range("J" & i).Value = Sheets(Feuille).Cells(6, "J")
 
        Else: i = i - 1
        End If
        Feuille = Feuille + 1
 
    Next i
    Unload UserForm1
    Set f1 = Nothing
End Sub

Merci d"avance pour votre secours

[Philippe Tulliez]

Bonjour,

ceci génère progressivement des feuilles avec des CodeName de la forme Article1, Article2, Article3, .... Article*n, et les noms des feuilles à mon choix via une userform
jusque là tout va bien.

Attention au vocabulaire utilisé. Sauf erreur de ma part (mauvaise lecture) aucun code affiché dans ta demande n'est un CodeName mais simplement un nom de feuille et la deuxième procédure que tu affiches utilise une variable objet et pas un CodeName

Pour en savoir plus sur le sujet, lire ce billet titré VBA – CodeName d’une feuille Excel

[EDIT]
Maintenant, si c'est obtenir la liste des feuilles répondant à des critères (commence par, se termine par, contient, etc.) comme décrit dans ta demande ci-dessous

j'aimerai par macro via un bouton récupérer le nom de toutes les feuilles articles

alors le code qui suit pourra certainement t'aider

Code d'une fonction qui renvoie une liste des noms de feuille trouvés en fonction de la valeur définie dans l'argument LookUpName

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Function SheetList(Optional LookUpName As String, Optional oWorkbook As Workbook) As Variant
  ' Renvoie la liste des feuilles du classeur défini par l'argument oWorkbook
  ' Author : philippe.tulliez www.magicoffice.be
  ' Version 1.0
  '
  ' Arguments
  ' [LookUpName]  ' Nom à chercher (les caractères génériques sont autorisés. Liste complète si vide
  ' [oWorkbook]   ' Classeur contenant les feuilles à lister[d:=ThisWorkbook]
  ' Déclaration variables
  Dim tbl()
  Dim sht As Worksheet
  Dim Counter As Integer
  ' Affecation des variables
  If oWorkbook Is Nothing Then Set oWorkbook = ThisWorkbook
  '
  For Each sht In oWorkbook.Worksheets
    If IIf(Len(LookUpName), LCase(sht.Name) Like LCase(LookUpName), True) Then
       ReDim Preserve tbl(Counter)
       tbl(Counter) = sht.Name: Counter = Counter + 1
    End If
 Next
 SheetList = tbl
 Set sht = Nothing
End Function

Exemple d'une procédure qui invoque cette fonction

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Sub TestSheetList()
  Dim tbl()
  Dim Count As Variant
  Dim msg As String
  Dim Elem As Integer
  tbl = SheetList("mvt*")
  On Error Resume Next: Count = UBound(tbl): On Error GoTo 0
  If Not IsEmpty(Count) Then
     For Elem = 0 To Count
       msg = msg & vbCrLf & tbl(Elem)
     Next
   Else
     msg = "Tableau vide"
  End If
  MsgBox msg
End Sub

[kedas]

Merci Philippe pour ta proposition,
Étant novice en VBA je ne comprends pas comment exploiter ta proposition pour résoudre mon problème.
concernant cette préoccupation :

Attention au vocabulaire utilisé. Sauf erreur de ma part (mauvaise lecture) aucun code affiché dans ta demande n'est un CodeName mais simplement un nom de feuille et la deuxième procédure que tu affiches utilise une variable objet et pas un CodeName

Voici un aperçu de mes Objets Microsoft excel :

[Philippe Tulliez]

Bonjour,
Oui, effectivement, d'après l'illustration "Article1 à X" sont bien des CodeName mais rien dans le code que tu as publié ne reflète la création de CodeName d'une feuille.

Pourrais-tu reformuler ta question car je n'ai toujours pas compris ce que tu souhaites obtenir comme aide.

• La liste des CodeName des feuilles d'un classeur ?
• Comment renommer le CodeName d'une feuille ?

Plus tu seras clair, plus de chances tu auras d'obtenir une réponse pertinente

[eriiic]

Bonjour à tous,

si j'ai bien compris c'est la liste des codenames qu'il veut.
Un petit programme qui te liste codename en A et name en B (garde ce que tu as besoin) des feuilles dont le codename commence par Article et porte un n° :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
    Dim sh As Worksheet, lig As Long
    lig = 7
    With Sheets("Synthèse")
        For Each sh In Worksheets
            If Left(sh.CodeName, 7) = "Article" And Len(sh.CodeName) > 7 Then
                .Cells(lig, 1) = sh.CodeName
                .Cells(lig, 2) = sh.Name
                lig = lig + 1
            End If
        Next sh
    End With

Corrige la graphie de "Synthèse" si besoin.
eric

[kedas]

Bonjour Eriiic,

Ton code réponds exactement à mon besoin.
il m'a permit après adaptation de solutionner mon problème .

MERCI ENCORE