Discussion :

[tonyhv]

Bonsoir le forum
Je souhaite compter le nombre de weekends travaillés qu’il y a entre deux dates.
Un weekend doit être compté même si un seul jour du weekend est compris dans la plage de dates.
Si on travaille du Dimanche au vendredi suivant = 1 Weekend (1 dimanche)
Si on travaille du Dimanche au samedi suivant = 2 weekends (1 dimanche + 1 samedi)
Si on travaille du Dimanche au samedi de la semaine d'après 3 weekends (2 dimanches + 2 samedis) etc
Que le weekend soit travaillé en entier ou pas il est compté.
J’ai essayé des formules avec SOMMEPROD mais lorsque qu’il n’y a qu’un demi weekend de travaillé je cale.
J’y arrive en combinant SOMMEPROD avec SI et ET en testant le jour de départ et le nombre de jours qu'il y a entre les deux dates : exemple je teste si la séquence commence un dimanche et si la page est inférieure a 6 jours j’ai un seul weekend, mais c’est ingérable il faudrait imbriquer une quantité phénoménale de SI rien que pour tester une plage de 30 jours.
je peux utiliser indifféremment une formule ou une fonction
Merci pour votre aide

[Pierre Fauconnier]

Salut.


La logique d'abord: La condition pour que la date soit comptée est qu'elle soit un samedi ou un dimanche mais qui soit alors la borne inférieure (seul cas où la veille, le samedi, n'aurait pas déjà été comptée). Il suffit donc de compter les samedis de la plage de date avec NB.JOURS.OUVRES.INTL en disant que seul le samedi est ouvré, et d'ajouter 1 à la valeur trouvée si le premier jour de la plage est un dimanche.

[unparia]

Bonjour Pierre
Attendons peut-être que soit précisé clairement (les tenants) ce qui correspond à ceci :

lorsque qu’il n’y a qu’un demi weekend de travaillé je cale.

Assez ambigu du fait que l'on lit plus haut

Un weekend doit être compté même si un seul jour du weekend est compris dans la plage de dates.
Si on travaille du Dimanche au vendredi suivant = 1 Weekend (1 dimanche)
Si on travaille du Dimanche au samedi suivant = 2 weekends (1 dimanche + 1 samedi)
Si on travaille du Dimanche au samedi de la semaine d'après 3 weekends (2 dimanches + 2 samedis) etc
Que le weekend soit travaillé en entier ou pas il est compté.

Qu'est alors exactement un "demi-weekend" : un samedi seul ou un dimanche seul (et donc un weekend "non complet") ? Et si oui, compare ceci :

Si on travaille du Dimanche au samedi de la semaine d'après 3 weekends (2 dimanches + 2 samedis)

au résultat de ta formule.
Des explications plus claires, plus précises et plus techniques seraient à mon sens souhaitables.

Je dirais assez volontiers (si n'existait pas ce que j'ai cité en troisième), que le nombre de weekends à prendre en compte est le plus élevé des nombres NS et ND, le premier étant celui des samedis et le second celui des dimanches. Et cela correspond d'ailleurs à ton résultat (ce qui me parait au demeurant plus logique)

[papouclo]

Bonjour,
En appelant début et fin les dates, bornes d'une période de travail sans interruption, j'essayerais la formule :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=NO.SEMAINE.ISO(fin)-NO.SEMAINE.ISO(début)+(JOURSEM(fin;2)>5)

Cordialement
Claude

[tonyhv]

Pierre, unparia, merci tout d'abord de vous être penché sur mon problème :
La plage de travail peut commencer et se terminer n'importe quel jour de la semaine et ou du weekend.
Lorsque dans la plage il n'y a que des weekends entiers et que donc leur somme est un nombre pair je divise par deux pour avoir le nombre de weekends,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SIERREUR((SOMMEPROD((JOURSEM(LIGNE(INDIRECT(D5&":"&F5));2)>5)*1)/2)*1;"")

j'ai identifié deux problèmes distincts :
le premier : si le résultat est impair on pourrais faire un arrondi, mais je souhaite avoir un vrai nombre entier en résultat pour pouvoir les sommer en final.
le deuxième : Si la séquence commence un dimanche et se termine le samedi suivant, il ne trouve qu'un weekend (1 samedi et 1 dimanche) mais ils sont sur deux semaines distinctes donc je dois compter 2 weekends.
En espérant avoir été plus clair
En passant par cette usine a gaz cela fonctionne mais je me suis limité volontairement a 3 weekends

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
=SIERREUR(
SI(ET(JOURSEM([@[Date_début]];11)=6;[@[Nbr de Jours]]<8);"1";
SI(ET(JOURSEM([@[Date_début]];11)=6;[@[Nbr de Jours]]>7;[@[Nbr de Jours]]<15);"2";
SI(ET(JOURSEM([@[Date_début]];11)=6;[@[Nbr de Jours]]>14;[@[Nbr de Jours]]<22);"3";
SI(ET(JOURSEM([@[Date_début]];11)=6;[@[Nbr de Jours]]>21);"+ de 3";
SI(ET(JOURSEM([@[Date_début]];11)=7;[@[Nbr de Jours]]<7);"1";
SI(ET(JOURSEM([@[Date_début]];11)=7;[@[Nbr de Jours]]>6;[@[Nbr de Jours]]<14);"2";
SI(ET(JOURSEM([@[Date_début]];11)=7;[@[Nbr de Jours]]>13;[@[Nbr de Jours]]<21);"3";
SI(ET(JOURSEM([@[Date_début]];11)=7;[@[Nbr de Jours]]>20);"+ de 3";
SI(ET(JOURSEM([@[Date_début]];11)<6;[@[Nbr de Jours]]<=8;SOMMEPROD(--(JOURSEM(LIGNE(INDIRECT([@[Date_début]]&":"&[@[Date_fin]]));2)>=6))=0);"0";
SI(ET(JOURSEM([@[Date_début]];11)<6;[@[Nbr de Jours]]<12;SOMMEPROD(--(JOURSEM(LIGNE(INDIRECT([@[Date_début]]&":"&[@[Date_fin]]));2)>=6))<=2);"1";
SI(ET(JOURSEM([@[Date_début]];11)<6;[@[Nbr de Jours]]<12;SOMMEPROD(--(JOURSEM(LIGNE(INDIRECT([@[Date_début]]&":"&[@[Date_fin]]));2)>=6))>2);"2";
SI(ET(JOURSEM([@[Date_début]];11)<6;[@[Nbr de Jours]]<18;SOMMEPROD(--(JOURSEM(LIGNE(INDIRECT([@[Date_début]]&":"&[@[Date_fin]]));2)>=6))>4);"3";"continue"))))))))))));"test")

[zenpbb]

Bonjour,
Utiliser les numéros de semaines rend compliqué le passage d'une année à l'autre (si début et fin sont sur deux années différentes)...

[tonyhv]

Cette formule résout le problème
Un grand merci

[...]

[tonyhv]

Effectivement...

Bonjour,
Utiliser les numéros de semaines rend compliqué le passage d'une année à l'autre (si début et fin sont sur deux années différentes)...

[zenpbb]

Du coup, la formule de Pierre est nickel, non ?

[Pierre Fauconnier]

Pourquoi ne testes-tu pas ma solution? Par rapport à tes explications de départ, elle est ok (teste-là avec des bornes hors weekend, des bornes qui sont samedi et ou dimanche, des années différentes pour le début et la fin, ...) Tu verras que ça fonctionne. Tu comptes les samedis compris dans ta période, et tu ajoutes 1 si la date du début est un dimanche. Fais varier les dates en A1 et A2 pour tester différents cas. Si tu n'es pas sûr, dessine une ligne de temps pour visualiser les cas.


Tu peux compter les weekends, mais alors tu devras:

• Compter les jours de weekend (avec le masque "1111100");
• Diviser par deux;
• ajouter 0.5 si la première date est un dimanche;
• ajouter 0.5 si la dernière date est un samedi.

Je n'aime pas la proposition de unparia de compter les samedis, puis les dimanches et de garder le nombre le plus élevé car cela demande un comptage inutile du bon nombre:
Si(CompterSamedis > CompterDimanches; CompterSamedis; CompterDimanches)

[unparia]

Bonjour Pierre

Je n'aime pas la proposition de unparia de compter les samedis, puis les dimanches et de garder le nombre le plus élevé

ce n'était pas là une proposition d'écrire une formule sur de telles bases, mais simplement la rédaction d'une formulation sans ambiguïté (à moins que l'une des phrases que j'ai citées ne comporte une erreur de frappe) de ce que sont les nombres de weekends à compter.

[tonyhv]

Merci Pierre,

Je vais tester ta proposition tout à l'heure

[Pierre Fauconnier]

Je précise que cette solution (avec nb.jours.ouvres.intl) est valable pour XL>=2010. Pour les versions antérieures, je ne vois qu'une matricielle pour s'en sortir et généraliser la solution

[tonyhv]

Un grand merci à tous,

La solution de Pierre fonctionne parfaitement, il faut ajouter 1 si la période commence un dimanche et se termine un samedi.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
=SI(ET(JOURSEM([@[Date_début]];2)=7;JOURSEM([@[Date_fin]];2)=6);NB.JOURS.OUVRES.INTL([@[Date_début]];[@[Date_fin]];"1111100")/2+1;
SI(JOURSEM([@[Date_début]];2)=7;NB.JOURS.OUVRES.INTL([@[Date_début]];[@[Date_fin]];"1111100")/2+0,5;
SI(JOURSEM([@[Date_fin]];2)=6;NB.JOURS.OUVRES.INTL([@[Date_début]];[@[Date_fin]];"1111100")/2+0,5;
NB.JOURS.OUVRES.INTL([@[Date_début]];[@[Date_fin]];"1111100")/2)))

Je vous souhaite a tous un bon weekend et une très bonne année !!

[Pierre Fauconnier]

Par rapport à ma première solution =NB.JOURS.OUVRES.INTL(A1;A2;"1111101")+(JOURSEM(A1;2)=7), il ne faut rien modifier. Pourquoi te compliques-tu la vie?...

[tonyhv]

Par rapport à ma première solution, il ne faut rien modifier...

Si je commence le Dimanche 6 janvier et que je termine le samedi 12 janvier, je dois compter 2 weekends. dans ce cas présent je dois ajouter l’équivalent de 2 * 0,5

[Pierre Fauconnier]

[tonyhv]

Par rapport à ma première solution =NB.JOURS.OUVRES.INTL(A1;A2;"1111101")+(JOURSEM(A1;2)=7), il ne faut rien modifier. Pourquoi te compliques-tu la vie?...

Désolé Pierre, je n'avais pas vu cette proposition, qui fonctionne a merveille avec une seule ligne.....