Discussion :

[olive323]

Bonjour à tous,

Je n'arrive pas à inserer la valeur "poids_ligne" de la table temp vers la table detail_commande avec les décimales.

Par exemple, j'ai 1,426 colonne (poids_ligne) dans la table temp et la requête renvoie la valeur 1,000 dans la table detail_commande.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
Private Sub valider_facture_Click()
Dim num_com As Long: Dim requete As String
Dim ligne As Recordset: Dim base As Database
Dim ref_produit As String: Dim qte_produit As Integer
Dim poids_ligne As Integer
 
If (n_client.Value <> "") Then
        Set base = Application.CurrentDb
 
        requete = "INSERT INTO Commandes (cli_com, montant_com,poids_total_commande,statut_com) VALUES ('" & n_client.Value & "','" & Int(total_commande.Value) & "'," & Int(poids_total.Value) & ",'" & statut_encours.Value & "')"
        base.Execute requete
If (n_client.Value <> "") Then
        Set ligne = base.OpenRecordset("SELECT MAX(num_com) as dernier_num FROM Commandes", dbOpenDynaset)
 
        ligne.MoveFirst
        num_com = Int(ligne.Fields("dernier_num").Value)
        n_commande.Value = num_com
 
 
        Set ligne = base.OpenRecordset("SELECT * FROM Detail_temp", dbOpenDynaset)
 
        ligne.MoveFirst
        'PARCOURS DE TOUTES LES LIGNES DE LA COMMANDE EN COURS
        Do
 
        ref_produit = ligne.Fields("ref_det").Value
        qte_produit = ligne.Fields("qute_det").Value
        poids_ligne = ligne.Fields("poids_ligne").Value
 
 
 
        requete = "INSERT INTO Detail_commandes (com_det,ref_det,qute_det,Designation,n_cme,type_exp,n_ote,type_emballage,ville,code_postal,pays,date_exp,civilite,nom_client,adresse_client,poids_lignes) VALUES ('" & n_commande.Value & "','" & ref_produit & "','" & qte_produit & "','" & Designation.Value & "','" & n_cme.Value & "','" & mode_exp.Value & "','" & n_ote.Value & "','" & type_support.Value & "','" & ville.Value & "','" & code_postal.Value & "','" & pays.Value & "','" & date_exp.Value & "','" & civilite.Value & "','" & nom_client.Value & "','" & adresse_client.Value & "','" & poids_ligne & "')"
 
        base.Execute requete
 
 
 
        ligne.MoveNext
        Loop Until ligne.EOF
 
        ligne.Close
        base.Close
        Set ligne = Nothing
        Set base = Nothing
 
        purger_table
 
        DoCmd.OpenReport "Bon_préparation", acViewPreview
 
 
        Else
                MsgBox "La commande ne contient aucun article", vbCritical, "ATTENTION"
 
        End If
        Else
 
        MsgBox "La commande ne contient aucun article", vbCritical, "ATTENTION"
End If

Merci pour votre aide

[Arkham46]

Bonjour,

Evitez de générer une requête par concaténation de valeurs.
C'est source de nombreuses erreurs : conversion inutile ou erronées (ce qui se passe sans doute avec les décimales), problème si une valeur contient des apostrophes ou guillemets...
Et c'est lourd à écrire et à lire.

On peut passer par une requête temporaire paramétrée :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
 
Dim qdf As DAO.QueryDef
requete = "INSERT INTO Detail_commandes (com_det,ref_det,poids_lignes) VALUES ([param_com_det],[param_ref_det],[param_poids_lignes])"
Set qdf = base.CreateQueryDef("", requete)
qdf.Parameters("param_com_det").Value = n_commande.Value 
qdf.Parameters("param_ref_det").Value = ref_produit
qdf.Parameters("param_poids_lignes").Value = poids_ligne
qdf.Execute

Je n'ai mis que quelques colonnes pour montrer le principe.
Entre crochets on défini les paramètres, sans les entourer de guillemets.
Et ensuite on affecte les valeurs de paramètres avant d'exécuter la requête.
La requête ainsi créée avec un nom vide est temporaire, elle n'est pas stockée.
Ainsi on ne soucie plus du type des données, et l'écriture de la requête est plus lisible qu'une concaténation où on se perd dans les guillemets.

[olive323]

Bonjour,

Merci pour ce retour, je vais tester

[micniv]

Bonjour,

Aussi, si tu veux des décimales, il faut typer le paramètre en conséquence

Dim poids_ligne As Integer ...

donc pas de decimales !


Améliore tes déclarations :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
Dim num_com As Long, requete As String
Dim ligne As DAO.Recordset, base As DAO.Database ...

Remplace

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Set ligne = base.OpenRecordset("SELECT MAX(num_com) as dernier_num FROM Commandes", dbOpenDynaset)
ligne.MoveFirst
num_com = Int(ligne.Fields("dernier_num").Value)
n_commande.Value = num_com

par

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

n_commande = dmax("num_com","Commandes")

CDLT

[olive323]

Bonjour a tous,

Tous mes voeux pour cette nouvelle année.

Je tenais à vous remercier pour votre aide cela fonctionne nickel

[micniv]

Merci de ton retour.
Dans ce cas, pourrais-tu passer ce fil en Résolu.

CDLT