Discussion :

[Sa Mariam]

Bonsoir, c'est moi encore une fois
J'ai lancé un code pour rechercher un mot sur ma feuille et j'ai remarqué que lorsqu'il détecte une ligne vide il arrête la recherche genre il ne saute pas la ligne vide pour continuer la recherche jusqu’à la fin de la page.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Sub Rechercher()
 
    'Procédure permettant de réaliser une recherche que la colonne Nom
    Columns("B:B").Select
    Selection.Find(What:=Feuil1.Range("Nom"), After:=ActiveCell, LookIn:=xlValues, _
        Lookat:=xlPart, SearchOrder:=xlByRows, SearchDirection:=xlNext, _
        MatchCase:=False, SearchFormat:=False).Select
 
End Sub

Merci d'avance pour votre aide

[mercatog]

Pour l'utilisation de la méthode find, il est préférable de procéder comme ceci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Sub Recherche()
Dim N As Long
Dim c As Range
Dim Nom As String
 
Nom = Feuil1.Range("Nom").Value
If Nom <> "" Then
    With Worksheets("nom de ta veuille")
        N = .Cells(.Rows.Count, 2).End(xlUp).Row
        Set c = .Range("B2:B" & N).Find(Nom, LookIn:=xlValues, Lookat:=xlPart)
        If Not c Is Nothing Then
            MsgBox c.Address
            'suite de ton code
        End If
    End With
End If
End Sub

[anasecu]

Bonsoir,

j'ai remarqué que lorsqu'il détecte une ligne vide il arrête la recherche genre il ne saute pas la ligne vide pour continuer la recherche jusqu’à la fin de la page.

Je pense que tu as mal "remarqué" car tu peux même rechercher les lignes vides.

Par contre ta procédure est brute et elle plante si tu n'as pas de résultat. Comme ceci cela serait plus propre même si ton activecell risque de te poser des soucis et il vaudrait mieux le remplacer par [B1]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Sub Rechercher()
 
'Procédure permettant de réaliser une recherche que la colonne Nom
Dim pos As Range
Set pos = Columns("B:B").Find(What:=Feuil1.Range("Nom"), After:=ActiveCell, LookIn:=xlValues, _
    Lookat:=xlPart, SearchOrder:=xlByRows, SearchDirection:=xlNext, _
    MatchCase:=False, SearchFormat:=False)
If pos Is Nothing Then
    MsgBox "nom inexistant"
Else
    pos.Activate
    ' ton traitement
End If
End Sub

[Sa Mariam]

Bonsoir, ça donne toujours le même résultat, le code ignore les valeurs stocké après une ligne vide

[mercatog]

Tu as une seule valeur trouvée ou plusieurs?

[Sa Mariam]

Plusieurs valeurs, je les classe sous format fe tableau sur l'interface

[mercatog]

Find trouve uniquement la première occurrence trouvée selon les paramètres.

Regarde l'aide sur Range.Find, tu trouves un exemple explicite pour trouver toutes les occurrences.

[Sa Mariam]

Par contre ça me donne tous les résultats disponibles sur ma feuille sauf que ça s'arrete lorsqu'il ya une ligne vide, donc je veux la programmer pour rechercher sur toute la page

[mercatog]

Je n'ai jamais rencontré ce que tu affirmes.

J'ai même testé maintenant ce code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Sub Recherche()
Dim Nom As String, Prem As String
Dim N As Long
Dim c As Range
 
Nom = Feuil1.Range("Nom").Value
If Nom <> "" Then
    With Worksheets("Feuil1")
        N = .Cells(.Rows.Count, 2).End(xlUp).Row
        Set c = .Range("B1:B" & N).Find(Nom, LookIn:=xlValues, Lookat:=xlPart)
        If Not c Is Nothing Then
            Prem = c.Address
            Do
                MsgBox c.Address
 
                Set c = .Range("B1:B" & N).FindNext(c)
            Loop While Not c Is Nothing And c.Address <> Prem
        End If
    End With
End If
End Sub

[Sa Mariam]

Meme avec ce code ça n'a pas marché :'(

[mercatog]

Tu peux mettre un extrait du fichier sans donnés confidentielles.

C'est vraiment étrange

[Sa Mariam]

Bonjour, vu que mon fichier est un peu confidentiel ça concerne mon boulot, je vous ai envoyé celui là du même principeVBA - Formulaire Multi Recherche.xlsm

Vous pouvez remarquer que le code ne détecte pas les valeurs stocké après la ligne vide


Merci toujours pour votre aide

[mercatog]

Je ne sais pas pourquoi tu cherche le truc sur Find alors que tu utilises le filtre avancé

Tu utilise Range("A5").currentregion. bien sur elle s'arrête à la première ligne vide.

Utilise ceci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Sub Filtrer()
Dim LastLig As Long
 
'Procédure permettant de filtrer les données à partir de la zone de critère
With Feuil1
    LastLig = .Cells(.Rows.Count, 1).End(xlUp).Row
    .Range("A5:K" & LastLig).AdvancedFilter Action:=xlFilterCopy, CriteriaRange:= _
                                            .Range("N5:N6"), CopyToRange:=.Range("P5:Z5"), Unique:=False
End With
End Sub

[Patrice740]

Bonjour,

Bonjour, vu que mon fichier est un peu confidentiel ça concerne mon boulot, je vous ai envoyé celui là du même principeVBA - Formulaire Multi Recherche.xlsm

Commences par supprimer tous les .Select de ton code (utilises les objets).

[Sa Mariam]

Re-Bonsoir, Je suis pas trop familiarisée avec les commandes VBA.

ça a marché

Milles Merci encore une fois

Bonne soirée