Discussion :

[TommyLobo]

Salut à tous !
Cela fait plusieurs années que je viens récupérer des réponses et des bouts de code ici, mais là je bloque (je n'ai pas fait de VBA depuis deux ans) et je viens vous demander vos lumières.
J'ai deux classeurs avec une quarantaine d'onglets (de A0 à A10 et d'autres avec des noms comme "fishing", "client_data" etc.) et je veux copier la colonne E du fichier 1 dans la colonne D du fichier 2, et ce pour chaque onglet. En grappillant à droite à gauche et dans mes cours de la fac, ceci marche pour un onglet :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
Sub Importer()
 
    Dim Chemin As String, Fichier As String, Fichier2 As String
 Dim ENMaster As String
ENMaster = InputBox("Name of the EN master (the EN and FR files have to be in the same folder): ", "EN Master")
    '
    Dim wkb As Workbook
    Dim shFrom As Worksheet
    Dim shTo As Worksheet
    Dim varTab As Variant
    '
    '
    Chemin = ThisWorkbook.Path & Application.PathSeparator
    Fichier = "\" & ENMaster
 
 
    Set wkb = Workbooks.Open(Chemin & Fichier)
    Set shFrom = wkb.Worksheets("A2")
    Set shTo = ThisWorkbook.Worksheets("A2")
 
    Application.ScreenUpdating = False
 
 
 
    varTab = shFrom.Range(shFrom.Range("E1"), shFrom.Range("E1").End(xlDown))
    shTo.Range("D1").Resize(UBound(varTab), UBound(varTab, 2)) = varTab
 
 
 
End Sub

Par contre, je cale pour faire cela pour l'ensemble des onglets. La seule solution que j'ai et qui marche a été de copier-coller le tout en changeant le nom de l'onglet (A3, A4, fishing etc.). Ça marche, mais ce n'est pas beau et ça prend de la place.
Vous auriez des pistes pour régler cela ?
Merci !

[anasecu]

Bonsoir,

Il te suffit de faire cette copie

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
    varTab = shFrom.Range(shFrom.Range("E1"), shFrom.Range("E1").End(xlDown))
    Dim sh As Worksheet
    For Each sh In ThisWorkbook.Sheets
        sh.Range("D2").Resize(UBound(varTab), UBound(varTab, 2)) = varTab
    Next sh

[TommyLobo]

Merci de ton aide, mais je me suis mal expliqué :
"je veux copier la colonne E du fichier 1 dans la colonne D du fichier 2, et ce pour chaque onglet" => j'essaye de copier la colonne E de l'onglet A2 dans la colonne D de l'onglet A2 du fichier 2, la colonne E de l'onglet A3 dans la colonne D de l'onglet A3 du fichier 2, etc.

Désolé de t'avoir fait perdre du temps :/

[anasecu]

Bonjour,

Effectivement je n'avais pas bien compris ta demande mais le principe demeure et tu peux réaliser ton projet ainsi

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Sub Importer()
    Dim Chemin As String
    Dim ENMaster As String
    Dim wkb As Workbook
    Dim wko As Workbook
    Dim varTab As Variant
    Dim sh As Worksheet
    '
    Set wko = ThisWorkbook
    ENMaster = InputBox("Name of the EN master (the EN and FR files have to be in the same folder): ", "EN Master")
    '
    Chemin = ThisWorkbook.Path & Application.PathSeparator
    Set wkb = Workbooks.Open(Chemin & ENMaster)
 
    For Each sh In wkb.Sheets ' recopie des onglets
        varTab = sh.Range("E1").Resize(sh.Range("E" & sh.Rows.Count).End(xlUp).Row, 1).Value
        wko.Sheets(sh.Name).Range("D2").Resize(UBound(varTab), UBound(varTab, 2)) = varTab
    Next sh
End Sub

[TommyLobo]

Merci encore !
Une erreur d’exécution 1004 apparaît pour la ligne wko.Sheets(sh.Name).Range("D2").Resize(UBound(varTab), UBound(varTab, 2)) = varTab mais la macro semble tout de même marcher. Je me pencherai dessus à la pause.

[MarcelG]

Bonjour,

1 - Pour ton erreur.
Sachant que tu l'as déclarée, tu n'es pas obligé d'attacher sh.
remplacer

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

wko.Sheets(sh.Name).Range("D2")

par

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

sh.Range("D2")

2 - Il est opportun de libérer les variables affectées à des objets après complète utilisation

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set wko = Nothing

3 - Pour le fun, utiliser Worksheet (La collection Sheets comprenant les graphiques)

[TommyLobo]

J'ai craqué, quand j'ai vu une notification de réponse, je n'ai pas pu attendre la pause ^^
Merci pour ton intervention, mais l'erreur est toujours présente sur la même ligne et contrairement à la version d'anasecu, la copie ne se fait que sur un onglet.
PS: d'ailleurs, c'est D1 qu'il faut et non D2, sinon tout est décalé.

[MarcelG]

D'accord.
J'ai regardé le code d'un peu plus près.
Un collage spécial valeurs ne suffirait-il pas?

[TommyLobo]

Comme je disais, je ne fais plus que très rarement du VBA, donc je ne suis pas sûr de savoir ce qu'est un collage spécial valeurs. En fait, il me faut le contenu des cellules et le formatage (couleur de fond principalement).

[anasecu]

Bonjour,

Une erreur d’exécution 1004 apparaît pour la ligne wko.Sheets(sh.Name)...

Bien entendu la macro telle qu'elle est n'est pas sécurisée et sans doute que tu n'as pas 2 classeurs avec exactement les mêmes structures d'onglets.
il te faudrait vérifier avec le débogage le paramètre qui est erroné car 1004 est un peu fourre tout.

En fait, il me faut le contenu des cellules et le formatage (couleur de fond principalement).

Si tu veux une copie il faut faire une copie tout simplement

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Sub Importer()
    Dim Chemin As String
    Dim ENMaster As String
    Dim wkb As Workbook
    Dim wko As Workbook
    Dim sh As Worksheet
    '
    Set wko = ThisWorkbook
    ENMaster = InputBox("Name of the EN master (the EN and FR files have to be in the same folder): ", "EN Master")
    '
    Chemin = ThisWorkbook.Path & Application.PathSeparator
    Set wkb = Workbooks.Open(Chemin & ENMaster)
 
    For Each sh In wkb.Sheets ' recopie des onglets
        sh.Range("E1").Resize(sh.Range("E" & sh.Rows.Count).End(xlUp).Row, 1).Copy _
        Destination:=wko.Sheets(sh.Name).Range("D1")
    Next sh
End Sub

[TommyLobo]

Si, les deux fichiers ont exactement la même structure : l'un contient des textes en chinois et la traduction anglaise et l'autre est une copie avec les textes anglais et la traduction française. Comme l'anglais de la version française n'est pas à jour, je vais juste le chercher dans la version anglais-chinois.
Avec ta proposition, tout me semble marcher à première vue, il me reste à le tester sur le vrai fichier.

Merci beaucoup de m'avoir donné de ton temps et d'avoir partagé tes connaissances !

[anasecu]

Bonjour,

Merci du retour et je suis content que ceci fonctionne comme tu le souhaites.