Problème de découpage.

**zinaif** · 20/07/2006, 23h03

mon problème est le suivant:
j'ai en entrée une chaine de taille 12 caracteres, je veux la découper automatiquement en un record dont la structure est :
NOM : string [5];
PRE : string[5];
AGE : string[2];
et ceci sans utilisé le COPY (car en réalité le record contient 150 champs)

j'ai utilisé le code suivant :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
 
Type 
   TDonnees = record
                      case integer of
                      0 : ( B1 : record
                                      NOM : string [5];
                                       PRE  : string[5];
                                      AGE  : string[2];
                                     end);
                        1: (B2: string[12]);
                      end;

mais que je renseigne le TDonnees.B2 , je ne réccupere correctement le TDonnees.B1.NOM ,...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
 
 var 
   D : TDonnees;
 Begin
    D.B2:='DUPONDUROC31';
  {le but c'est d'accèder à D.B1.NOM , D.B1.PRE , D.B1.AGE }
   writeln(D.B1.NOM);
   writeln(D.B1.PRE);
   writeln(D.B1.AGE);
 {je devrai reccuper NOM= 'DUPON' PRE='DUROC' , AGE = '31' , mais ca ne fonctionne pas}

si quelqu'un a une méthode je suis preneur . car cela me permettera de recupperer une chaine de 1180 car en un type record.
Merci d'avance .

**Eric Sigoillot** · 21/07/2006, 00h04

Bonjour,

Ca ne peut pas fonctionner ! Ceci est dû à la structure interne d'un ShortString (les types string[X] sont des ShortString).

En mémoire, elle sont représentées par une zone mémoire dont le premier octet contient la longueur effective de la chaîne, et les octets suivants contient la chaîne en elle-même.

