Discussion :

[vicjohns]

Bonjour à tous,

Etant débutant en VBA, je viens solliciter votre aide face à un problème au quel je suis confrontré. Au fait j'ai un userform contenant un textbox dans lequel je permet à l'utilisateur de donner des longueurs. La condition que j'ai envie d'imposer à ce textbox est que les longueurs entrées par l'utilisateur doivent être uniquement impaires et supérieurs à 1.

Pourriez vous s'il vous plait m'aider?

Merci d'avance.

[unparia]

Bonjour
Qui dit impair, dit nombre entier --->>

C'est pour toi, hein ... pas pour un exercice scolaire ...
Voilà donc une solution (que tu n'auras à expliquer à personne)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Private Sub TextBox1_Exit(ByVal Cancel As MSForms.ReturnBoolean)
  If (Not Val(TextBox1.Text) And 1) Or Val(TextBox1.Text) < 3 Then
    MsgBox "j'ai dit impair et supérieur à 1 !": Cancel = True
  End If
End Sub

Mais si pour exercice scolaire et que tu as à expliquer ta solution --->> bûche donc la rubrique Mod, Opérateur de ton aide VBA interne et utilise-la

[Pierre Fauconnier]

Salut.

Cela revient à tester que le modulo 2 de la valeur est 1 ET que la valeur est supérieure à 1... Voici une fonction booléenne (VRAI/FAUX) qui réalise cela

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Function ValueIsOK(value As Long) As Boolean
  ValueIsOK = (value Mod 2) = 1 And value > 1
End Function

En Test

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Sub Test3()
  Dim value As Long
 
  For value = 1 To 10
    Debug.Print value & " : " & ValueIsOK(value)
  Next
End Sub

[vicjohns]

Tout d'abord merci pour vos réponses, mais ce que je veux en vrai c'est qu'une fois l'utilisateur a fini d'entrer un nombre impair dans la textbox mon programme efface son nombre et lui envoi un message disant d'entrer un nombre impair supérieur à 1. Je ne veux pas que la saisie du nombre pair reste.

[Pierre Fauconnier]

Si la fonction que je t'ai donnée, utilisée après la saisie, renvoie FALSE, tu effaces et tu demandes de recommencer

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Private Sub TextBox1_Exit(ByVal Cancel As MSForms.ReturnBoolean)
  If IsNumeric(TextBox1) Then
    If Not ValueIsOK(TextBox1.value) Then
      MsgBox "Raté"
      TextBox1.value = Null
      Cancel = True
    End If
    Else
      MsgBox "on a dit numérique!"
      Cancel = True
  End If
End Sub

[vicjohns]

Merci @Pierre Fauconnier c'est exactement ce que je voulais

[unparia]

et lui envoi un message disant d'entrer un nombre impair supérieur à 1. Je ne veux pas que la saisie du nombre pair reste.

Il est peut-être maladroit de faire cela, qui prive l'utilisateur de constater le bien fondé du reproche fait.
Il me semble préférable qu'il puisse en faire le constat, tout en lui donnant la possibilité de corriger directement, sans effacer.
Ce qui donnerait par exemple (avec mon premier code) ceci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Private Sub TextBox1_Exit(ByVal Cancel As MSForms.ReturnBoolean)
  With TextBox1
    If (Not Val(.Text) And 1) Or Val(.Text) < 3 Then
      MsgBox "j'ai dit impair et supérieur à 1 !"
      Cancel = True
      .SelStart = 0: .SelLength = Len(.Text)
    End If
  End With
End Sub

A toi de l'adapter en utilisant l'opérateur Mod, si tu préfères.

[Arkham46]

Il est peut-être maladroit de faire cela, qui prive l'utilisateur de constater le bien fondé du reproche fait.
Il me semble préférable qu'il puisse en faire le constat, tout en lui donnant la possibilité de corriger directement, sans effacer.

Côté ergonomie je suis tout à fait d d'accord.
J'ai horreur qu'on me vide ma saisie sans préavis alors qu'il me suffisait de corriger un seul caractère.

[Pierre Fauconnier]

Je plussoie Arkham et unparia sur l'ergonomie