Supprimer le 8eme et 17eme caractère d'un string

**ryan.ighilahriz** · 13/02/2019, 17h12

Bonjour le Forum,

Tout d'abord merci pour l'aide que vous m'avez apporté à chaque fois que je vous ai sollicités !
Etant débutant en VBA, je fais un peu de bricolage en adaptant des bouts de codes.
Voici ma requête :

J'ai une colonne contenant plusieurs chaines de caractères. Je voudrais parcourir cette colonne et retirer systématiquement le 8eme et 17eme caractère.
Une idée ?

J'ai essayé de bidouiller ce bout de code trouvé sur le forum mais sans succès..

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
 
Sub test()
 
ncar = Len(Range("A4"))
vcel = Range("A4").Value
 
vcel1 = Left(vcel, 7)
vcel2 = Mid(vcel, 9, ncar)
vcel3 = Left(vcel, 17)
vcel2 = Mid(vcel, 19, ncar)
 
Range("A4").Value = vcel1 & vcel2 & vcel3 & vcel4
 
End Sub

**Igloobel** · 13/02/2019, 17h27

Bonjour,

moi je le ferai dans l'autre sens

c-a-d que je commence par supprimer le 17 ème puis le 8 ème

de plus Mid ecrit comme cela : Mid(MyString, 6) sans longueur de spécifié te ramène tout le restant de la chaine après 6 (cf touche [F1] de l'aide en ligne )

je verai qu'une serie de Mid

1) mid de 1 à 16 & mid de 18 au reste
2) je reprends cette chaine optenue et je fais pareil pour le 8 à supprimer

tu essayes

et tu reviens nous montrer ce que tu as fais

A bientôt

**Thautheme** · 13/02/2019, 17h28

Bonjour le fil, bonjour le forum

Comme le dit Igloobel :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Sub Macro1()
Dim O As Worksheet
Dim TV As Variant
Dim I As Integer
 
Set O = Worksheets("Feuil1")
TV = O.Range("A1").CurrentRegion
TV(1, 1) = TV(1, 1)
For I = 2 To UBound(TV, 1)
    TV(I, 1) = Left(TV(I, 1), 16) & Mid(TV(I, 1), 18)
    TV(I, 1) = Left(TV(I, 1), 6) & Mid(TV(I, 1), 8)
Next I
O.Range("D1").Resize(UBound(TV, 1), 1).Value = TV
End Sub

**Patrice740** · 13/02/2019, 17h37

Bonjour le fil,

Ou encore :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Option Explicit
Sub test()
Dim str As String
  str = ActiveSheet.Range("A1").Text
  Mid(str, 17, 1) = Chr(1)
  Mid(str, 9, 1) = Chr(1)
  ActiveSheet.Range("A1").Formula = Replace(str, Chr(1), "")
End Sub

**ryan.ighilahriz** · 13/02/2019, 21h42

Merci Igloobel, Patrice et Thautheme,

J'ai opté pour la solution de Thautheme et c'est exactement ce que je voulais

Par ailleurs, je viens de me rendre compte d'une subtilité : est il possible d'ajouter une condition pour éviter d'agir sur les string qui commencent par un point . ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
 
Sub Macro1()
Dim O As Worksheet
Dim TV As Variant
Dim I As Integer
 
Set O = Worksheets("Feuil1")
TV = O.Range("A1").CurrentRegion
TV(1, 1) = TV(1, 1)
For I = 2 To UBound(TV, 1)
    TV(I, 1) = Left(TV(I, 1), 16) & Mid(TV(I, 1), 18)
    TV(I, 1) = Left(TV(I, 1), 6) & Mid(TV(I, 1), 8)
Next I
O.Range("D1").Resize(UBound(TV, 1), 1).Value = TV
End Sub

**patricktoulon** · 13/02/2019, 21h56

