Discussion :

[s.miled]

Bonjour à tous,

Voici 3 heures que je tourne en rond sur un problème, j'espère que l'un d'entre vous pourra m'aider !
On m'a chargé de prendre des fichiers excel de suivi RH existants, et de pouvoir sortir un paquet de statistiques en mettant tout cela dans une BDD Access (donc je n'ai pas le choix sur le format des données d'entrée...).

Voici en gros comment c'est foutu :

Matricule	Nom	Poste	Emploi_reference	Prise de poste
00001	BOB	A001	E001	01/01/18
00001	BOB	A001	E002	01/01/18
00001	BOB	A002	E003	15/02/19

Donc pour un utilisateur j'ai un matricule unique, il ne peut avoir qu'un poste (unique) en même temps, et un poste est composé de 1 à 3 emplois de référence (non uniques). L'info la plus importante pour moi est cet emploi de référence, qui tire toutes les données sur lesquelles je dois faire mes statistiques.
Par exemple : un emploi de référence est relié à un métier. Je veux pouvoir calculer entre Date1 et Date2 tous les utilisateurs qui sont passés d'un métier à un autre, et donc pouvoir sortir tous les changements d'emploi_reference qui ont eu lieu pendant cet intervalle.

A ce stade j'arrive à lister tous mes matricules qui ont été concernés par un changement dans ma plage de temps souhaitée, mais je n'arrive pas à trouver la logique qui me permette d'identifier "Ce matricule est passé du Poste A001 avec les ER E001 et E002, au Poste A002 avec l'ER E003".

A vot'bon coeur, toute aide sera fortement appréciée

[Invité]

bonsoir,

une solution qui mixe sql et vba, si trop lent, passer par une solution vba.

la fonction vba qui transpose les lignes de ER en colonne. Attention, sur la ligne sSQL modifier le nom de la table (2 fois) et si besoin le nom des colonnes
Référencer DAO via VBE.

Code vba :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
 
Public Function getListeER(ByVal Matricule As String, ByVal MinDate As Date, ByVal CurDate As Date) As String
    On Error GoTo fin
    Dim oDb As dao.Database, oRs As dao.Recordset, sSql As String
    sSql = "SELECT Poste, Emploi_Reference & "","" As ER FROM suivi_rh As T1 " & _
           "INNER JOIN (SELECT MAX(Prise_De_Poste) As PP FROM suivi_rh WHERE " & _
           "Matricule ='" & Matricule & "' AND Prise_De_Poste BETWEEN " & _
           Format(MinDate, "\#m/d/yyyy\#") & " AND " & Format(CurDate, "\#m/d/yyyy\#") & ") As T2 " & _
           "ON T1.Prise_De_Poste=T2.PP WHERE Matricule='" & Matricule & "' " & _
           "ORDER BY Emploi_Reference"
    Set oDb = CurrentDb: Set oRs = oDb.OpenRecordset(sSql, dbOpenSnapshot)
    If Not oRs.EOF Then
        getListeER = oRs!poste & " ("
        Do
            getListeER = getListeER & oRs(1): oRs.MoveNext
        Loop Until oRs.EOF
        getListeER = Left$(getListeER, Len(getListeER) - 1) & ")"
    End If
    oRs.Close
fin:
    Set oDb = Nothing: Set oRs = Nothing
End Function

La requete exemple (changer aussi le nom de la table et colonnes si besoin).
Les paramètres mindate et maxdate permettent de cerner la période étudiée

Code SQL :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
 
PARAMETERS MinDate DateTime, MaxDate DateTime;
SELECT Suivi_RH.Matricule, Suivi_RH.Prise_de_Poste, getListeER([Matricule],[MinDate],[prise_de_poste]-1) AS [Du poste et ER], getListeER([Matricule],[MinDate],[prise_de_poste]) AS [Au poste et ER]
FROM Suivi_RH
GROUP BY Suivi_RH.Matricule, Suivi_RH.Prise_de_Poste
HAVING Suivi_RH.Prise_de_Poste<=[MaxDate];

[s.miled]

Merci, je teste ça !!