Discussion :

[informer]

Bonjour à tous,

Comment affecter la plage autofilter à un objet de type range avec le code suivant

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
 With xlsWkSheet
        With .Range("A1").CurrentRegion
            .AutoFilter Field:=4, Criteria1:="Gros minet"
            .AutoFilter Field:=19, Criteria1:="Titi"
            .AutoFilter Field:=24, Criteria1:="Toto"
        End With
End With

Merci par avance

[MarcelG]

Bonjour,

J'avoue ne pas comprendre la question.
Je te demanderais, sauf ignorance de ma part, ce que tu entends par là. Plus explicitement.

[halaster08]

Bonjour,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
 
dim plage as range
With xlsWkSheet
        With .Range("A1").CurrentRegion
            .AutoFilter Field:=4, Criteria1:="Gros minet"
            .AutoFilter Field:=19, Criteria1:="Titi"
            .AutoFilter Field:=24, Criteria1:="Toto"
        End With
set  plage = .Range("A1").CurrentRegion 'suffit si tu laisse le filtre actif
 
Set plage = Range("A1").CurrentRegion.SpecialCells(xlCellTypeVisible) ' si tu comptes enlever le filtre par la suite
 
End With

[informer]

halaster08 ,

Merci pour ton aide précieuse. Après implementation

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set xlsRangeAutoFilter = .SpecialCells(xlCellTypeVisible)

Le debug.print me donne respectivement

Debug.Print xlsRangeAutoFilter.Address -> $A$1:$E$1,$P$1:$V$1,$AD$1:$AF$1,$A$29:$E$29,$P$29:$V$29,$AD$29:$AF$29
Debug.Print xlsRangeAutoFilter.Rows.Count -> 1

Row.count = 1 car j'imagine que la ligne 1 des entêtes n'est pas prise en compte mais à part ce type de routine

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
aRange = split(xlsRangeAutoFilter.Address, ",") 
For I= 1 to UBound(aRange)
      Traitement pour récupérer toutes les lignes sauf la 1ère
next I

Je ne vois pas comment faire pour récupérer le nombre des lignes sélectionnées et leur chiffre associé

Une autre idée?

[MarcelG]

Salut,

Il te faut décompter sur le nombre de lignes d'une colonne

(à adapter)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Option Explicit
 
Sub lecompte()
 
Dim derlign As Integer
 
With ThisWorkbook.Worksheets("Back")
        derlign = .Cells(.Rows.Count, 4).End(xlUp).Row
        '..........
        'Application du filtre
        '..........
        Debug.Print .Range("A2:A" & derlign).SpecialCells(xlCellTypeVisible).Count
End With
 
End Sub

[halaster08]

Je ne vois pas comment faire pour récupérer le nombre des lignes sélectionnées et leur chiffre associé

Une autre idée?

Si tu souhaite envoyer le résultat de ton filtre sur une autre plage, la solution la plus simple et la plus efficace c'est les filtres avancés: https://philippetulliez.developpez.c...dvancedfilter/

[MarcelG]

D'accord Halaster, mais tu peux également effectuer un copier/coller.
La copie d'un Objet Range filtré sera un autre objet Range non filtré.
Si le filtre d'un objet Range affiche 2 lignes visibles discontinues, alors la copie résultera en 2 lignes successives (non filtrées).

[informer]

halaster08

Si je suis le tuto qui donne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Function ExportByFilter(znData As Range, znCriteria As Range, Optional znExport As Range) As Long
 ' Procédure d'exportation basée sur le filtre élaboré
 ' Author : Philippe Tulliez http://philippe.tulliez.be
 ' Valeur renvoyée : Nombre d'enregistrements exportés
 ' znData     ' Table de données
 ' znCriteria ' Zone des critères
 ' [znExport]   ' Zone d'exportation (si vide exporte tout en créant une feuille)
 If znExport Is Nothing Then ' Création de la feuille d'export et coloration en rouge
  Worksheets.Add before:=Sheets(1)
  With Worksheets(1): ActiveCell = .Range("A1") : .Tab.Color = vbRed: End With
  Set znExport = ActiveCell
 End If
 znData.AdvancedFilter Action:=xlFilterCopy, CriteriaRange:=znCriteria, CopyToRange:=znExport
 ExportByFilter = znExport.CurrentRegion.Rows.Count – 1
End Function

J’ai quelques difficultés pour adapter à mon code car ne vois pas ce à quoi correspondent

• CriteriaRange:=znCriteria
• znData

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
 
Dim znExport as Range
Set xlsRangeAutoFilter = .SpecialCells(xlCellTypeVisible)
?.AdvancedFilter Action:=xlFilterCopy, CriteriaRange:=?, CopyToRange:=znExport