bonsoir
un exemple

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Sub test()
'remplacons  le 7 et 9
mystring = "toto titi riri fifi"
Mid$(mystring, 7, 1) = "o"
Mid$(mystring, 9, 1) = "o"
MsgBox mystring
'
'suppression du 7 et du 9
mystring = "toto titi riri fifi"
mystring = Mid$(mystring, 1, 6) & Mid$(mystring, 8, 1) & Mid$(mystring, 10)
MsgBox mystring
End Sub

**ryan.ighilahriz** · 13/02/2019, 22h06

Patricktoulon,

Merci pour ta réponse. Sais tu comment mettre une condition pour eviter d'agir sur les string qui commencent par un point . ?
Merci

**unparia** · 13/02/2019, 22h25

Bonjour

Sais tu comment mettre une condition pour eviter d'agir sur les string qui commencent par un point .

Oui : utiliser la fonction Left et une expression conditionnelle plus que basique.

**unparia** · 13/02/2019, 22h55

Je te "vois" chercher partout (dans des discussions) alors que la fonction Left est parfaitement exposée (et assortie d'exemples clairs) dans ton aide interne VBA, à la rubrique Left, fonction.
Bon ...
Je vais te montrer comment, mais avec un autre code que ceux qui t'ont été montrés.
A toi d'y prendre ce qu'il faut y prendre. Soit tout, soit l'utilisation de l'expression conditionnelle.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
toto = "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
  If Left(toto, 1) = "." Then
    tata = toto
  Else
    titi = Split(StrConv(toto, vbUnicode), Chr(0))
    titi(8) = "": titi(17) = ""
    tata = Join(titi, "")
  End If
  MsgBox tata

**ryan.ighilahriz** · 13/02/2019, 23h47

Pour ne rien te cacher, je suis à moitié sur le forum et à moitié en train d’écouter de la musique. Pas très efficace me diras tu

Je teste ça demain matin, une fois au bureau !
Bonne soirée et merci pour ta "bienveillance"

**unparia** · 13/02/2019, 23h52

je suis à moitié sur le forum et à moitié en train d’écouter de la musique

Je suis très différent. Lorsque je m'intéresse à une chose, je m'y consacre sans compter.

Invité · 14/02/2019, 08h24

Bonjour,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
mid(txt,8,1)="£"
Mid(txt,17,1)="£"
Txt=replace(txt,"£","")

**unparia** · 14/02/2019, 08h34

Bonjour Robert
N'as-tu pas comme un peu l'impression de ce que ta solution (au demeurant la plus aisée) est celle déjà donnée par Patrice740 ?
Amitiés

**Thautheme** · 14/02/2019, 08h47

Bonjour le fil, bonjour le forum,

le code adapté :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Sub Macro1()
Dim O As Worksheet
Dim TV As Variant
Dim I As Integer
 
Set O = Worksheets("Feuil1")
TV = O.Range("A1").CurrentRegion
TV(1, 1) = TV(1, 1)
For I = 2 To UBound(TV, 1)
    If Not Left(TV(I, 1), 1) = "." Then
        TV(I, 1) = Left(TV(I, 1), 16) & Mid(TV(I, 1), 18)
        TV(I, 1) = Left(TV(I, 1), 6) & Mid(TV(I, 1), 8)
    End If
Next I
O.Range("D1").Resize(UBound(TV, 1), 1).Value = TV
End Sub

Le VBA sans musique c'est comme la Saint Valentin sans câlin - Thautheme

**unparia** · 14/02/2019, 08h52

Bonjour Thautheme

Le VBA sans musique c'est comme la Saint Valentin sans câlin - Thautheme

Mais les deux vont encore mieux sans la dualité "casseuse d'harmonie" d'un variant

Invité · 14/02/2019, 09h03

Envoyé par unparia

Bonjour Robert
N'as-tu pas comme un peu l'impression de ce que ta solution (au demeurant la plus aisée) est celle déjà donnée par Patrice740 ?
Amitiés

bonjour Jaques,
tu as raison

@Patrice740