Discussion :

[Evodub]

Bonjour,

j'ai une question concernant la manipulation des strings.
Je fais un traitement de comparaison de string (Quoi ?!!,hé oui..)

Je me retrouve face à un petit souci.
Je m'explique, je souhaite comparer 2 cellules qui contiennent des caractères.

Cellule A3 : ALPHA_M
Cellule A4 : ALPHAA

Si j'écris en formule : =SI(A3<A4;"OK";"pasok") --> j'obtiens OK

En revanche si j'écris :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Dim cellule1  As Variant
Dim cellule2  As Variant
Sheets("test").Activate
Set feuille = ThisWorkbook.ActiveSheet
cellule1 = feuille.Cells(3, 1)
cellule2 = feuille.Cells(4, 1)
If cellule1 <= cellule2 Then
MsgBox "coool"
Else
MsgBox "pas cool"
End If
End Sub

--> j'obtiens "pas cool"
Cela signifie que la formule et VB ne sont pas d'accord. Quelqu'un pourrait-il m'expliquer pourquoi ? Et surtout comment faire pour que VB me donne le même résultat ?
Merci d'avance,

Evo

[unparia]

Bonjour

Cela signifie que la formule et VB ne sont pas d'accord.

Ils le seront sans aucun doute lorsque tu leur feras comparer ce qu'il convient de comparer.
En typant, comme tu le fais, en variant les cellule cellule1 et cellule2 puis en écrivant, comme tu le fais) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
cellule1 = feuille.Cells(3, 1)
cellule2 = feuille.Cells(4, 1)
If cellule1 <= cellule2 Then

Tu "perds" complètement VBA, qui ne sait plus ce qu'il doit comparer (des objets Range ou leur valeur ?)
Il est toujours important de préciser la propriété à comparer d'un objet

[Evodub]

Merci pour ton retour.
Hmm mais si je met :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

If cellule1.Value <= cellule2.Value Then

J'ai une erreur à l’exécution : objet requis.
Donc je t'avoue que je suis tout aussi perdu que VB sur ce coup ;-)

[unparia]

Si cellule1 et cellule2 sont des objets (des objets range en l'occurrence) ils doivent être initialisés comme tels, par une instruction Set (ton aide vba interne à consulter : rubrique Set, instruction)
et initialisés comme tels (des objets Range et non en type Variant)

[Evodub]

Pas mieux, je suis toujours largué.
L'aide indique :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Dim YourObject, MyObject, MyStr 
Set MyObject = YourObject    ' Assign object reference. 
' MyObject and YourObject refer to the same object. 
YourObject.Text = "Hello World"    ' Initialize property. 
MyStr = MyObject.Text    ' Returns "Hello World". 
 
' Discontinue association. MyObject no longer refers to YourObject. 
Set MyObject = Nothing    ' Release the object.

Je tente d'adapter sans succès.
Si je copie le code de l'aide en l'état :
erreur "incomptabilité de type" à l'éxecution.

[unparia]

T'est-il si difficile de te montrer aussi strict que ce que je t'ai exposé ?
Regarde comme tout est pourtant simple :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Dim cellule1  As Range
Dim cellule2  As Range
Dim feuille As Worksheet
'Sheets("test").Activate ' nul besoin d'activer. on travaille directement sur les objets
Set feuille = ThisWorkbook.Worksheets("test")
Set cellule1 = feuille.Cells(3, 1)
Set cellule2 = feuille.Cells(4, 1)
If cellule1.Value <= cellule2.Value Then
  MsgBox "coool"
Else
  MsgBox "pas cool"
End If

EDIT : j'ai très délibérément VOULU coller à ton propre code (de sorte à ce que tu comprennes mieux le sens de chaque chose et ne brules pas les étapes)

Tu apprendras ensuite (mais ce sera une autre étape) comment écrire tout cela beaucoup plus simplement et directement (sans le moindre "tremplin").

[Evodub]

Effectivement je suis partie loin... :-) :-)

En revanche j'obtiens toujours "pas cool" comme résultat.

