Ajout image dans le corps du message

**Math71** · 11/03/2019, 16h52

Bonjour,

Je viens vers vous car j'ai besoin d'envoyer des mails contenant une image par programmation.

J'avais trouvé un lien sur ce site avec un exemple en VBA mais je ne retrouve plus le lien.

Je me rappelle seulement qu'ils parlaient de l'image en pièce-jointe et du CID.

J'ai seulement besoin du code pour ça, et quel que soit le langage, je serait capable de l'adapter avec le langage utilisé.

**Oliv-** · 11/03/2019, 18h00

Bonjour,
Il y a plusieurs méthodes en voici une:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Sub new_mail_with_embedded()
'---------------------------------------------------------------------------------------
' Procedure : new_mail_with_embedded
' Author    : Oliv
' Date      : 11/03/2019
' Purpose   :
'---------------------------------------------------------------------------------------
'
Dim objmail As MailItem
Dim pj As Attachment, pj2 As Attachment
    Set objmail = Application.CreateItem(olMailItem)
    Set pj = objmail.Attachments.add("C:\Users\Public\Pictures\genou.png")
    Set pj2 = objmail.Attachments.add("C:\Users\Public\Pictures\pouce.jpg")
 
    objmail.BodyFormat = olFormatHTML
    objmail.HTMLBody = "<html><p>This is a picture.</p>" & _
            "<img src='cid:" & pj.FileName & "'><p>This is one more.</p><img src='cid:" & pj2.FileName & "' >"
    objmail.Display
    'objMail.Close olSave
    Set objmail = Nothing
End Sub

**Math71** · 11/03/2019, 18h04

Je n'ai pas de tester avant demain matin, mais j'ai une question
Le pj.filename contient le nom du fichier avec l'extension? Ou un code specifique?

Car j'ai deja essaye avec cid:nom.png et dans le mail recu, je n'ai pas l'image

**Math71** · 13/03/2019, 10h10

Bonjour,

désolé pour le retard, je travaillait sur autre chose.

Le code que tu m'as donné ne fonctionne pas.

Quand je vais dans l'inspecteur pour voir le code généré du mail.

J'ai une simple balise <img> vide.

Je n'ai meme pas la src et je ne comprends pas pourquoi.

**Oliv-** · 13/03/2019, 10h25

