Discussion :

[DAV23]

Bonjour à tous,

Je suis débutant en XSLT et je n'arrive pas à faire ce que je veux avec un xslt.

Mon fichier XML :
<Document>
<DOC.MAIN NO="0001" >
<PAGE.FIRST>12</PAGE.FIRST>
<PAGE.LAST>12</PAGE.LAST>
<PAGE.TOTAL>1</PAGE.TOTAL>
<PAGE.SEQ>1</PAGE.SEQ>
</DOC.MAIN>

<DOC.SUB NO="0001.0001" >
<PAGE.FIRST>13</PAGE.FIRST>
<PAGE.LAST>14</PAGE.LAST>
<PAGE.TOTAL>2</PAGE.TOTAL>
</DOC.SUB>

<DOC.SUB NO="0001.0001.0001" >
<PAGE.FIRST>13</PAGE.FIRST>
<PAGE.LAST>14</PAGE.LAST>
<PAGE.TOTAL>2</PAGE.TOTAL>
</DOC.SUB>

<DOC.SUB NO="0001.0001.0001.0001" >
<PAGE.FIRST>13</PAGE.FIRST>
<PAGE.LAST>14</PAGE.LAST>
<PAGE.TOTAL>2</PAGE.TOTAL>
</DOC.SUB>

</Document>
Je veux un xslt pour avoir cet imbrication selon la hierarchy du NO pour avoir ce résultat:

<Document>
<DOC.MAIN NO="0001" >
<PAGE.FIRST>12</PAGE.FIRST>
<PAGE.LAST>12</PAGE.LAST>
<PAGE.TOTAL>1</PAGE.TOTAL>
<PAGE.SEQ>1</PAGE.SEQ>
</DOC.MAIN>

<DOC.SUB NO="0001.0001" >
<PAGE.FIRST>13</PAGE.FIRST>
<PAGE.LAST>14</PAGE.LAST>
<PAGE.TOTAL>2</PAGE.TOTAL>
<DOC.SUB NO="0001.0001.0001" >
<PAGE.FIRST>13</PAGE.FIRST>
<PAGE.LAST>14</PAGE.LAST>
<PAGE.TOTAL>2</PAGE.TOTAL>
<DOC.SUB NO="0001.0001.0001.0001" >
<PAGE.FIRST>13</PAGE.FIRST>
<PAGE.LAST>14</PAGE.LAST>
<PAGE.TOTAL>2</PAGE.TOTAL>
</DOC.SUB>
</DOC.SUB>
</DOC.SUB>
</Document>


J'ai essayé avec un for-each select, mais ça ne marche pas

<xsl:template match="/">
<DOCUMENT>

<xsl:for-each select="//Document">
<xsl:element name="DOC.PRIM">
<xsl:variable name="NO">
<xsl:value-of select="@NO"/>
</xsl:variable>
<xsl:variable name="x" select="//Document[@NO=$NO]"/>
<xsl:element name="NO">
<xsl:value-of select="$NO"/>
</xsl:element>
<xsl:element name="DOC.SUB">
<xsl:value-of select="."/>
</xsl:element>
</xsl:for-each>


</DOCUMENT>
</xsl:template>


JE VOUS REMERCIE D AVANCE POUR VOTRE AIDE

[tsuji]

Ce n'est pas apte comme problème pour un "grand" débutant - ça risque de mener des imaginations incorrectes en voyant une solution - vous êtes prévenu. Voici comment on peut y arriver en xslt 2.0.

Code xslt2 :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" encoding="utf-8" omit-xml-declaration="yes" indent="yes" />
<xsl:strip-space elements="*" />
 
<xsl:template match="*|@*|text()">
    <xsl:copy>
        <xsl:apply-templates select="*|@*|text()" />
    </xsl:copy>
</xsl:template>
 
<xsl:template match="/">
    <xsl:apply-templates select="Document" />
</xsl:template>
 
<xsl:template match="Document">
    <xsl:copy>
        <xsl:apply-templates select="DOC.MAIN" />
    </xsl:copy>
</xsl:template>
 
<xsl:template match="DOC.MAIN">
    <xsl:copy>
        <xsl:apply-templates select="*|@*|text()" />
    </xsl:copy>
    <!-- xslt2 spécifique -->
    <xsl:variable name="rx" select="concat('^', @NO, '\.\d{4}$')" />
    <xsl:apply-templates select="/Document/DOC.SUB[matches(@NO, $rx)]" mode="special">
        <xsl:sort select="@NO" data-type="text" />
    </xsl:apply-templates>
    <!-- xslt2 spécifique -->
</xsl:template>
 
<xsl:template match="/Document/DOC.SUB" mode="special">
    <xsl:copy>
        <xsl:apply-templates select="*|@*|text()" />
        <!-- xslt2 spécifique -->
        <xsl:variable name="rx" select="concat('^', @NO, '\.\d{4}$')" />
        <xsl:apply-templates select="/Document/DOC.SUB[matches(@NO,$rx)]" mode="special">
            <xsl:sort select="@NO" data-type="text" />
        </xsl:apply-templates>
        <!-- xslt2 spécifique -->
    </xsl:copy>
</xsl:template>
 
</xsl:stylesheet>

[DAV23]

Merci beaucoup, ça marche