IdentifiantMot de passe
Loading...
Mot de passe oublié ?Je m'inscris ! (gratuit)
Navigation

Inscrivez-vous gratuitement
pour pouvoir participer, suivre les réponses en temps réel, voter pour les messages, poser vos propres questions et recevoir la newsletter

Scripts/Batch Discussion :

Problème de variable..


Sujet :

Scripts/Batch

  1. #1
    Nouveau Candidat au Club
    Homme Profil pro
    Développeur informatique
    Inscrit en
    Février 2019
    Messages
    1
    Détails du profil
    Informations personnelles :
    Sexe : Homme
    Localisation : Suisse

    Informations professionnelles :
    Activité : Développeur informatique
    Secteur : High Tech - Multimédia et Internet

    Informations forums :
    Inscription : Février 2019
    Messages : 1
    Points : 1
    Points
    1
    Par défaut Problème de variable..
    Bonjour, je crée un petit utilitaire en batch, qui utilise l'outil DISM de Microsoft. Au départ, l'utilitaire demande qu'est-ce qu'on veut faire. Le problème, c'est que cela ne fonctionne pas. Cela me renvoie toujours au point 1...

    Code Batch : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    3
    4
    5
    6
    7
    8
    9
    10
    11
    12
    13
    14
    15
    16
    17
    18
    19
    20
    21
    22
    23
    24
    25
    26
    27
    28
    29
    30
    31
    32
    33
    34
    35
    36
    37
    38
    39
    40
    41
    42
    43
    44
    45
    46
    47
    48
    49
    50
    51
    52
    53
    54
    55
    56
    57
    58
    59
    60
    61
    62
    63
    64
    65
    66
    67
    68
    69
    70
    71
    72
    73
    74
    75
    76
    77
    78
    79
    80
    81
    82
    83
    84
    85
    86
    87
    88
    89
    90
    91
    92
     
    @echo off
    chcp 28591 > nul
     
    echo OUTIL DISM UNIVERSEL
    echo.
    echo 1. Capturer WIM
    echo 2. Déployer WIM
    echo 3. Capturer FFU
    echo 4. Déployer FFU
    echo 5. Connaître index
    echo 6. Ajouter au menu du boot
    echo.
    set demande=0
    set /p demande="Que voulez vous faire (écrire numéro correspondant) ? "
    echo.
    echo Numéro entré : %demande%
    echo.
     
    if /i %demande% == 1 goto capturerWIM
    :capturerWIM
    diskpart /s %~dp0diskpart_VOL.txt
    echo.
    set /p cible="Quel est le chemin du fichier cible ? "
    set /p capture="Quel est la lettre du lecteur à capturer ? "
    set /p name="Définissez un nom pour la capture : "
    cls
    DISM /Capture-Image /ImageFile:"%cible%" /CaptureDir:%capture%:\ /Name:"%name%"
    goto end
     
    if /i %demande% == 2 goto deployerWIM
    :deployerWIM
    diskpart /s %~dp0diskpart_VOL.txt
    echo.
    set /p cible="Quel est le chemin du fichier à déployer ? "
    set /p capture="Quel est la lettre du lecteur à capturer ? "
    set /p index="Quel est le numéro d'index de l'image à capturer ? "
    cls
    DISM /Apply-Image /ImageFile:"%cible%" /index:%index% /ApplyDir:%capture%:\
    goto end
     
    if /i %demande% == 3 goto capturerFFU
    :capturerFFU
    diskpart /s %~dp0diskpart_DISK.txt
    diskpart /s %~dp0diskpart_VOL.txt
    echo.
    set /p cible="Quel est le chemin du fichier cible ? "
    set /p numdisque="Quel est le numéro du disque à capturer ? "
    set /p name="Définissez un nom pour la capture : "
    set /p description="Définissez une description pour la capture : "
    cls
    DISM /capture-ffu /imagefile="%cible%" /capturedrive=\\.\PhysicalDrive%numdisque% /name:"%name%" /description:"%description%"
    goto end
     
    if /i %demande% == 4 goto deployerFFU
    :deployerFFU
    diskpart /s %~dp0diskpart_DISK.txt
    diskpart /s %~dp0diskpart_VOL.txt
    echo.
    set /p cible="Quel est le chemin du fichier cible ? "
    set /p numdisque="Quel est le numéro du disque sur lequel l'image FFU va être déployée ? "
    cls
    DISM /Apply-FFU /ImageFile="%cible%" /ApplyDrive:\\.\PhysicalDrive%numdisque%
    goto end
     
    if /i %demande% == 5 goto connaitreINDEX
    :connaitreINDEX
    diskpart /s %~dp0diskpart_VOL.txt
    echo.
    set /p cibleindex="Quel est le chemin de l'image ? "
    cls
    Dism /Get-ImageInfo /ImageFile:"%cibleindex%"
    goto end
     
    if /i %demande% == 6 goto ajouterMENUBOOT
    :ajouterMENUBOOT
    diskpart /s %~dp0diskpart_VOL.txt
    echo.
    set /p lettrelecteur="Quel est la lettre du lecteur à ajouter au menu du boot ? "
    set /p description="Définissez une description pour l'entrée : "
    cls
    bcdboot %lettrelecteur%:\Windows
    bcdedit /set {current} description "%description%"
    goto end
     
    if /i %demande% == 0 goto end
     
    :end
    echo.
    echo Toutes les opérations ont été effectuées avec succès.
    echo.
    PAUSE

    Avez-vous une solution ? Merci !

  2. #2
    Membre éprouvé
    Homme Profil pro
    Développeur .NET en devenir
    Inscrit en
    Août 2017
    Messages
    546
    Détails du profil
    Informations personnelles :
    Sexe : Homme
    Âge : 44
    Localisation : France, Moselle (Lorraine)

    Informations professionnelles :
    Activité : Développeur .NET en devenir
    Secteur : High Tech - Éditeur de logiciels

    Informations forums :
    Inscription : Août 2017
    Messages : 546
    Points : 1 084
    Points
    1 084
    Par défaut
    Bonjour,

    Voilà quelques corrections :

    Code Batch : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    3
    4
    5
    6
    7
    8
    9
    10
    11
    12
    13
    14
    15
    16
    17
    18
    19
    20
    21
    22
    23
    24
    25
    26
    27
    28
    29
    30
    31
    32
    33
    34
    35
    36
    37
    38
    39
    40
    41
    42
    43
    44
    45
    46
    47
    48
    49
    50
    51
    52
    53
    54
    55
    56
    57
    58
    59
    60
    61
    62
    63
    64
    65
    66
    67
    68
    69
    70
    71
    72
    73
    74
    75
    76
    77
    78
    79
    80
    81
    82
    83
    84
    85
    86
    87
    88
    89
    90
    91
    92
    93
    94
    95
    @echo off
    chcp 28591 >nul
     
    :menu
    cls
    echo OUTIL DISM UNIVERSEL
    echo.
    echo 1. Capturer WIM
    echo 2. Déployer WIM
    echo 3. Capturer FFU
    echo 4. Déployer FFU
    echo 5. Connaître index
    echo 6. Ajouter au menu du boot
    echo.
    set demande=0
    set /p demande="Que voulez-vous faire (écrire numéro correspondant) ? "
    echo.
    echo Numéro entré : %demande%
    echo.
     
    if /i %demande% == 0 goto end
    if /i %demande% == 1 goto capturerWIM
    if /i %demande% == 2 goto deployerWIM
    if /i %demande% == 3 goto capturerFFU
    if /i %demande% == 4 goto deployerFFU
    if /i %demande% == 5 goto connaitreINDEX
    if /i %demande% == 6 goto ajouterMENUBOOT
     
    goto :menu
     
    :capturerWIM
    diskpart /s %~dp0diskpart_VOL.txt
    echo.
    set /p cible="Quel est le chemin du fichier cible ? "
    set /p capture="Quel est la lettre du lecteur à capturer ? "
    set /p name="Définissez un nom pour la capture : "
    cls
    DISM /Capture-Image /ImageFile:"%cible%" /CaptureDir:%capture%:\ /Name:"%name%"
    goto end
     
    :deployerWIM
    diskpart /s %~dp0diskpart_VOL.txt
    echo.
    set /p cible="Quel est le chemin du fichier à déployer ? "
    set /p capture="Quel est la lettre du lecteur à capturer ? "
    set /p index="Quel est le numéro d'index de l'image à capturer ? "
    cls
    DISM /Apply-Image /ImageFile:"%cible%" /index:%index% /ApplyDir:%capture%:\
    goto end
     
    :capturerFFU
    diskpart /s %~dp0diskpart_DISK.txt
    diskpart /s %~dp0diskpart_VOL.txt
    echo.
    set /p cible="Quel est le chemin du fichier cible ? "
    set /p numdisque="Quel est le numéro du disque à capturer ? "
    set /p name="Définissez un nom pour la capture : "
    set /p description="Définissez une description pour la capture : "
    cls
    DISM /capture-ffu /imagefile="%cible%" /capturedrive=\\.\PhysicalDrive%numdisque% /name:"%name%" /description:"%description%"
    goto end
     
    :deployerFFU
    diskpart /s %~dp0diskpart_DISK.txt
    diskpart /s %~dp0diskpart_VOL.txt
    echo.
    set /p cible="Quel est le chemin du fichier cible ? "
    set /p numdisque="Quel est le numéro du disque sur lequel l'image FFU va être déployée ? "
    cls
    DISM /Apply-FFU /ImageFile="%cible%" /ApplyDrive:\\.\PhysicalDrive%numdisque%
    goto end
     
    :connaitreINDEX
    diskpart /s %~dp0diskpart_VOL.txt
    echo.
    set /p cibleindex="Quel est le chemin de l'image ? "
    cls
    Dism /Get-ImageInfo /ImageFile:"%cibleindex%"
    goto end
     
    :ajouterMENUBOOT
    diskpart /s %~dp0diskpart_VOL.txt
    echo.
    set /p lettrelecteur="Quel est la lettre du lecteur à ajouter au menu du boot ? "
    set /p description="Définissez une description pour l'entrée : "
    cls
    bcdboot %lettrelecteur%:\Windows
    bcdedit /set {current} description "%description%"
    goto end
     
    :end
    echo.
    echo Toutes les opérations ont été effectuées avec succès.
    echo.
    PAUSE

Discussions similaires

  1. [VB.NET] Probléme de variable
    Par Silvia12 dans le forum Windows Forms
    Réponses: 3
    Dernier message: 02/03/2005, 12h51
  2. [Debutant(e)]problème de variable d'environnement
    Par tolsam dans le forum Eclipse Java
    Réponses: 1
    Dernier message: 12/08/2004, 20h08
  3. Problème de variable
    Par vp dans le forum Windows
    Réponses: 2
    Dernier message: 14/05/2004, 17h27
  4. [Débutant] Problème de variables
    Par bonnefr dans le forum SWT/JFace
    Réponses: 9
    Dernier message: 12/05/2004, 18h41
  5. [servlet]problème de variable jamais nulle
    Par omega dans le forum Servlets/JSP
    Réponses: 2
    Dernier message: 18/03/2004, 10h31

Partager

Partager
  • Envoyer la discussion sur Viadeo
  • Envoyer la discussion sur Twitter
  • Envoyer la discussion sur Google
  • Envoyer la discussion sur Facebook
  • Envoyer la discussion sur Digg
  • Envoyer la discussion sur Delicious
  • Envoyer la discussion sur MySpace
  • Envoyer la discussion sur Yahoo