Discussion :

[erwan.97]

Bonjour,

Dans le cadre d'un développement d'outil, j'ai rencontré un problème, à un moment je dois importer des tables Excel avec une vingtaine de variables. Le soucis est que le nom des colonnes de ces tables contiennent des espaces, des apostrophes et des accents.
Je ne peux pas les changer manuellement car à chaque fois que l'outil sera lancé il faut que les noms soient changés. Est-ce qu'il est possible de le faire via des macros ?

Merci d'avance !

[mgdondon]

Bonjour,

À priori les espaces et caractères spéciaux sont remplacés par le caractère souligné lors de l'import. La solution dépend du contexte et de ce que vous voulez faire.

• S'il n'y a pas trop de tables et pour avoir des noms de variables bien propres, il est possible renommer les variables manuellement, ce qui permet de conserver le caractère souligné (date_nais, age_inter...).

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
data test;
  set test;
  rename fa_on = facon;
run;

• Si vous souhaiter supprimer tous les caractères souligné, vous pouvez utiliser la macro qui suit mais vous aurez un faon au lieu d'une facon, de même pour les caractères accentués.

Cette macro est une adaptation de la macro renamevar proposée dans la discussion Renommer des variables avec une macro SAS.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
%macro renamevar(mvtabin,mvtabout);
  proc contents data=&mvtabin out=work.tempo noprint;
  run;
 
  data _null_;
     set work.tempo;
     call symput('mvvar'||compress(_n_),compress(name)) ;
     call symput('mvmax',compress(_n_)) ;
  run;
 
  data &mvtabout;
    set &mvtabin;
    %do i=1 %to &mvmax;        
      rename &&mvvar&i = %sysfunc(compress(&&mvvar&i,_));
    %end;
  run;
%mend;

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
data test;
  input V_1 V__2 $;
  cards;
1 A
;
run;
 
%renamevar(test,test_out);

• Si vous avez la possibilité d'utiliser des fichiers csv plutôt que des fichiers Excel, une alternative est de corriger les fichiers csv par programme :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
%let accent="ÀÁÂÃÄÅÆÇÈÉÊËÌÍÎÏÐÑÒÓÔÕÖØÙÚÛÜÝÞßàáâãäåæçèéêëìíîïðñòóôõöøùúûýýþÿ";
%let noaccent="AAAAAAACEEEEIIIIDNOOOOOOUUUUYbsaaaaaaaceeeeiiiidnoooooouuuyyby";
 
%macro renamevar_csv(file_in,file_out);
  data _null_;
     infile &file_in;
     file &file_out;
     input;
     if _n_=1 then _infile_=translate(_infile_,&noaccent,&accent);
     put _infile_;
  run;
%mend;
 
%renamevar_csv("d:/temp/test_in.csv","d:/temp/test_out.csv");

(Voir les discussions Modifier un fichier texte avec SAS et Remplacer les caractères accentués).

Cordialement,

[hossward]

Bonjour,
Si tu veux garder le nom des variables avec les espaces et caractères spéciaux, tu peux forcer SAS à les accepter pendant la session avec l'option : OPTIONS VALIDVARNAME=ANY ; . Il faut obligatoirement activer cette option avant de faire l'importation.

Cordialement Ward