Discussion :

[UnVieux]

Bonjour,


mon problème est assez simple, mais je ne vois pas comment le réaliser ??



J'ai 2 fichiers video, et j'aimerais juste savoir si j'ai fait une copie sous un autre nom d'un même fichier. Je sais bien que c'est béta de ne pas s'en souvenir, quand on l'a fait soi-même, mais est ce que vous auriez une idée de comment réaliser cela ??

Connaitre les différences entre les 2, n'est pas obligatoire, parce que je me doute que c'est complexe sur une video. Juste savoir si c'est le même fichier ou pas. J'ai bien pensé au MD5 mais je n'ai aucune idée de comment on le fait, et c'est peut-etre bien trop compliqué pour quelque chose d'aussi simple ?

Merci

[giragu03]

Bonjour,
Je pense qu'un freeware comme http://www.novirusthanks.org/product...checksum-tool/ ou http://winmerge.org/downloads/?lang=fr te conviendra.
Le premier permet soit de générer les hash, soit de comparer les fichiers. L'autre permet une comparaison des fichiers.

[hackoofr]

Windows a un utilitaire intégré appelé Certutil pour générer MD5, SHA256 ou bien SHA512
Alors, j'ai fait ce petit script batch pour comparer deux fichiers en utilisant l'utilitaire Certutil
Juste copier et coller ce petit code dans votre Notepad (Bloc Notes) et enregistrer-le sous le nom de MD5_Files_Compare.bat
Puis faites glisser et déposer vos deux fichiers un par un sur ce batch afin de comparer leurs MD5 HASHES

Code Batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
@echo off
>nul chcp 65001
Color 0A & Mode 110,6
Title Using Certutil Command Line to Compare MD5 HASHES Files by Hackoo 2018
Set "LogFile=%~n0.txt"
Set "MD5hash1="
Set "MD5hash2="
echo(
echo Drag and drop a file N°1 and hit enter key to get its MD5 HASH Checksum 
Set /p File1=
for /f "delims=" %%a in ("%File1%") do (
    Set "FilePath1=%%~fa"
    Set "FileName1=%%~nxa"
)
 
for /f "delims=" %%H in ('CertUtil -hashfile "%FilePath1%" MD5 ^| findstr /I /V "%FileName1%:" ^| findstr /I /V "CertUtil"') Do (
    Set "MD5hash1=%%H"
)
echo HASH of "%FileName1%" = "%MD5hash1%"
Timeout /T 2 /NoBreak>nul
cls
echo(
echo Drag and drop another file N°2 and hit enter key to get its MD5 HASH and to comapre it with "%FileName1%"
Set /p File2=
for /f "delims=" %%b in ("%File2%") do (
    Set "FilePath2=%%~fb"
    Set "FileName2=%%~nxb"
)
 
for /f "delims=" %%G in ('CertUtil -hashfile "%FilePath2%" MD5 ^| findstr /I /V "%FileName2%:" ^| findstr /I /V "CertUtil"') Do (
    Set "MD5hash2=%%G"
)
echo HASH of "%FileName2%" = "%MD5hash2%"
Timeout /T 2 /NoBreak>nul
cls
echo(
If [%MD5hash1%] EQU [%MD5hash2%] (
    Color 0A  
    echo THE TWO FILES ARE AUTHENTIC !
    echo MD5 HASH of "%FileName1%" = "%MD5hash1%"
    echo MD5 HASH of "%FileName2%" = "%MD5hash2%"
) else (
    Color 0C
    echo THE TWO FILES ARE NOT AUTHENTIC !
    echo MD5 HASH of "%FileName1%" = "%MD5hash1%"
    echo MD5 HASH of "%FileName2%" = "%MD5hash2%"
)
(
    If [%MD5hash1%] EQU [%MD5hash2%] ( 
        echo THE TWO FILES ARE AUTHENTIC !
        echo MD5 HASH of "%FileName1%" = "%MD5hash1%"
        echo MD5 HASH of "%FileName2%" = "%MD5hash2%"
    ) else (
        echo THE TWO FILES ARE NOT AUTHENTIC !
        echo MD5 HASH of "%FileName1%" = "%MD5hash1%"
        echo MD5 HASH of "%FileName2%" = "%MD5hash2%"
    )    
)>"%LogFile%"
Timeout /T 4 /NoBreak>nul & Start "" "%LogFile%" 
Exit

[UnVieux]

Ok merci à vous 2 pour votre réponse. Je vais étudié cela.

Le second, le programme batch, je vais le décortiquer en entier, pour comprendre comment il fonctionne.

[hackoofr]

J'ai fait un autre script afin d'obtenir tous les Hashes (MD2, MD4, MD5, SHA1, SHA256, SHA384, SHA512) avec l'outil intégré Certutil.exe de Windows à partir d'un fichier par glisser et déposer sur ce script batch et enregistrer les résultats dans un fichier texte
Get-FileHash.bat

Code Batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
@echo off
Color 0A & Mode 136,10
Title GET ( MD2, MD4, MD5, SHA1, SHA256, SHA384, SHA512 ) HASHES from file by drag and drop using Certutil by Hackoo 2018
set "ScriptName=%~nx0"
if "%~1"=="" goto error
Set "LogFile=%~nx1_HASHES.txt"
If Exist "%LogFile%" Del "%LogFile%"
SetLocal EnableDelayedExpansion
echo(
for %%a in (MD2 MD4 MD5 SHA1 SHA256 SHA384 SHA512) do (
     for /f "skip=1 delims=" %%H in ('CertUtil -hashfile "%~1" %%a ^| findstr /i /v "CertUtil"') do set H=%%H
        echo %%a=!H: =!
        (echo %%a=!H: =!)>>"%LogFile%"
)
Timeout /T 4 /NoBreak>nul & Start "" "%LogFile%" & Exit
::****************************************************************************************
:Error
Color 0C & Mode 104,5
echo( & echo(
echo               You should drag and drop a file over this batch file "%ScriptName%"
Timeout /T 5 /nobreak>nul & exit
::****************************************************************************************

[chrtophe]

ou tout simplement la commande :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

fc /b fichier1 fichier2