Discussion :

[papillon13150]

Bonjour

Dans mon formulaire, apres avoir trouver une recherche de produit (soit par le biais du menu deroulant soit par la bouton rechercher), je ne comprends pas pourquoi il ne m'affiche pas les details du dit produit rechercher ?
Voici la section de code:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
Private Sub moteur_Change()
 
 
If liste_commune.Visible = False Then liste_commune.Visible = True
liste_commune.RowSource = "SELECT DISTINCT libelle FROM liste_commune WHERE libelle LIKE '" & moteur.Text & "*'"
 
 
 
End Sub
 
 
Function masquerlist()
 
If liste_commune.Visible = True Then liste_commune.Visible = False
 
End Function
 
Private Sub categorie_Change()
 
Dim ligne As Recordset
Dim base As DAO.Database
 
Set base = Application.CurrentDb
Set ligne = base.OpenRecordset("SELECT*FROM liste_commune WHERE libelle='" & moteur.Value & "'", dbOpenDynaset)
 
 
ligne.MoveFirst
 
categorie.Value = ligne.Fields("categorie").Value
item.Value = ligne.Fields("item").Value
prix.Value = ligne.Fields("prix").Value
 
 
ligne.Close
base.Close
Set ligne = Nothing
Set base = Nothing
 
 
End Sub

Pourtant, si j'ai bien comprends la suite d'instruction, il selectionne tout depuis la table liste_commune où la valeur du champ "libelle" est egal a la valeur rechercher dans le cadre de recherche "moteur".
Apres quoi il parcours la ligne correspondante dans la table pour afficher le resultat !
Et malgres cela rien ne se passe !
Quel en serait la raison ?
Merci

[hyperion13]

Salut
Avez-vous pensé à compléter Champ Père/Fils dans votre sform ? Champ Père = NomListe / Champ Fils = nom du champ de votre sform

[papillon13150]

C'est à dire bien nommer les differente sform dans l'onglet autre ? Si c'est cela oui

[hyperion13]

Non. Champs Père/Fils dans l'onglet Données. Voir image. La valeur retournée dans ma combobox va être recherchée et comparée parmi les valeurs existantes de ma textbox du sform et affichera ou non des résultats correspondants.
J'ai du mal à associer vos variables dans vos proc et les objets de votre form dans ce post.

[papillon13150]

Merci je verifie cela de suite et vous joint des copie ecran si cela vous premet de vous situer

[hyperion13]

Combien de réf article avez-vous dans votre animalerie ? Parce qu'utiliser une textbox !
Une combobox serait plus simple à mettre en oeuvre pour alimenter vos 3 autres champs de form !

[papillon13150]

Voici la copie ecran de la table "liste_commune" ainsi que la table "detail_temps" mais elle je ne peut verifier dans l'immediat
La finalité comme vous l'avez surement compris est de pouvoir chercher un produit de deux manieres differentes, y rentrer la quantité voulue, l'ajouter dans une table temporaire dans le cas ou il y aurait des produits differents afin d'y editer le bon de vente pour impression c'est l'idée.
En tout cas merci pour le temps que vous accorder afin que je puisse comprendre et avancer dans ce petit projet.

[hyperion13]

Si vous avez 1000 références ou plus, plus, dans votre animalerie, je vous mets au défi de saisir sans faute de frappe leurs libellés respectifs dans la textbox "moteur".
Le plus sage serait de remplacer cette textbox par une combobox indépendante.
Sur l'évènement Form_Load(), vous chargez et alimentez la combobox.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Option Compare Database
Dim dbs As DAO.Database
Dim rst As DAO.Recordset
Dim strSql As String
Private Sub Form_Load()
strSql = "SELECT * FROM liste_commune"
Me!cboliste_commune.RowSource = strSql
Me!cboliste_commune.ColumnCount = 5
Me!cboliste_commune.ColumnWidths = "1cm;3cm;3cm;3cm;2cm"
Me!cboliste_commune.ListWidth = "12cm"
End Sub

Ci-dessous vous alimentez les champs indépendants de votre form selon valeur sélectionnée dans votre combobox

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Private Sub cboliste_commune_Change()
strSql = "SELECT * FROM liste_commune WHERE N° =" & Me.cboliste_commune.Column(0)
Set dbs = CurrentDb
Set rst = dbs.OpenRecordset(strSql, dbOpenDynaset)
    Me.N° = rst!N°
    Me.item = rst!item
    Me.categorie = rst!categorie
    Me.libelle = rst!libelle
    Me.prix = rst!prix
rst.Close
dbs.Close
Set rst = Nothing
Set dbs = Nothing
End Sub

ci-dessous, vous videz tous les contrôles de votre form

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Private Sub btnReset_Click()
Call ToutVider(Me)
End Sub

Ci-dessous, vous ajoutez dans la detail_tmp, le jeu de valeurs affiché dans le form

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Private Sub btnAjout_Click()
Set dbs = CurrentDb
Set rst = dbs.OpenRecordset("detail_tmp")
With rst
    .AddNew
    !item = Me.item
    !categorie = Me.categorie
    !libelle = Me.libelle
    !quantite = Me.quantite
    !prix = Me.prix
    !soustotal = Me.soustotal
    .Update
End With
End Sub

Ci-dessous fonction à recopier dans un module standard

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Public Function ToutVider(frm As Form)
Dim ctrl As Control
For Each ctrl In frm.Controls
   Select Case ctrl.ControlType
      Case acTextBox
           ctrl = ""
      Case acOptionGroup, acComboBox, acListBox
          ctrl = Null
      Case acCheckBox
         ctrl = False
   End Select
Next
End Function

[papillon13150]

Je vous remercie infiniment pour vos conseils et vais appliquer votre méthode je vous tiens informé dès que possible
Très cordialement
PS : il y a moinse 1000 référence environ 300 ce qui est déjà pas mal😊😊😊
Encore merci beaucoup vous tiens informé

[papillon13150]

Alors euh... je ne sais quoi vous dire si ce n'est un grand merci !!! Cela fait bientot plus de 2 semaines que je suis dessus sans resultat à "tourner en rond" a essayer de comprendre ce qui n'allait pas, où etait mes erreurs et vous avez resolu le probleme en un rien de temps ( un dimanche en plus!!!) Il est vrai que je debute en vba access mais je ne pensais etre autant en difficulté et soyez assurer que je vais bien etudier le code .
Une fois de plus merci infiniment pour votre aide!!!