MySQL ODBC VBScript OK, HTA erreur!

Invité · 21/03/2019, 14h13

Bonjour,
J’ai un VBScript qui fonctionne très bien après avoir installé et configuré le connecteur ORBD adéquat.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

StrConnectionString = "DRIVER={MySQL ODBC 8.0 ANSI Driver}; SERVER=server;PORT=3306;DATABASE=locationposte;UID=read;PASSWORD=read;OPTION=3"

Quand je porte mon script en HTA j’ai cette erreur :

Erreur : [Microsoft][Gestionnaire de pilotes ODBC] Source de données introuvable et nom de pilote non spécifié

J’ai tester avec les connecteurs 32 et 64 bits idem
Paramétré la source de donnée utilisateur ou système pas mieux.
Avez-vous une idée ?

**ProgElecT** · 21/03/2019, 17h00

Salut

Il faudrait un peu plus de code, l'endroit ou est déclaré la ligne dans l'ensemble du code a peut être (sûrement) son importance.

**omen999** · 21/03/2019, 17h05

bonjour,

classiquement, ce genre de message survient quand mshta et le connecteur ne sont pas accordés (64/32bits)

maintenant, si tu es sûr d'avoir testé les connecteurs dans les deux versions avec le même mshta, je ne vois pas.

Invité · 21/03/2019, 18h11

Voici le code:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
<HTML>
        <HEAD>
        <TITLE> Un HTA </TITLE>
                <HTA:APPLICATION
         ApplicationName = "Test_MySQL"
         Id="Test_MySQL"
                >
   </HEAD>
<SCRIPT language="VBScript" type="text/VBScript" >
OPTION Explicit
 
        Dim ObjConnection
        Dim ObjRecordset
        Dim StrConnectionString
        Dim ObjMySQL
        Dim PrinterName 
 
Sub Window_Onload()
 
    self.ResizeTo 600,600   
 
End Sub
 
Sub run
 
        PrinterName = TxtPrinterName.value
 
        Set ObjConnection = CreateObject("ADODB.Connection")
        Set ObjRecordset = CreateObject("ADODB.Recordset")
 
        StrConnectionString = "DRIVER={MySQL ODBC 8.0 ANSI Driver}; SERVER=IP_SERVEUR;PORT=3306;DATABASE=locationposte;UID=read;PASSWORD=read;OPTION=3"
 
        ObjConnection.ConnectionString = StrConnectionString
        ObjConnection.Open  
 
        ObjMySQL = "SELECT * FROM location WHERE (`DefaultPrinter` LIKE '%" & PrinterName & "%')"
 
        ObjRecordset.Open ObjMySQL, ObjConnection
 
    Dim oOption, V 
    'vide la liste
    For V = LstImpr.length To 0 Step -1: LstImpr.Remove (V): Next
    V=0
        While Not ObjRecordset.EOF
                'ajoute les noms à la liste 
                Set oOption = window.Document.createElement("OPTION")
                oOption.Text = ObjRecordset.fields("ClientName")
                oOption.Value = "Option " & V
                LstImpr.Add (oOption)
        V = V + 1
                ObjRecordset.MoveNext
    Wend
        ObjRecordset.Close: Set ObjRecordset = Nothing
        ObjConnection.Close: Set ObjConnection = Nothing
    If V = 0 Then
        Set oOption = window.Document.createElement("OPTION")
        oOption.Text = "Auncune IMPRIMANTE disponnible"
        oOption.Value = V
        LstImpr.Add (oOption)
        LstImpr.disabled = "disabled"
        Else
        LstImpr.disabled = ""
                MsgBox V & " Client(s) trouvée(s)"
        End If
 
End sub
  
 </SCRIPT>
        <body>
                <input type="text" name="TxtPrinterName" value=""></p>
                <input id=runbutton  class="button" type="button" value="GO" onClick="run"><p>
 
                <SELECT name="LstImpr" Id="LstImpr"  disabled="disabled"> </SELECT>
 
   </Body>
</HTML>

**ProgElecT** · 21/03/2019, 19h19

Essais de passer en Unicode plutôt que ANSI

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

StrConnectionString = "DRIVER={MySQL ODBC 8.0 Unicode Driver}; SERVER=IP_SERVEUR;PORT=3306;DATABASE=locationposte;UID=read;PASSWORD=read;OPTION=3"

Invité · 22/03/2019, 09h29

Pas mieux avec le pilote Unicode !

Impossibilité de configurer le pilote ODBC 32 bits sur mon OS 64 bits via le Panneau de configuration => Outils d’administration => Sources de données (ODBC) le pilote n'apparait pas dans la liste.

Solution de contournement (Bidouille ou pas !!!!):
Depuis l’application « odbcad32 » disponible en C:\Windows\SysWOW64.
Sous l’onglet : Sources de données système => Ajouter.
Sélectionner le bon pilote dans la liste et le configurer.
Et la ça fonctionne.

**omen999** · 22/03/2019, 11h05

ce n'est pas une question de bidouille
c'est simplement que Windows ne propose pas nativement de pilote ODBC MySQL
et qu'il t'appartient de l'installer

normalement le répertoire "Outils d'administration" des Windows 64bits contient deux liens distincts
pour gérer les sources de données ODBC 32 ou 64bits

si tu as correctement installé la version 32bits du driver, l'appel doit se faire
impérativement avec la version 32bits de mshta.exe dans "C:\Windows\SysWOW64"

Invité · 22/03/2019, 14h03

Envoyé par omen999

normalement le répertoire "Outils d'administration" des Windows 64bits contient deux liens distincts
pour gérer les sources de données ODBC 32 ou 64bits

Il semblerait que ce ne soit pas le cas sous Windows 7 64bits

MySQL ODBC VBScript OK, HTA erreur!

VBScript

Discussions similaires

Partager

Partager