Discussion :

[Fleurey21]

Bonjour à tous

J'ai un fichier excel qui comprend dans une colonne des questions avec à la fin de la question, les mots M1 ou S1 ou les 2

exemples :
"Ce cours a-t-il répondu à vos attentes ? M1"
"Ce programme a-t-il été traité entièrement ? M1+S1"
"Si des supports de cours étaient mis à disposition, étaient-ils adaptés ? S1"

au total dans l'ensemble des questions M1 apparaît 6 fois et S1 apparaît 7 fois

J'ai le code suivant :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
 
With feuilleE           'Workbooks("bilan M2.xlsx").Sheets("Etudiant")
    i1 = 3
    i2 = 2
    For i1 = 3 To nbcolonne
        For i2 = 2 To nbligne
            position = InStr(1, .Cells(i2, 1).Value, "M1")
            If position > 1 Then
                        (instructions incrémentant la valeur de quelques cellules et ne faisant pas appel à la valeur de la variable position)
            End If
            position = InStr(1, Cells(i2, 1), "S1")
            If position > 1 Then
                       (instructions incrémentant la valeur de quelques cellules et ne faisant pas appel à la valeur de la variable position)
            End If
        Next
End With

Or il s'avère que le code n'identifie la chaîne "M1" que 5 fois et la chaîne "S1" qu'une seule fois.
Et je ne parviens pas à comprendre pourquoi

Je vous mets ci-dessous, la liste des questions telles qu'elles sont écrites dans ma feuille excel (une cellule par question):

Ce cours vous paraît-il nécessaire dans le cadre du master ? M1
Ce cours a-t-il répondu à vos attentes ? M1
Ce cours avait-il un programme bien défini ? M1
Ce programme a-t-il été traité entièrement ? M1+S1
Le volume horaire était-il ? M1
Si des supports de cours étaient mis à disposition, étaient-ils adaptés ? S1
Les outils pédagogiques utilisés vous ont-ils permis d'assimiler ce cours ? S1
Les applications pratiques (exercices, TP) ont-elles permis l'appropriation du contenu théorique ? S1
L'enseignant respecte-t-il son planning et ses horaires de cours ? S1
L'enseignant est-il à l'écoute des élèves ? S1
Le(s) contrôle(s) a-t-(ont)-il(s) permis de révéler le niveau de compréhension de ce cours ? M1+S1

je suis preneuse de toute explication

merci d'avance

[Menhir]

Deux For pour un seul Next ? Il est peut probable que ce code ait fonctionné.

Il manque aussi un "." devant le Cell de la recherche de S1.

De plus, sans savoir comment tu incrémentes, difficile de savoir si l'erreur ne vient pas de là.
Déjà que l'initialisation d'une variable (i1 et i2) juste avant un For To alors qu'elle va être la valeur tournante, c'est bizarre...
Tout comme il est étrange que tu n'ais pas initialisé avant les boucles les variables ou cellules qui serviront à l'incrémentation.

[Pierre Fauconnier]

Salut.

Une idée avec des expressions régulières, illustrée ici pour tes questions en A1:A11



Le code de la fonction qui renvoie un tableau de deux élements

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Function M1S1()
  Dim regexp As Object
  Dim matches As Object
  Dim Cell As Range
  Dim m1 As Long, s1 As Long
  Dim Counter As Long
  Dim Result(0 To 1)
  Set regexp = CreateObject("VBScript.RegExp")
  regexp.Pattern = "(M1|S1)?\+?(S1|M1)?$"
  For Each Cell In Range("a1:a11")
    Set matches = regexp.Execute(Cell.Value)
    If matches.Count > 0 Then
      For Counter = 0 To matches(0).submatches.Count - 1
        m1 = m1 + -(matches(0).submatches(Counter) = "M1")
        s1 = s1 + -(matches(0).submatches(Counter) = "S1")
      Next
    End If
  Next
  Result(0) = m1
  Result(1) = s1
  M1S1 = Result
End Function

Son utilisation:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Sub Test()
  Dim Result
  Result = M1S1()
  Debug.Print "M1: " & Result(0)
  Debug.Print "S1: " & Result(1)
End Sub

Son résultat:



Explication du pattern: "(M1|S1)?\+?(S1|M1)?$"

• Le dollar en fin de pattern signifie qu'on ne regarde que la fin de la chaîne;
• Il y a deux groupes qui sont renvoyés car deux (...);
• M1|S1 veut dire "M1" ou "S1";
• ? derrière le premier groupe veut dire 0 ou une fois;
• \+? veut dire qu'après le groupe, on peut trouver 0 ou 1 caractère +;
• S1|M1 dans le second groupe veut dire "S1" ou "M1";
• ? derrière le second groupe veut dire que l'on peut trouver ce groupe 0 ou une fois.

En "clair", on a donc (0 ou 1 fois M1 ou S1) suivi de 0 ou 1 fois + suivi de (0 ou 1 fois S1 ou M1), le tout en fin de chaine. Les groupes sont récupérés dans les submatches.
Il y a 0 ou 1 matches qui peut être récupéré, et il y en a 1 si la chaine se termine par ce que je j'ai énoncé plus haut.

Ca évite les calculs sur les instr plus le code qui doit déterminer s'il y a un + ou pas, ça permet d'ajouter facilement d'autres codes en modifiant le moins de code possible, etc, etc.

Autrement dit, tu mets le principal de ta logique métier dans le pattern de l'expression régulière, ce qui simplifie ton code...

[Fleurey21]

Deux For pour un seul Next ? Il est peut probable que ce code ait fonctionné.

Il manque aussi un "." devant le Cell de la recherche de S1.

De plus, sans savoir comment tu incrémentes, difficile de savoir si l'erreur ne vient pas de là.
Déjà que l'initialisation d'une variable (i1 et i2) juste avant un For To alors qu'elle va être la valeur tournante, c'est bizarre...
Tout comme il est étrange que tu n'ais pas initialisé avant les boucles les variables ou cellules qui serviront à l'incrémentation.

Dans mon programme, il y a bien 2 next.

En fait le problème venait du "." manquant devant Cell à 2 endroits.

Problème résolu

Merci!