Discussion :

[JehanLePetit]

Bonjour à tous, j'ai besoin de vos lumières !

Ma base Access comporte environs 700 objets (tables, requêtes, rapports...) avec des tables utilisant des données externes.
J'ai créé une table "Audit" que je remplis via VBA qui liste tous ces objets.

L'étape suivante, c'est, pour chaque objet listé dans cette table "Audit", de définir "les objets qui dépendent de lui" ainsi que " les objets dont il dépend".
L'outil Access "dépendances d'objet" (dans Outils de base de données) fait le job...un par un.
Savez-vous comment automatisé cela par VBA ?
Merci d'avance.

[EricDgn]

Bonjour,
En recherchant sur internet:
- cette page pour lister les objets.
- cette page pour lister les dépendances d'un objet, dont je donne le code ci-dessous (testé ok).

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
'--- https://flylib.com/books/en/1.129.1.105/1/
Public Sub ShowDependencies(intType As AcObjectType, strName As String)
   ' Show dependency information for the specified object
   Dim AO As AccessObject
   Dim AO2 As AccessObject
   Dim DI As DependencyInfo
   On Error GoTo HandleErr
   ' Get the AccessObject
   Select Case intType
     Case acTable
        Set AO = CurrentData.AllTables(strName)
       Debug.Print "Table: ";
     Case acQuery
       Set AO = CurrentData.AllQueries(strName)
       Debug.Print "Query: ";
     Case acForm
       Set AO = CurrentProject.AllForms(strName)
       Debug.Print "Form: ";
     Case acReport
       Set AO = CurrentProject.AllReports(strName)
       Debug.Print "Report: ";
   End Select
   Debug.Print strName
   ' Get the dependency info
   Set DI = AO.GetDependencyInfo()
   ' Print results
   If DI.Dependencies.Count = 0 Then
     Debug.Print "This object does not depend on any objects"
   Else
     Debug.Print "This object depends on these objects:"
     For Each AO2 In DI.Dependencies
       Select Case AO2.Type
         Case acTable
           Debug.Print "  Table: ";
         Case acQuery
           Debug.Print "  Query: ";
         Case acForm
           Debug.Print "  Form: ";
         Case acReport
           Debug.Print "  Report: ";
       End Select
       Debug.Print AO2.Name
     Next AO2
   End If
   If DI.Dependants.Count = 0 Then
     Debug.Print "No objects depend on this object"
   Else
     Debug.Print "These objects depend on this object:"
     For Each AO2 In DI.Dependants
       Select Case AO2.Type
         Case acTable
           Debug.Print "  Table: ";
         Case acQuery
           Debug.Print "  Query: ";
         Case acForm
           Debug.Print "  Form: ";
         Case acReport
           Debug.Print "  Report: ";
       End Select
       Debug.Print AO2.Name
     Next AO2
   End If
ExitHere:
   Exit Sub
HandleErr:
   MsgBox "Error " & Err.Number & ": " & Err.Description, vbCritical
   Resume ExitHere
End Sub

Bonne continuation.