[boisgontierjacques]

Bonjour,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Sub ExtraitVersAutreFeuille()
  critere = InputBox("Critere?")
  If critere = "" Then Exit Sub
  [A1].AutoFilter Field:=1, Criteria1:=critere & "*"
  Sheets.Add after:=Sheets(Sheets.Count)
  ActiveSheet.Name = critere
  Sheets("BD").Range("_FilterDataBase").SpecialCells(xlCellTypeVisible).Copy [A1]
  Cells.EntireColumn.AutoFit
  Sheets("BD").ShowAllData
End Sub

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Sub NbLignes()
  n = [_filterdatabase].Resize(, 1).SpecialCells(xlCellTypeVisible).Count - 1
  MsgBox n
End Sub

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Sub parcoursItemsVisibles()
  For Each c In [_FilterDataBase].Resize(, 1).SpecialCells(xlCellTypeVisible)
    MsgBox c.Value & " " & c.Address
  Next c
End Sub

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Sub TransfertArray()
  NbCol = [_FilterDataBase].Columns.Count
  Dim Liste(): ReDim Liste(1 To [_FilterDataBase].Resize(, 1).SpecialCells(xlCellTypeVisible).Count, 1 To NbCol)
  For Each c In [_FilterDataBase].Offset(1).Resize(, 1).SpecialCells(xlCellTypeVisible)
     i = i + 1
     For k = 1 To NbCol: Liste(i, k) = c.Offset(, k - 1): Next k
  Next c
  Sheets(2).[A1].Resize(UBound(Liste), UBound(Liste, 2)) = Liste
End Sub

Boisgontier

[MarcelG]

Salut,

Salut Jacques

Informer,
Avec tout le respect que j'ai pour Philippe, je persiste et signe.
Sur Excel, essaie d'effectuer un copier/coller d'un Range filtré vers une feuille annexe.
Tu te rendras compte.

[halaster08]

D'accord Halaster, mais tu peux également effectuer un copier/coller.
La copie d'un Objet Range filtré sera un autre objet Range non filtré.
Si le filtre d'un objet Range affiche 2 lignes visibles discontinues, alors la copie résultera en 2 lignes successives (non filtrées).

Je suis d'accord, mais quitte a faire filtre puis copié/coller, perso je préfère utiliser le filtre avancé qui fait "2 en 1", d'autant que le filtre avancé permet de faire des trucs qu'on peut pas faire avec les filtres normaux, notamment avec les critère calculés.

J’ai quelques difficultés pour adapter à mon code car ne vois pas ce à quoi correspondent

CriteriaRange:=znCriteria
znData

As-tu regarder le tuto directement à la partie VBA? Ou as-tu regarder aussi la partie Excel ?
Si tu regardes la partie Excel, tu verra qu'il n'y a que trois champ à remplir pour faire un filtre avancé, la plage des données (znData), la plage des critères de filtre (znCriteria), et la plage où tu souhaite envoyer le résultat (znExport), une fois que tu as compris comment ça marche en Excel le vba est très simple à écrire.

[informer]

Merci à tous pour toutes ces solutions.

Une précision très importante, le but de la manœuvre.

Je dois modifier un fichier Excel avec les données d’une extraction Access mais impossible de faire un copyFromRecord car les lignes dans Excel sont MAJ partiellement et avec des règles de gestion.

Par conséquent, j’ouvre le fichier Excel depuis Access puis lie sequentiellement un recordset dans Access et filtre le fichier Excel en fonction de valeurs de plusieurs champs du recordset pour enfin MAJ la ligne filtrée avec les données de la ligne active du recordset

Il me faut donc ABSOLUMENT un objet range dans Access qui pointe sur la ligne filtrée pour faire les MAJ.

Je veux faire comme ça plutôt que de faire une succession de find imbriqué car doit trouver la ligne dans Excel correspondante à celle dunrecordset en fonction de plusieurs champs.

Sauf à me dire qu’il est possible de faire un équivalent de FIND sur plusieurs champs et sur la currentSelection.
Vous pouvez me le dire car excel c’est pas ma partie.

Encore merci à tous

[Philippe Tulliez]

Bonjour,
Si tu es plus à l'aise avec Access qu'avec Excel, la manière dont est gérée la zone des critères du filtre avancé d'excel est similaire à l'interface conviviale des requêtes d'Access (QBE).

[halaster08]

Sauf à me dire qu’il est possible de faire un équivalent de FIND sur plusieurs champs et sur la currentSelection.

En ajoutant une colonne qui concatène tes champs tu peux faire un find sur plusieurs champs.

