Discussion :

[pacolapin]

Bonjour, voila je fais des graphiques sur VBA et j'ai un problème de choix de colonnes car je n'arrive pas à cibler deux colonnes précises. Du coup les deux lignes en rouge sont l'endroit où le choix de la plage de données se fait, j'aimerai pouvoir avoir la colonne B et AC seulement mais j'ai toute les données de la colonne B à la colonne AC quand je crée le schéma. Pourriez - vous m'aider svp, merci d'avance.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
Private Sub Graphiquetransmissiondonnees_Click()
 Const sheDonnéesSource  As String = "Import - Export"
    Const sheGraphiquetransmissiondonnees      As String = "Graphiquetransmissiondonnees"
    Dim chGraph             As Chart
    Dim rPlage              As Range

    ' Définition de la plage des données source du graphique
    DerCel = Sheets(sheDonnéesSource).Range("a65536").End(xlUp)(1).Row
    Set rPlage = Sheets(sheDonnéesSource).Range("B2:B" & DerCel, "AC2:AC" & DerCel)
    

    ' Suppression du graphique si déjà existant
    On Error Resume Next
    Sheets(sheGraphiquetransmissiondonnees).Delete
    On Error GoTo 0
    
    ' Création du graphique
    Set chGraph = Charts.Add
    With chGraph
        ' Type histogramme
        .ChartType = xlLine
        ' Source du graphique
        .SetSourceData Source:=rPlage, PlotBy:=xlColumns
        ' Affichage du titre
        .HasTitle = True
        ' Intitulé
        .ChartTitle.Characters.Text = "Graphique transmission de données en fonction du temps"
        ' Nom de la feuille recevant le graphique
        .Name = sheGraphiquetransmissiondonnees
         ' Axe des catégories
        With .Axes(xlCategory)
        
            ' Inversé
            .ReversePlotOrder = False
            ' Coupe catégorie max
            .Crosses = xlMaximum
            ' Toutes les étiquettes
            .TickLabelSpacing = 1
            ' Titre de l'axe
            ' Affichage du titre
            .HasTitle = True
            .AxisTitle.Text = "le temps en heure : minutes"
             ' Police des étiquettes
             With .TickLabels.Font
               .Bold = False
               .Color = RGB(0, 0, 0)
               .Size = 9
    End With
    End With
    End With

    Sheets(sheGraphiquetransmissiondonnees).Select
End Sub

[EricDgn]

Bonjour,

Il faut ajouter une virgule devant la seconde plage de données (et pas dans le texte du code VBA):

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
    ' Définition de la plage des données source du graphique
    Dim DerCel as Long
    DerCel = Sheets(sheDonnéesSource).Range("a65536").End(xlUp)(1).Row
    Set rPlage = Sheets(sheDonnéesSource).Range("B2:B" & DerCel & ",AC2:AC" & DerCel)

Bonne continuation.