Discussion :

[ameir]

bonjour
j'ai une base de données avec le poids corporel (variable "poids) de milliers de sujets qui on été vus 1 fois par un médecin (V1) ou plusieurs fois (donc plusieurs visites V1, V2, V3 etc).
Chaque visite correspond a une ligne dans ma base SAS.
j'aimerais quand je n'ai pas le poids pour la V1, reporter le poids qui est en V2 sur la ligne correspondant à la V1. mes tentatives jusqu’à présent reportent le poids V2 en V1 mais sur la ligne V2.
Auriez vous une idée ?
Merci !

voici ce que j'ai écrit:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
if numvisite="V1" then PoidsV1=Poids;
if numvisite="V2" then PoidsV2=Poids;
if numvisite="V3" then PoidsV3=Poids;
if numvisite="V4" then PoidsV4=Poids;
if numvisite="V5" then PoidsV5=Poids;
if numvisite="V6" then PoidsV6=Poids;
if numvisite="V7" then PoidsV7=Poids;
if numvisite="V8" then PoidsV8=Poids;
if numvisite="V9" then PoidsV9=Poids;
if numvisite="V10" then PoidsV10=Poids;
if numvisite="V11" then PoidsV11=Poids;
 
if PoidsV1=. and PoidsV2 ne . then PoidsV1=PoidsV2  ; run;

[m.brahim]

Bonjour,
Je te propose cette solution:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
data test;
input pat $ numvis point;
cards;
A 1 5
A 2 .
A 3 6
B 1 .
B 2 4
; run;
 
data test1;
merge test test(where=(point ne .));
by pat;
run;

Cordialement

[ameir]

Merci m.Brahim
c'est un bon début mais là toutes mes données (je n'ai pas que le poids dans ma database, j'ai l'age, les dates de visite, la biologie etc...) sont copiées également. Or je ne veux transférer que la variable poids.
comment la sélectionner ?

[m.brahim]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
data test;
input pat $ numvis point;
cards;
A 1 5
A 2 .
A 3 6
B 1 .
B 2 4
; run;
 
data test1;
merge test test(Keep= pat point where=(point ne .));
by pat;
run;

[ameir]

merci on y est presque mais pas tout a fait.
exemple j'avais

             poidsV1   poidsV2
ID=1 V1     .              .
ID=1 V2     .             85

apres ce codage j'obtiens :

             poidsV1   poids V2
ID=1 V1      .             85
ID=1 V2      .             85

alors que j'aimerais avoir :

             poidsV1    poidsV2
ID=1 V1      85              .
ID=1 V2      .              85

Merci beaucoup pour votre aide !

[m.brahim]

Bonjour Ameir,
Pourrais-tu, stp, me donner l'image complète de la table de départ et les résultats attendus?
Merci
Cordialement

[mgdondon]

Bonjour,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
data test;
  input ID poidsV1 poidsV2 poidsV3;
  cards;
1 . . .
1 . 85 .
2 80 . .
2 . 85 .
2 . . 90
3 . . .
3 . . .
3 . . 90
;
run;

Il est possible de rajouter une étape de test sur la visite.

• Numérotation des visite par sujet

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
data test;
  set test;
  by ID;
  if first.ID then RepNo=1;
  else RepNo=RepNo+1;
  retain RepNo;
run;

• Test

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
data test1;
  merge test test(Keep=ID poidsV2 where=(poidsV2 ne .));
  by ID;
run;
 
data test1;
  set test1;
  if RepNo=1 then do;
    if poidsV1=. then poidsV1=poidsV2;
    poidsV2=.;
  end;
run;

• Une alternative avec la fonction lag (voir Le LAG expliqué à ma fille d'Olivier Decourt)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
proc sort data=test out=test2;
  by ID descending RepNo;
run;
 
data test2;
  set test2;
  poids=lag(poidsV2);
run;
 
data test2(drop=poids);
  set test2;
  if RepNo=1 and poidsV1=. then poidsV1=poids;
run;
 
proc sort data=test2;
  by ID RepNo;
run;

Cordialement,

[hossward]

Bonjour,
Une proposition avec la boucle DOWloop qui consiste en deux boucles DO-UNTIL avec l’instruction SET et l’instruction By :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
 
data Test;
input Id $ numvis Pv1 Pv2 Pv3 Pv4 ;
cards;
1 1 . . . .
1 2 . 3 . .
1 3 . . 7 .
2 1 5 . . .
2 2 . 8 . .
2 3 . . 2 .
2 4 . . . 5
3 1 . . . .
3 2 . 6 . .
; run ;	  
 
data Finale (drop=_:) ;	
do _Cnt=1 by 1 until (last.Id) ;
set Test;
by Id notsorted; 
if first.id and missing(Pv1) then _N=_Cnt+1 ;
if _Cnt=_N then _Pv2=Pv2 ; 	
end ;		  
do until (last.Id) ;
set Test;
by Id notsorted; 
if first.id and missing(Pv1) then Pv1=_Pv2 ; output ; 
end;
run;

Bon Courage
Ward

[ameir]

c'est exactement ce qu'il me fallait merci beaucoup Ward !!!

[ameir]

Bonjour mgdondon,

Merci !!