Discussion :

[Cereal123]

Bonjour,

Dans l'écran de situation de commande de client (écran SOHD), je voudrait afficher pour chaque ligne, 2 champs issus de la ligne de commande de vente correspondante :
- le champ standard SORDERQ.SOPLIN
- Un champ spécifique SORDERQ.ZNOLIGNE

J'ai ajouté ces champs à l'écran, mais je ne sais pas comment récupérer les valeurs correspondantes.
Comment pointer sur la bonne ligne de SORDERQ ?

Merci de votre aide.
C.

[Cereal123]

Je remets le sujet sur la pile car je n'ai toujours pas réussi à m'en sortir.

Mon problème est que dans l'écran "Situation de commande", il peut y avoir plusieurs ligne du tableau qui correspond à une même ligne de commande de vente. Par exemple si celle-ci a été livrée en plusieurs fois.
Mais dans le tableau, il n'est pas fait explicitement référence à la ligne de commande d'origine.

Conséquence, la valeur de [SOHD]NOLIGN ne correpond pas à la valeur de [SOH4]NOLIGN.

Un coup de pouce serait grandement apprécié...

C.

[hado34]

À mon avis dans cet écran il faut mettre un specifique qui boucle sur les lignes une fois le tableau charge par le standard

pour chaque ligne pour lesquelles le champ itmref/qty sont renseignés récupère le numéro de ligne et affiche.

car en gros le standard parcours le tableau de SOH4 et pour chaque ligne va chercher les livraisons/bon prepa/factures

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
#------------------------------------------------------------------------------#
# Chargement du masque visualisation commande
$CHARGE_SDI
 
Raz [M] 
Raz I,J
 
For I=0 To [M:SOH4]NBLIG-1
   [M]ITMREF(J) = [M:SOH4]ITMREF(I)
   [M]QTY(J)    = [M:SOH4]QTY(I)
   [M]ALLQTY(J) = [M:SOH4]ALLQTY(I)
   [M]SHTQTY(J) = [M:SOH4]SHTQTY(I)
   [M]SOQSTA(J) = [M:SOH4]SOQSTA(I)
   [M]SAU(J)    = [M:SOH4]SAU(I)
   [M]FMINUM(J) = [M:SOH4]FMINUM(I)  
   [M]FMI(J)    = [M:SOH4]FMI(I)  
   If [M:SOH0]SOHCAT = 3
      For [SID]SID0 Hint Key SID1
&                   Where [SID]BPCINV=[M:SOH1]BPCINV & [SID]SALFCY=[M:SOH0]SALFCY &
&                         [SID]SOHNUM=[M:SOH0]SOHNUM & [SID]SOPLIN=[M:SOH4]SOPLIN(I)
         If [F:SIV]NUM<>[F:SID]NUM
            Read [SIV]SIV0=[F:SID]NUM
            If fstat Raz [F:SIV] Endif 
         Endif

[Cereal123]

Merci hado34 pour cette suggestion et pour l'extrait de code.

J'ai commencé à l'adapter pour y faire appel à l'ouverture de l'écran SOHD ("Situation de commande").

Je comptais y faire appel en ajoutant un bloc $ACTION dans le code SPE et une action "LIENS" mais cette action ne semble pas appelée par l'écran.
D'ailleurs, aucune action ne semble appelée car je ne passe pas dans mon bloc :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
$ACTION
#Debug pour afficher les actions appelées
Infbox ACTION
 
Case ACTION
  When "LIENS"   : Gosub LIENS
 When Default
Endcase
Return

Où faut-il insérer l'appel au code spé ?

C.

[hado34]

doit etre place dans le traitement SPE XYTRTVENFEN de l action TRTORDETA

je dirais qu il faudrait une action DEBUT dans votre spe

faire un appel au standard

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
 
$DEBUT
Call DEBUT from TRTVENFEN
GPE=1 #pour ne pas refaire standard apres le SPE
 
#parcours du tableau du SOHD et pour chaque ligne ou ITMREF est affiche affiche votre numero de ligne en spe
 
Return

[Cereal123]

Merci de cette précision, je n'aurai pas trouvé XYTRTVENFEN tout seul !

Pour info, l'action $DEBUT n'existe pas dans ce type de traitement. j'ai donc ajouté mon code dans l'action $AV_CHOIX.

[Cereal123]

Pour info, voici le code qui fonctionne en ajout dans $AV_CHOIX :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
 
$ACTION
 
Case ACTION
  When "AV_CHOIX"     : Gosub AV_CHOIX
 When Default
Endcase
Return
 
 
$AV_CHOIX
 
Local Integer LIG_CDE
Local Integer LIG_SIT
 
#parcours du tableau du SOHD et pour chaque ligne ou ITMREF est affiche affiche votre numero de ligne en spe
Raz [L]LIG_CDE,[L]LIG_SIT
 
For [L]LIG_CDE=0 To [M:SOH4]NBLIG-1
    If [M:SOHD]ITMREF([L]LIG_SIT)<>"" Then
        [M:SOHD]SOPLIN([L]LIG_SIT) = [M:SOH4]SOPLIN([L]LIG_CDE)
        Affzo [M:SOHD]SOPLIN([L]LIG_SIT)
        [M:SOHD]ZNOLIG([L]LIG_SIT) = [M:SOH4]ZNOLIG([L]LIG_CDE)
        Affzo [M:SOHD]ZNOLIG([L]LIG_SIT)
    Endif
    [L]LIG_SIT += 1
 
    If [L]LIG_SIT>[M:SOHD]NBLIG-1 : Break : Endif
    While [M:SOHD]ITMREF([L]LIG_SIT)=""  
       [M:SOHD]SOPLIN([L]LIG_SIT) = 0
        Affzo [M:SOHD]SOPLIN([L]LIG_SIT)
       [M:SOHD]ZNOLIG([L]LIG_SIT) = ""
        Affzo [M:SOHD]ZNOLIG([L]LIG_SIT)
       [L]LIG_SIT += 1
       If [L]LIG_SIT>[M:SOHD]NBLIG-1 : Break : Endif
    Wend
Next [L]LIG_CDE
 
Return