Ainsi, si tu stockes la chaîne '12345' dans D.B2, alors en mémoire, il y aura ceci : $05 $31 $32 $33 $34 $35 ($31 = 49, c'est le code ASCII du caractère '1').

De fait, en utilisant à présent le champ D.B1, tu n'auras pas l'effet escompté, puisque tous les champs mis à part D.B1.NOM auront une longueur de chaîne complètement fausse.

Tu n'y arriveras pas de cette manière.

Une solution (non étudiée, c'est uniquement une piste faite à minuit

) pourrait consister en l'utilisation d'un tableau de chaînes à la place d'un record, accompagné d'un ensemble de constante liant le champ à l'index dans le tableau (Nom = 0, Prenom = 1, etc...). Il faudra également stocker la taille des chaînes.

Par exemple :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
const
  dNom = 0;
  dPrenom = 1;
  dAge = 2;
 
  dMax = dAge;
 
const
  CTailleDonnees: array[0..dMax] of Byte = (5, 5, 2);
 
type
  TDonnees = array[0..dMax] of string;
 
procedure ChargeDonnees(const Source: string; var d: TDonnees);
var
  i: Integer;
  Index: Byte;
begin
  Index := 1;
  for i := 0 to dMax do
  begin
    d[i] := Copy(Source, Index, Index + CTailleDonnees[i]);
    Index := Index + CTailleDonnees[i];
  end;
end;

A creuser

@++

**zinaif** · 21/07/2006, 17h26

Merci pour le code, le problème est que je suis obligé d'utliser un Record,
par contre je vous remercie pour les explications, car j'ai compris pourquoi ma méthode ne peut pas fonctionner.
j'ai utilisé une autre méthode :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
 
 Type 
    TDonnees = record
                        NOM : string [5];
                        PRE  : string[5];
                        AGE  : string[2];
                    end;
 var CHAINE : string;
      D : TDonnees ;
   function Decouper(Taille : Integer): string
    begin
      result := Trim(Copy(CHAINE ,1,Taille-1));
      Delete(CHAINE ,1,Taille-1);
    end;
 begin
    CHAINE := 'DUPONDUROC31';
    D.NOM  := Decouper(SizeOf(D.NOM));
    D.PRE   := Decouper(SizeOf(D.PRE));
    D.AGE   := Decouper(SizeOf(D.AGE));
 end.

Avec cette méthode si la taille de mes champs change, j'aurai juste à modifier le RECORD.

Sinon il ya un collègue qui m'a donné une autre idée :
Ecire la chaine dans un fichier TEXTE,
après relire le fichier mais avec le record ;(du style : READ(F,D)).
mais je ne l'est pas encore essayée.

Salutations.

**slimjoe** · 21/07/2006, 17h57

Essaye avec :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
 
type
   TDonnees = record
      case integer of
         0: (B1: record
               NOM: array[1..5] of Char;
               PRE: array[6..10] of Char;
               AGE: array[11..12] of Char;
            end);
         1: (B2: array[1..12] of Char;);
   end;
 
var
   S: TDonnees;
begin
   S.B2 := 'DUPONDUROC31';
   Showmessage(S.B1.NOM + #13 + S.B1.PRE + #13 + S.B1.AGE);
end;

**zinaif** · 22/07/2006, 23h32

j'ai trouver une solution assez intéressante en combinant vos 2 solutions
1. j'ai ajouté un octet obsolete , juste pour avoir les données bien découpée , mais sans utilisé des strings.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
 
 Type
     TDonnees = Record
                        Case integer of
                        0:(O_Obsolete : byte;
                            B1 : record
                                    NOM : array[1..5] of char;
                                    PRE  : array[1..5] of char;
                                    AGE  : array[1..2] of char;
                                 end;
                           );
                        1:(B2:  string[12]);
                       end;
  var 
   D: TDonnees ;
 begin
     D.B2 := 'DUPONDUROC31';
     ShowMessage(D.B1.NOM+#13+D.B1.PRE+#13+D.B1.AGE);
 
 end.

et ceci fonctionne correctement.
Je vous remercie beaucoup .
(ceci va m'évité de faire du découpage, car je travail sur une application DELPHI/AS400 , et je voulais réccupérer l'enregistrement sans accèder au fichier. et pour ceci j'appelle un CALL/AS400 qui me rend l'enregistrement mais sous format long (B2).

**LadyWasky** · 23/10/2006, 13h48

Oui mais non, ton code risque de ne pas fonctionner si ton enregistrement complet (B2) est une chaîne longue, c'est à dire supérieure à 255 caractères étant donné que la représentation en mémoire d'une telle chaîne n'est absolument plus la même !
Et donc, c'est ce qui risque de se passer si tu as plus de 150 champs par enregistrement.

Voici ce que je te propose, d'abord une petite classe Tenregistrement spécialisée dans ce genre de traîtement :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
unit UnitRecord;
 
interface
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs;
 
type
  Tenregistrement=class
  private
    Champs:TStringList;
    Offsets:array of integer;
    FEnregistrement: string;
    function GetOffset(Nom:string):integer; overload;
    function GetLength(Nom:string):byte; overload;
    function GetOffset(Index:integer):integer; overload;
    function GetLength(Index:integer):byte; overload;
    function GetValue(Index:integer):ShortString;
    procedure MAJOffsets;
    procedure SetEnregistrement(const Value: string);
  public
    constructor Create;
    destructor Destroy;
    procedure Clear;
    procedure AddField(Nom:string;Longueur:byte);
    procedure RemoveField(Nom:string); overload;
    procedure RemoveField(Index:integer); overload;
    function GetFieldValue(Nom:string):ShortString; overload;
    function GetFieldValue(index:integer):ShortString; overload;
    procedure SetFieldValue(Nom:string;NewValue:shortString); overload;
    procedure SetFieldValue(Index:integer;NewValue:shortString); overload;
    function GetFieldName(Index:integer):string;
    function GetFieldIndex(Nom:string):integer;
    function GetFieldLength(Nom:string):byte; overload;
    function GetFieldLength(index:integer):byte; overload;
    procedure SetFieldLength(Nom:string;NewLength:byte); overload;
    procedure SetFieldLength(Index:integer;NewLength:byte); overload;
    procedure RenameField(AncienNom,NouveauNom:string);
    procedure LoadFieldDefinitions(NomFichier:string);
    procedure SaveFieldDefinitions(NomFichier:string);
    procedure MoveToRecord(var Dest;Size:integer);
    property Enregistrement:string read FEnregistrement write SetEnregistrement;
  end;
 
implementation
{ Tenregistrement }
 
procedure Tenregistrement.AddField(Nom: string; Longueur: byte);
var i:integer;
begin
  i:=Champs.IndexOfName(Nom);
  if i>0 then begin
                ShowMessage('Ce champ à déjà été défini');
                exit;
              end;
  i:=Champs.Add(Nom+'='+IntToStr(Longueur));
  SetLength(Offsets,Champs.Count);
  if i=0 then begin
                Offsets[0]:=0;
                SetLength(FEnregistrement,Longueur);
              end
         else begin
                Offsets[i]:=Offsets[i-1]+StrToInt(Champs.ValueFromIndex[i-1]);
                SetLength(FEnregistrement,Offsets[i]+Longueur);
              end;
end;
 
constructor Tenregistrement.Create;
begin
  Champs:=TStringList.Create;
  Champs.Clear;
end;
 
destructor Tenregistrement.Destroy;
begin
  Champs.Clear;
  Champs.Free;
end;
 
function Tenregistrement.GetFieldIndex(Nom: string): integer;
begin
  Result:=Champs.IndexOfName(Nom);
end;
 
function Tenregistrement.GetFieldLength(Nom: string): byte;
begin
  Result:=GetLength(Nom);
end;
 
function Tenregistrement.GetFieldName(Index: integer): string;
begin
  Result:=Champs.Names[Index];
end;
 
function Tenregistrement.GetLength(Nom: string): byte;
begin
  Result:=GetLength(Nom);
end;
 
function Tenregistrement.GetValue(Index: integer): ShortString;
begin
 result:=Copy(FEnregistrement,GetOffset(index)+1,GetLength(index));
end;
 
function Tenregistrement.GetOffset(Nom: string): integer;
begin
  Result:=GetOffset(Champs.IndexOfName(Nom));
end;
 
function Tenregistrement.GetOffset(Index: integer): integer;
begin
  Result:=Offsets[index];
end;
 
procedure Tenregistrement.LoadFieldDefinitions(NomFichier: string);
begin
  Champs.LoadFromFile(NomFichier);
  MAJOffsets;
end;
 
procedure Tenregistrement.MAJOffsets;
var i:integer;
    OldLength,NewLength,LastIndex:integer;
begin
  SetLength(Offsets,Champs.Count);
  if Champs.Count>0 then
  begin
    Offsets[0]:=0;
    i:=1;
    while i<Champs.Count do
    begin
      Offsets[i]:=Offsets[i-1]+StrToInt(Champs.ValueFromIndex[i-1]);
      Inc(i);
    end;
  end;
  OldLength:=Length(FEnregistrement);
  LastIndex:=Champs.Count-1;
  if LastIndex>-1
  then NewLength:=Offsets[LastIndex]+StrToInt(Champs.ValueFromIndex[LastIndex])
  else NewLength:=0;
  SetLength(FEnregistrement,NewLength);
  if NewLength>OldLength then
     for i:=OldLength to NewLength do
         FEnregistrement[i]:=' ';
end;
 
procedure Tenregistrement.RemoveField(Index: integer);
begin
  Champs.Delete(index);
  MAJOffsets;
end;
 
procedure Tenregistrement.RemoveField(Nom: string);
begin
  RemoveField(Champs.IndexOfName(Nom));
end;
 
procedure Tenregistrement.RenameField(AncienNom, NouveauNom: string);
var i:integer;
begin
  i:=Champs.IndexOf(NouveauNom);
  if i<>-1 then begin
                 ShowMessage('Le champ '+NouveauNom+' existe déjà !');
                 exit;
               end;
  i:=Champs.IndexOf(AncienNom);
  if i=-1 then begin
                 ShowMessage('Le champ '+AncienNom+' n''existe pas !');
                 exit;
               end;
  Champs.Strings[i]:=NouveauNom+'='+Champs.ValueFromIndex[i];
end;
 
procedure Tenregistrement.SaveFieldDefinitions(NomFichier: string);
begin
  Champs.SaveToFile(NomFichier);
end;
 
procedure Tenregistrement.SetEnregistrement(const Value: string);
var i,CountMax:integer;
begin
  CountMax:=Length(FEnregistrement);
  if Length(Value)<CountMax then CountMax:=Length(Value);
  i:=1;
  while i<=CountMax do
  begin
     FEnregistrement[i]:=Value[i];
     Inc(i);
  end;
  CountMax:=Length(FEnregistrement);
  while i<=CountMax do
  begin
     FEnregistrement[i]:=' ';
     Inc(i);
  end;
end;
 
procedure Tenregistrement.SetFieldLength(Nom: string; NewLength: byte);
begin
  Champs.Values[Nom]:=IntToStr(NewLength);
  MAJOffsets;
end;
 
procedure Tenregistrement.SetFieldValue(Nom: string;
  NewValue: shortString);
begin
  SetFieldValue(Champs.IndexOfName(Nom),NewValue);
end;
 
function Tenregistrement.GetLength(Index: integer): byte;
begin
  Result:=StrToInt(Champs.ValueFromIndex[Index]);
end;
 
function Tenregistrement.GetFieldLength(index: integer): byte;
begin
  result:=GetLength(index);
end;
 
function Tenregistrement.GetFieldValue(index: integer): ShortString;
begin
  Result:=Trim(GetValue(index));
end;
 
procedure Tenregistrement.SetFieldLength(Index:integer; NewLength: byte);
begin
  Champs.ValueFromIndex[Index]:=IntToStr(NewLength);
  MAJOffsets;
end;
 
procedure Tenregistrement.SetFieldValue(Index: integer;
  NewValue: shortString);
var i,j,LNewValue,LChamp:integer;
begin
  i:=1;
  j:=OffSets[index]+1;
  LNewValue:=Length(NewValue);
  LChamp:=GetLength(Index);
  while ((i<=LNewValue) and (i<=LChamp)) do
  begin
    FEnregistrement[j]:=NewValue[i];
    Inc(i);
    Inc(j);
  end;
  while (i<=LChamp) do
  begin
    FEnregistrement[j]:=' ';
    Inc(i);
    Inc(j);
  end;
end;
 
function Tenregistrement.GetFieldValue(Nom: string): ShortString;
begin
  result:=GetFieldValue(Champs.IndexOfName(Nom));
end;
 
procedure Tenregistrement.Clear;
begin
  Champs.Clear;
  SetLength(Offsets,0);
end;
 
procedure Tenregistrement.MoveToRecord(var Dest;Size:integer);
var i:integer;
    LongueurChamp:byte;
    Buffer:array of Byte;
    CurrentOffset:integer;
    S:ShortString;
    SizeOfBuffer:integer;
    MaxSize:integer;
begin
  if ((Length(FEnregistrement)=0) or (Champs.Count=0)) then exit;
  SizeOfBuffer:=Length(FEnregistrement)+Champs.Count;
  if (Size<SizeOfBuffer) then exit;
  SetLength(Buffer,Length(FEnregistrement)+Champs.Count);
  CurrentOffset:=0;
  for i:=0 to Champs.Count-1 do
  begin
    LongueurChamp:=GetLength(i);
    S:=GetFieldValue(i);
    move(LongueurChamp,Buffer[CurrentOffset],1);
    Inc(CurrentOffset);
    move(S[1],Buffer[CurrentOffset],LongueurChamp);
    Inc(CurrentOffset,LongueurChamp);
  end;
 
  move(buffer[0],Dest,Size);
end;
 
 
 
end.

Comment ça marche ?
La classe Tenregistrement te permet de définir les champs d'un enregistrement de longueur fixe représenté sous forme d'une chaîne de caractères.
- Tu définies tes champs avec la méthode AddField,
tu peux aussi :
- les supprimer de ta définition avec RemoveField en indiquant au choix son nom ou son index
- les renommer avec RenameField,
- et même sauver la définition de tes champs dans un fichier SaveFieldDefinitions ou les charger depuis un fichier (LoadFieldDefinitions)
- Tu peux modifier la longueur de tes champs avec SetFieldLength en indiquant au choix son nom ou son index.
- obtenir sa longueur GetFieldLength
- obtenir ou modifier son contenu : GetFieldValue et SetFieldValue

La propriété Enregistrement te permet d'assigner une chaines de caractère et tu peux accéder alors au différent contenu de tes champs.

Tu peux assigner une chaine trop longue à enregistrement, elle sera simplement tronquée en fonction de la longueur de tes champs et la longueur maxi qu'elle devrait avoir.
Une chaine trop courte est automatiquement rallongée avec des espaces.

Pareil si tu renseigne au champ par champ : si ce que tu rentres est trop long pour ta définition de champs, ce sera tronqué, si c'est trop court ce sera rallongé avec des espaces.

La méthode MoveToRecord est spécialement conçue pour toi

Elle te permet de tout transférer dans n'importe quel type de variable (enregistrement, tableau de caractères, etc...), seulement, en second paramètre tu dois indiquer la taille de la variable qui va contenir les données.
Ca marche un petit peu comme la procédure Move

Un exemple, vaut mieux qu'un long discours :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
procedure TForm1.Button1Click(Sender: TObject);
Type
    TDonnees = record
                        NOM : string [5];
                        PRE  : string[5];
                        AGE  : string[2];
                    end;
var MonEnregistrement:Tenregistrement;
    MesDonnees:TDonnees;
begin
  MonEnregistrement:=Tenregistrement.Create;
  MonEnregistrement.AddField('Nom',5);
  MonEnregistrement.AddField('Prénom',5);
  MonEnregistrement.AddField('Age',2);
 
  MonEnregistrement.Enregistrement:='DUPONDUROC31';
 
  //affiche le troisième (index=2) enregistrement, donc l'age
  ShowMessage(MonEnregistrement.GetFieldValue(2));
  //Affiche le Prénom
  ShowMessage(MonEnregistrement.GetFieldValue(('Prénom')));
 
  //Change le Nom du Monsieur
  MonEnregistrement.SetFieldValue('Nom','DULA');
 
  //Copie le tout dans un TRecord
  MonEnregistrement.MoveToRecord(MesDonnees,SizeOf(MesDonnees));
  MonEnregistrement.Free;
 
  with MesDonnees do
  ShowMessage(NOM+' '+PRE+' '+AGE);
end;

Bon dev

Problème de découpage.

Delphi

Discussions similaires

Partager

Partager