Salut,
Utilises-tu bien le code tel quel ? (avec des chemins d'images existantes bien sûr)

Chez moi cela fonctionne très bien, quelle est ta version de OL ?

**Math71** · 13/03/2019, 10h38

J'utilise office 365, donc je suppose que j'ai office 2019.

Voila le code que j'ai, que j'ai du un peu modifier.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
 
Sub Main()
        Dim objmail As MailItem
        Dim pj As Attachment
 
        Dim outlookApp As Application
        outlookApp = CreateObject("Outlook.Application")
 
        objmail = outlookApp.CreateItem(olMailItem)
        pj = objmail.Attachments.Add("S:\macarte.jpg")
 
        objmail.To = "************"
        objmail.CC = "********"
 
        objmail.BodyFormat = olFormatHTML
        objmail.HTMLBody = "<html><p>This is a picture.</p>" &
                    "<img src='cid:" & pj.FileName & "'/>"
        objmail.Send()
        'objMail.Close olSave
        objmail = Nothing
    End Sub

**Oliv-** · 13/03/2019, 10h51

Le objmail.Display est capital !

**Math71** · 13/03/2019, 11h20

En effet c'est mieux, mais par contre, l'image n'est pas trouvé.

Nom : 2019-03-13_11h19_27.png
Affichages : 627
Taille : 1,9 Ko

Et pourtant j'ai bien rajouter le display.

Je remet le code au cas ou.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
 
Dim objmail As MailItem
        Dim pj As Attachment
 
        Dim outlookApp As Application
        outlookApp = CreateObject("Outlook.Application")
 
        objmail = outlookApp.CreateItem(olMailItem)
        pj = objmail.Attachments.Add("S:\macarte.jpg")
 
        objmail.To = "**************"
        objmail.CC = "**********"
        objmail.Subject = "test"
 
        objmail.BodyFormat = olFormatHTML
        objmail.HTMLBody = "<html><p>This is a picture.</p>" &
                    "<img src='cid:" & pj.FileName & "'/>"
        objmail.Display()
        objmail.Send()
        'objMail.Close olSave
        objmail = Nothing

**Oliv-** · 13/03/2019, 12h19

Ton code ne peut pas marcher tel que publié !

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
Sub TEST()
 
Dim objmail As MailItem
        Dim pj As Attachment
 
        Dim outlookApp As Application
        Set outlookApp = CreateObject("Outlook.Application")
 
        Set objmail = outlookApp.CreateItem(olMailItem)
        Set pj = objmail.Attachments.add("S:\macarte.jpg")
 
'        objmail.To = "**************"
'        objmail.CC = "**********"
        objmail.Subject = "test"
 
        objmail.BodyFormat = olFormatHTML
        objmail.HTMLBody = "<html><p>This is a picture.</p>" & _
                    "<img src='cid:" & pj.FileName & "'/>"
        objmail.Display
        'objmail.Send
        'objMail.Close olSave
        'objmail = Nothing
End Sub

**Math71** · 13/03/2019, 12h46

Je comprends pas
Pourquoi enlever le send et les destinataires?

Cette technique fonctionne seulement si le mail est envoye par l'utilisateur?

Car j'ai besoin de l'envoyer automatiquement.

EDIT : Même avec ton code, et l'envoie par l'utilisateur, l'image ne s'affiche toujours pas.

Qu'est ce que je ne comprends pas la dedans ?

**Oliv-** · 13/03/2019, 13h50

Le send je l'ai juste commenté pour test en fait c'est le

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
      outlookApp = CreateObject("Outlook.Application")
 
        objmail = outlookApp.CreateItem(olMailItem)
        pj = objmail.Attachments.Add("S:\macarte.jpg")

remplacé en

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
  Set outlookApp = CreateObject("Outlook.Application")
 
        Set objmail = outlookApp.CreateItem(olMailItem)
        Set pj = objmail.Attachments.add("S:\macarte.jpg")

Voici une autre méthode

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
Sub NewMessage_With_Embedded_Dmitry()
    Dim olApp As Outlook.Application
    If Application.Name = "Outlook" Then
        Set olApp = Application
    Else
        Set olApp = CreateObject("outlook.application")
    End If
    Set NS = olApp.Session
 
    Set objOutlookMsg = olApp.CreateItem(olMailItem)
 
    Set objOutlookRecip = objOutlookMsg.Recipients.add("test@toto.com")
    objOutlookRecip.Type = olTo
    objOutlookMsg.Subject = "test"
 
    ' add graphic as attachment to Outlook message
    Set colAttach = objOutlookMsg.Attachments
    Set l_Attach = colAttach.add("C:\Users\Public\Pictures\pouce.jpg")
    l_Attach.propertyAccessor.SetProperty "http://schemas.microsoft.com/mapi/proptag/0x370E001F", "image/jpeg"
    'Change From 0x370eE001E
    l_Attach.propertyAccessor.SetProperty "http://schemas.microsoft.com/mapi/proptag/0x3712001F", "myident"
    'Changed from 0x3712001E
    objOutlookMsg.propertyAccessor.SetProperty "http://schemas.microsoft.com/mapi/id/{00062008-0000-0000-C000-000000000046}/8514000B", True
    'Set body format to HTML
    objOutlookMsg.BodyFormat = olFormatHTML
    objOutlookMsg.HTMLBody = "<html><p>This is a picture.</p>" & _
            "<img src='cid:myident' >"
 
    objOutlookMsg.Save
    objOutlookMsg.Display
    'objOutlookMsg.Send
End Sub

**Math71** · 13/03/2019, 14h07

Ah okay.

Sinon tu utilises quel langage ? du VBA ? Car VS me dit que Set/Let ne sont plus prise en charge. J'ai VS 2017.

C'est surement la, la différence.

**Oliv-** · 13/03/2019, 20h37

Ah oui je code en vba

**Math71** · 14/03/2019, 09h30

Pour le coup, je ne pense que cela change grand chose pour le CID.

Je vais continuer a chercher, sinon tu ne connais pas une autre solution pour le faire.

**Oliv-** · 14/03/2019, 10h22

As tu vu la dernière partie de ma réponse ?
https://www.developpez.net/forums/d1.../#post10821604

il y a encore une autre solution, c'est d'utiliser .WORDEDITOR et d'insérer l'image comme pour une macro WORD.

**Math71** · 14/03/2019, 10h26

Non je l'avais pas vu, mais j'ai trouvé cette solution de moi même x)

En tout cas merci beaucoup.

Voici le code qui fonctionne ne VB.NET avec l'objet COM.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
 
        Dim objmail As MailItem
        Dim pj As Attachment
 
        Dim outlookApp As Application
        outlookApp = CreateObject("Outlook.Application")
 
        objmail = outlookApp.CreateItem(olMailItem)
        pj = objmail.Attachments.Add("**********\cgu.png")
 
        Dim contentID As String = "cgu"
 
        pj.PropertyAccessor.SetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E", contentID)
 
        objmail.To = "****************"
        objmail.CC = "*************"
        objmail.Subject = "test"
 
        objmail.BodyFormat = olFormatHTML
        objmail.HTMLBody = "<html><p>This is a picture.</p>" &
                    "<img src='cid:" & contentID & "'/>"
        objmail.Display()
        objmail.Send()
        'objMail.Close olSave
        'objmail = Nothing

Ajout image dans le corps du message

Outlook

Discussions similaires

Partager

Partager