A noter que mon code de départ fonctionne dans 99% des cas. Je ne rencontre un problème que sur la cellule qui contient le caractère _. C'est surement lié.
Je pense que ton code est plus cohérent que le mien, néanmoins les 2 donnent le même résultat pour l'instant.

VB aurait-il du mal à interpréter le caractère "_" ?

[unparia]

Montre donc les valeurs comparées.
Je te rappelle que la comparaison de chaînes de caractères se fait en fonction de la valeur ascii de chaque caractère
le code accii de l'underscore est 95
le code ascii de la lettre "A" est 65
et donc ; l'underscore est par exemple plus grand que la lettre "A"
Je te laisse maintenant là.

[Evodub]

Certes...
Ce qui signifie que la comparaison par formule ne compare pas de la même manière ?

Les valeurs comparées sont dans mon premier post :
Cellule 3 : ALPHA_M
Cellule 4 : ALPHAA

En formule : Cellule3 < Cellule 4
en VB : Cellule3 > Cellule 4

Même résultat que le format de cellule 3 et 4 soit "Standard" ou "Texte".

Merci pour ton aide, bonne soirée !

Quelqu'un d'autre pour tenter de m'expliquer d’où vient cet écart ?

[clementmarcotte]

Bonjour,

Je te rappelle que la comparaison de chaînes de caractères se fait en fonction de la valeur ascii de chaque caractère

Désolé de te décevoir , mais pas toujours

Cela dépend.
C'est vrai sans la ligne suivante dans l'entête ou peut-être dans les options. (Je ne me souviens plus pour VB6-VBA, mais c'est vrai dans VB.net)

Option compare text


dans l'entête du module implique que les lettres majuscules, les lettres accentuées et les lettres minuscules sont comparées et triées en semble selon les paramètres régionaux de Windows, ou les paramètres linguistiques d'Office. donc À, A, à, a sont "égales". C'est pareil pour É, E, Ê, È, ê, è, et toutes les autres lettres. En cas d'égalité, c'est le premier caractêre différent qui l'emporte

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Option Compare Binary

ou rien, c'est l'ordre déterminé par la page de code utilisée qui est appliqué, comme tu le mentionnes.

[Pierre Fauconnier]

Salut.

+1 pour Clément.

Si tu mets Option Compare Text en début de module, tes résultats seront conformes à ceux d'Excel.

Si, dans une procédure particulière, tu veux déroger à l'option précisée en tête de module, tu peux préciser, à l'intérieur de la procédure, comment tu veux que la comparaison se fasse en utilisant la fonction strComp qui permet de définir le type de comparaison quel que soit l'option du module.

strComp(A,B, ...) renvoie -1 si A<B, 0 si A=B et 1 si A>B

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
  If StrComp(Range("a3").Value, Range("a4").Value, vbTextCompare) = -1 Then
    Debug.Print "OK"
  Else
    Debug.Print "Nok"
  End If
  If StrComp(Range("a3").Value, Range("a4").Value, vbBinaryCompare) = -1 Then
    Debug.Print "OK"
  Else
    Debug.Print "Nok"
  End If

D'autres fonctions de texte peuvent utiliser un argument de ce type, par exemple la fonction InStr() qui permet de rechercher une chaine à l'intérieur d'une autre. Pour cette fonction également, tu peux déroger à Option Compare présent (ou absent et donc équivalent à Option Compare Binary) du début de module.

Ces arguments de fonction sont très utiles car elles peuvent être utilisées au sein de fonctions génériques que tu te crées comme outils et que tu souhaites utiliser dans différents projets. Dans ce cas, ils permettent à tes fonctions perso de fonctionner toujours de la même façon dans n'importe quel module de n'importe quel projet sans tenir compte de la ligne d'option. Cela te permet de te créer tes boites à outils que tu balades de projet en projet sans devoir réinventer la roue à chaque fois et sans devoir tenir compte du contexte dans lequel ta fonction perso est utilisée.

[Evodub]

Parfait !
Merci à tous, ça fonctionne très bien avec :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Option Compare Text

Evo