Discussion :

[dowdow44]

Bonjourà tous,

Je suis actuellement en train de créer un fichier excel pour gérer des réceptions de documents. Voici l'image d'un exemple de tableau :
Date de réception Date suivante
10/04/2012 10/05/2012
20/03/2012 20/04/2012
19/03/2012 19/04/2012

Je voudrais qu'un message d'alerte s'affiche à l'ouverture d'Excel lorsque les "dates suivantes" sont égales à la date d'aujourd'hui + 5 jours et 4,3,2,1 et le jour J.

Pourriez vous m'aider SVP

[Daniel.C]

Bonjour,

Mets cette macro dans le module "ThisWorkbook" (change le nom de la feuille) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Private Sub Workbook_Open()
    Dim c As Range
    With Sheets("Feuil1")
        For Each c In .Range(.[B2], .Cells(.Rows.Count, 2).End(xlUp))
            If Date < c.Value Then
                If c.Value - Date <= 5 Then
                    MsgBox c.Value & " : " & c.Value - Date & " jours"
                End If
            End If
        Next c
    End With
End Sub

[dowdow44]

Merci beaucoup.
Si les dates à tester dans la colonne E, je dois changer quoi?
merci

[Edit]
C'est bon, j'ai trouvé.
Par contre je voudrais afficher un message du genre :

blablablabla pour "valeur cellule A correspondante"

[Daniel.C]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Private Sub Workbook_Open()
    Dim c As Range
    With Sheets("Feuil1")
        For Each c In .Range(.[E2], .Cells(.Rows.Count, 5).End(xlUp))
            If Date < c.Value Then
                If c.Value - Date <= 5 Then
                    MsgBox "blabla " & .Cells(c.Row, 1)
                End If
            End If
        Next c
    End With
End Sub

[fredy45]

Bonjour , et merci de cette discussion concernant ce code.
Cependant j'ai besoin de votre aide , dans cette même configuration
j'aurai besoin d'un code qui permet à partir du 25 du mois et jusqu'au
30 un message qui m'alerte en décomptant les jours soit le 25 " attention
il ne reste que 5 jours pour effectuer ......" et donc arrivé au 30 du mois
il vous reste 1 jour ....... , merci d'avance de votre aide si possible.
Bien cordialement.

[Daniel.C]

Bonjour,

Est-ce tu veux dire du 25 à la fin du mois ou de à partir de 5 jours avant la fin du mois ? Par exemple, en février dernier, le message serait apparu du 23/02/2019 au 28/02/2019. Est-ce qu'il doit apparaître le dernier jour du mois ?

[fredy45]

Bonjour Daniel.c et merci d'avoir consulté ma demande.
OUI, en faite je voudrai comme votre exemple cité , par exemple, en février dernier, le message serait apparu du 23/02/2019 au 28/02/2019.
Si vous pouvez m'aider je serai satisfait , merci d'avance de votre réponse , bien cordialement.

[Daniel.C]

Essaie :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
  If Date <= CDate(Application.EoMonth(Date, 0)) And _
    Date >= CDate(Application.EoMonth(Date, 0) - 5) Then
    MsgBox "il ne reste que " & CInt(Application.EoMonth(Date, 0) - Date) & _
    " jours pour effectuer ......"
  End If

Il peut y avoir un jour de décalage. Rectifie en conséquence.

[fredy45]

Un très grand merci Daniel.C
j'ai changer la date de mon ordi et ça fonctionne
j'ai bien le message attendu , encore un grand merci
et vive ce forum
bien cordialement.