[informer]

Bonjour,
Si tu es plus à l'aise avec Access qu'avec Excel, la manière dont est gérée la zone des critères du filtre avancé d'excel est similaire à l'interface conviviale des requêtes d'Access (QBE).

Bonjour Philippe,

Le truc c'est que je pilote Excel depuis VBA et je n'arrive toujours pas à pointer sur la/les lignes de l'autoFilter

[Philippe Tulliez]

Bonjour,

Le truc c'est que je pilote Excel depuis VBA et je n'arrive toujours pas à pointer sur la/les lignes de l'autoFilter

AutoFilter c'est la méthode du filtre simple qui n'a rien à voir avec AdvancedFilter qui est celle du filtre avancé d'excel
Je n'ai toujours pas compris ce que tu veux faire.
Est-ce du VBA pour Access ou du VBA pour excel que tu utilises ?
Tu peux parfaitement construire un critère calculé en VBA en utilisant deux cellules du classeur dont tu veux copier les données

[informer]

Philippe,

L'objectif est de MAJ des lignes d'un fichier Excel par des données d'une requête dans Access, sachant que toutes les colonnes ne sont pas MAJ et que sur d'autres, il y a des RG.

Donc depuis Access

• J'ouvre mon fichier Excel
• J'initialise un recordSet
• Je parcours le RecordSet et pour chaque enregistrement , je vérifie qu'une ligne correspond dans Excel
• S'il existe une ligne correspondante, alors je modifie les valeurs dans Excel

Le problème est d'obtenir un objet Range qui pointe sur les lignes filtrées pour ensuite les parcourir

Je suis parti sur cette piste mais il semble qu'elle soit imcmplète voir pas adequate avec mon besoin

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set xlsRangeAutoFilter = .SpecialCells(xlCellTypeVisible)

[Philippe Tulliez]

Bonjour,
Un petit exemple

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Sub t()
 Dim rng As Range, rngAfterFilter As Range, Row As Range
 Set rng = ThisWorkbook.Worksheets("BD").Range("A1").CurrentRegion
 Set rngAfterFilter = rng.SpecialCells(xlCellTypeVisible)
 For Each Row In rngAfterFilter.Rows
   Debug.Print Row.Cells(1, 1) ' Affichage de la cellule de la colonne 1 de la ligne
 Next
End Sub

Pour lire la colonne 2

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

   Debug.Print Row.Cells(1, 2) ' Affichage de la cellule de la colonne 1 de la ligne

Mieux encore en utilisant le nom de l'étiquette de colonne. En rouge, ce qui a été ajouté par rapport au code précédent

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Sub t()
 Dim rng As Range, rngAfterFilter As Range, Row As Range, Column As Integer
 Set rng = ThisWorkbook.Worksheets("BD").Range("A1").CurrentRegion
 Set rngAfterFilter = rng.SpecialCells(xlCellTypeVisible)
 For Each Row In rngAfterFilter.Rows
   Column = Application.WorksheetFunction.Match("Prénom", rng.Rows(1), 0)
   Debug.Print Row.Cells(1, Column) ' Affichage de la cellule de la colonne cherchée par la fonction MATCH
 Next
End Sub

[EDIT]
Exemple de code pour ne pas prendre en compte la ligne de titre

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Sub t()
 Dim rngAfterFilter As Range, Row As Range, Column As Integer
 With ThisWorkbook.Worksheets("BD").Range("A1").CurrentRegion
  Column = Application.WorksheetFunction.Match("Prénom", .Rows(1), 0)
  With .Offset(1).Resize(.Rows.Count - 1)
   Set rngAfterFilter = .SpecialCells(xlCellTypeVisible)
  End With
 End With
 For Each Row In rngAfterFilter.Rows
   Debug.Print Row.Cells(1, Column) ' Affichage de la cellule de la colonne 1 de la ligne
 Next
End Sub

et pour obtenir le numéro de la ligne filtrée

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Debug.Print Row.Row

Pour éviter toute confusion dans le nom des variables, il serait évidemment préférable de nommé la plage de la ligne visible par ce nom rngRow
Ce qui donnera alors

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Debug.Print rngRow.Row

[informer]

Philippe,

Si je prends to code, j'en déduis q'uil n'y a pas de propriété sur l'objet

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

 rngAfterFilter = rng.SpecialCells(xlCellTypeVisible)

Qui permette d'avoir les numéros de lignes affichées après autoFilter car il faut passer par Match

Je vais developper une routine qui va lire rngAfterFilter.Address avec un split

[Philippe Tulliez]

Bonjour,
As-tu lu ma réponse jusqu'en bas ?