IdentifiantMot de passe
Loading...
Mot de passe oublié ?Je m'inscris ! (gratuit)
Navigation

Inscrivez-vous gratuitement
pour pouvoir participer, suivre les réponses en temps réel, voter pour les messages, poser vos propres questions et recevoir la newsletter

Contribuez Pascal Discussion :

Simple calendrier au format texte


Sujet :

Contribuez Pascal

  1. #1
    Rédacteur/Modérateur

    Avatar de Roland Chastain
    Homme Profil pro
    Enseignant
    Inscrit en
    décembre 2011
    Messages
    3 828
    Détails du profil
    Informations personnelles :
    Sexe : Homme
    Âge : 48
    Localisation : France, Moselle (Lorraine)

    Informations professionnelles :
    Activité : Enseignant

    Informations forums :
    Inscription : décembre 2011
    Messages : 3 828
    Points : 13 685
    Points
    13 685
    Billets dans le blog
    8
    Par défaut Simple calendrier au format texte
    Bonjour !

    Je souhaite partager avec vous un petit programme que j'ai fait aujourd'hui, une application console qui produit un simple calendrier au format texte.

    Si j'ai le temps, j'ajouterai des options.

    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    3
    4
    5
    6
    7
    8
    9
    10
    11
    12
    13
    14
    15
    16
    17
    18
    19
    20
    21
    22
    23
    24
    25
    26
    27
    28
    29
    30
    31
    32
    33
    34
    35
    36
    37
    38
    39
    40
    41
    42
    43
    44
    45
    46
    47
    48
    49
    50
    51
    52
    53
    54
    55
    56
    57
    58
    59
    60
    61
    62
    63
    64
    65
    66
    67
    68
    69
    70
    71
    72
    73
    74
    75
    76
    77
    78
    79
    80
    81
    82
    83
    84
    85
    86
    87
    88
    89
    90
    91
    92
    93
    94
    95
    96
    97
    98
    99
    100
    101
    102
    103
    104
    105
    106
    107
    108
    109
    110
    111
    112
    113
    114
    115
    116
    117
    118
    119
    120
    121
    122
    123
    124
    125
    126
    127
    128
    129
    130
    131
    132
     
    { Calendrier. }
     
    {.$DEFINE USETHLIST}
     
    uses
      SysUtils, Classes{$IFDEF USETHLIST}, ThList{$ENDIF};
     
    const
      NOM: array[1..12] of string = (
        'Janvier',
        'Février',
        'Mars',
        'Avril',
        'Mai',
        'Juin',
        'Juillet',
        'Août',
        'Septembre',
        'Octobre',
        'Novembre',
        'Décembre'
      );
      NOMSJOURS = ' Di Lu Ma Me Je Ve Sa';
     
    function JourSemaine(const annee, mois, jour: word; const julien: boolean = FALSE): word;
    {
      Jour de la semaine pour une date donnée.
      Le résultat est donné sous la forme d'un nombre entier de zéro à six, où zéro signifie dimanche.
      https://www.tondering.dk/claus/cal/chrweek.php
    }
    var
      a, y, m: word;
    begin
      a := (14 - mois) div 12;
      y := annee - a;
      m := mois + 12 * a - 2;
      result := jour + y + y div 4 + 31 * m div 12;
      if julien
      then result := result + 5                      { Pour une date du calendrier julien. }
      else result := result - y div 100 + y div 400; { Pour une date du calendrier grégorien. }
      result := result mod 7;
    end;
     
    function Bissextile(const annee: word): boolean;
    begin
      result := (annee mod 4 = 0) and ((annee mod 100 <> 0) or (annee mod 400 = 0));
    end;
     
    function NombreCaracteres(s: string): integer;
    begin
      s := {$IFDEF USETHLIST}ThList.RemoveAccent(s){$ELSE}Utf8ToAnsi(s){$ENDIF};
      result := Length(s);
    end;
     
    function LigneTitre(const s: string; const n: integer): string;
    var
      i, j: integer;
    begin
      i := n - NombreCaracteres(s);
      j := i div 2;
      result := Concat(StringOfChar(' ', j), s, StringOfChar(' ', i - j));
    end;
     
    function Calendrier(const annee: word): TStringList;
    var
      nj: array[1..12] of integer = (31, 28, 31, 30, 31, 30, 31, 31, 30, 31, 30, 31);
     
      procedure ConstruireListeMois(const mois: word; lst: TStrings);
      var
        jm: word;
        s: string;
        js: integer;
        i: integer;
      begin
        lst.Append(LigneTitre(NOM[mois], 7 * 3));
        lst.Append(NOMSJOURS);
        js := JourSemaine(annee, mois, 1);
        s := StringOfChar(' ', 3 * js);
        for jm := 1 to nj[mois] do
          s := Concat(s, Format('%3d', [jm]));
        s := Concat(s, StringOfChar(' ', (42 - nj[mois] - js) * 3));
        for i := 1 to 6 do
          lst.Append(Copy(s, 7 * 3 * Pred(i) + 1, 7 * 3));
      end;
     
    var
      listes: array [1..12] of TStringList;
      i, j, k: integer;
      s: string;
    begin
      if Bissextile(annee) then
        Inc(nj[2]);
     
      result := TStringList.Create;
     
      for i := 1 to 12 do
      begin
        listes[i] := TStringList.Create;
        ConstruireListeMois(i, listes[i]);
      end;
     
      result.Append('');
      result.Append(LigneTitre(Format('Année %d', [annee]), 3 * (7 * 3 + 3)));
     
      for i := 0 to 3 do
      begin
        result.Append('');
        for j := 0 to 7 do
        begin
          s := '';
          for k := 1 to 3 do
            s := Concat(s, '   ', listes[k + i * 3][j]);
          result.Append(s);
        end;
      end;
     
      for i := 1 to 12 do
        listes[i].Free;
    end;
     
    var
      annee: word;
      cal: TStringList;
     
    begin
      annee := StrToIntDef(ParamStr(1), CurrentYear);
      cal := Calendrier(annee);
      WriteLn(cal.Text);
      cal.SaveToFile(Format('calendrier%d.txt', [annee]));
      cal.Free;
    end.
    Fichiers attachés Fichiers attachés

  2. #2
    Membre éclairé

    Homme Profil pro
    Rédacteur technique (retraité)
    Inscrit en
    octobre 2009
    Messages
    164
    Détails du profil
    Informations personnelles :
    Sexe : Homme
    Âge : 78
    Localisation : France, Essonne (Île de France)

    Informations professionnelles :
    Activité : Rédacteur technique (retraité)

    Informations forums :
    Inscription : octobre 2009
    Messages : 164
    Points : 788
    Points
    788
    Par défaut
    Intéressant, mais l'utilisateur doit être informé d'une limitation importante s'il utilise ce programme pour des années passées.

    Par exemple si on recherche quel jour de la semaine a eu lieu la bataille de Marignan (13 & 14 septembre 1515) : le programme indiquera lundi/mardi pour ces deux jours alors que les historiens affirment que la bataille a eu lieu un jeudi/vendredi.

    La raison en est que le programme est exclusivement grégorien et qu'en 1515 le calendrier en usage était encore julien. La réforme grégorienne n'aura lieu, au mieux, qu'en 1582.

    Par conséquent l'année demandée au programme doit être postérieure à l'année d'application de la réforme grégorienne pour le pays considéré. Celle-ci n'a pas eu lieu en même temps pour tout le monde: octobre 1582 pour les états du Pape, l'Espagne et le Portugal; 2 mois plus tard pour la France, ... pour la Russie ce ne sera qu'en 1918 !

    D'ailleurs, le programme est encore plus erroné pour l'année de la réforme elle-même car il ne tient pas compte de la correction appliquée uniquement cette année-là afin de rattraper l'erreur julienne du passé : en 1582 il y avait 10 jours d'écart avec les astres, pour corriger, à Rome on est passé directement, en une seule nuit, du jeudi 4 octobre 1582 au vendredi 15 octobre ! En France la correction a eu lieu en passant du dimanche 9 décembre 1582 au lundi 20 décembre. (et on se plaint aujourd'hui lorsqu'on doit avancer ou retarder nos montres d'une pauvre petite heure )

    Référence : l'excellent ouvrage de Paul Couderc "Le Calendrier", collection Que sais-je ? (éditions PUF).

  3. #3
    Rédacteur/Modérateur

    Avatar de Roland Chastain
    Homme Profil pro
    Enseignant
    Inscrit en
    décembre 2011
    Messages
    3 828
    Détails du profil
    Informations personnelles :
    Sexe : Homme
    Âge : 48
    Localisation : France, Moselle (Lorraine)

    Informations professionnelles :
    Activité : Enseignant

    Informations forums :
    Inscription : décembre 2011
    Messages : 3 828
    Points : 13 685
    Points
    13 685
    Billets dans le blog
    8
    Par défaut
    @DomDA91

    Merci pour avoir regardé le programme et pour toutes ces informations.

    Je vous propose une nouvelle version un peu meilleure.

    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    3
    4
    5
    6
    7
    8
    9
    10
    11
    12
    13
    14
    15
    16
      LParam := StrToIntDef(ParamStr(1), CurrentYear);
      if (LParam >= 0) and (LParam <= 65535) then
        LAnnee := LParam
      else
        Erreur('La valeur du paramètre doit être comprise entre 0 et 65535.');
     
      case LAnnee of
        0:
          Erreur('Il n''y a pas d''année zéro.');
        1..1581:
          LJulien := TRUE;
        1582:
          Erreur('Année non disponible dans le programme de démonstration.');
        1583..65535:
          LJulien := FALSE;
      end;
    Pour l'année 1582 et pour les particularités locales, il faudra attendre. En revanche vous avez déjà un calendrier correct pour l'année 1515.
    Fichiers attachés Fichiers attachés

  4. #4
    Membre éclairé

    Homme Profil pro
    Rédacteur technique (retraité)
    Inscrit en
    octobre 2009
    Messages
    164
    Détails du profil
    Informations personnelles :
    Sexe : Homme
    Âge : 78
    Localisation : France, Essonne (Île de France)

    Informations professionnelles :
    Activité : Rédacteur technique (retraité)

    Informations forums :
    Inscription : octobre 2009
    Messages : 164
    Points : 788
    Points
    788
    Par défaut Comptage des caractères d'une chaine UTF8
    Une suggestion :
    Plutôt que de faire les "pieds au mur" en passant par une conversion en Ansi ou une dé-accentuation des caractères voici une fonction universelle qui renvoi le nombre de caractères (et non le nombre d'octets comme le fait Length) d'une chaine AnsiString, que celle-ci soit codée en UTF8 ou autre page de code :

    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    3
    4
    5
    6
    7
    8
    9
    Function CharCount(Const S: ansistring): Integer;
    Var i: Integer;
    Begin
       If StringCodePage(s) = CP_UTF8 Then Begin
          Result := 0;
          For i := 1 To Length(s) Do
             If (byte(s[i]) And $C0) <> $80 Then Inc(result)
        End Else Result := Length(s)
    End;
    Ce code ne dépend d'aucune unité autre que System.

  5. #5
    Rédacteur/Modérateur

    Avatar de Roland Chastain
    Homme Profil pro
    Enseignant
    Inscrit en
    décembre 2011
    Messages
    3 828
    Détails du profil
    Informations personnelles :
    Sexe : Homme
    Âge : 48
    Localisation : France, Moselle (Lorraine)

    Informations professionnelles :
    Activité : Enseignant

    Informations forums :
    Inscription : décembre 2011
    Messages : 3 828
    Points : 13 685
    Points
    13 685
    Billets dans le blog
    8
    Par défaut
    @DomDA91

    Merci pour cette fonction, que j'ai intégrée au programme. J'ai aussi ajouté un fichier INI qui permet de régler les deux options disponibles : lundi en premier, nombre de colonnes.
    Fichiers attachés Fichiers attachés

Discussions similaires

  1. [générale] PhP => flash format texte
    Par Destiny dans le forum Flash
    Réponses: 2
    Dernier message: 17/10/2005, 13h33
  2. Lecture simple de fichiers formatés
    Par enicnath dans le forum Général Python
    Réponses: 4
    Dernier message: 10/10/2005, 14h44
  3. lecture simple de fichiers formatés
    Par enicnath dans le forum Langage
    Réponses: 7
    Dernier message: 06/10/2005, 18h06
  4. CppUnit et la generation de rapport au format text
    Par xxiemeciel dans le forum Bibliothèques
    Réponses: 3
    Dernier message: 03/10/2005, 22h08
  5. [Dates] Calendrier sous format 20000101
    Par nunor dans le forum Langage
    Réponses: 9
    Dernier message: 10/11/2004, 00h03

Partager

Partager
  • Envoyer la discussion sur Viadeo
  • Envoyer la discussion sur Twitter
  • Envoyer la discussion sur Google
  • Envoyer la discussion sur Facebook
  • Envoyer la discussion sur Digg
  • Envoyer la discussion sur Delicious
  • Envoyer la discussion sur MySpace
  • Envoyer la discussion sur Yahoo