Discussion :

[Bono1664]

Bonjour à tous,

Est-il possible en VBA de rechercher et mettre en surbrillance une variable (mot, nombre...) au sein d'un long TextBox dans un UserForm ? et si oui comment formuler le code ?

Je n'ai rien trouvé sur le Net. Merci à celle ou celui qui voudra bien répondre.

Bono1664

[unparia]

Bonjour
oui, ainsi (exemple)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
cherche = "toto"
With TextBox1
  pos = InStr(.Text, cherche)
  If pos > 0 Then
   .SelStart = pos
   .SelLength = Len(cherche)
   .SetFocus
  End If
End With

EDIT : évite d'utiliser le terme "variable" (qui a une signification spécifique) en lieu et place de "chaîne de caractères" (ce que tu cherches). Si ce que tu cherches est le contenu d'une variable, ce n'est pas pour autant une "variable". Ce n'est que son contenu et donc une chaîne de caractères.

[Bono1664]

Bonjour Unparia et merci beaucoup pour cette réponse ultra-rapide.

Je suis débutant en VBA (d'où les erreurs de dénomination), je vais tenter de la mettre en application dans mon projet et je te tiens au courant.

Bonne journée

Bono1664

[Bono1664]

Bonsoir Unparia,

ça marche parfaitement : la formule met bien en surbrillance la chaine de caractères !

Je n'aurais jamais trouvé tout seul.

Merci infiniment.

Cependant, et après avoir fait de nombreuses tentatives, je n'ai pas trouvé le moyen de faire "Find Next". Est-ce possible ?

Bono1664

[patricktoulon]

re
bonjour perso j'aimerais bien savoir pourquoi je n'ai pas tout a fait la selection exacte

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
'texte a l'interieur du texbox ="mais ou est donc passé toto avec sa moubilet'"
cherche = "toto"
With TextBox1
  pos = InStr(.Text, cherche)
  Debug.Print pos
  If pos > 0 Then
   .SelStart = pos
   .SelLength = Len(cherche)
   .SetFocus
  End If
End With

[unparia]

j'aimerais bien savoir pourquoi je n'ai pas tout a fait la selection exacte

- parce que tout ce que j'écris depuis quelques jours l'est à main levée (autres préoccupations mille fois plus importantes)
- parce-que une textbox multiligne a ses particularités
- parce-que dans certains cas, il y a difficulté à définir la position de départ, du fait que vbcrlf contient deux caractères
Je propose cette correction personnelle, qui devrait faire face à tous les cas :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
cherche = "toto"
With TextBox1
  pos = InStr(.Text, cherche)
  If pos > 0 Then
   nbl = UBound(Split(Left(TextBox5, pos), Chr(13)))
   .SelStart = pos - (nbl + 1)
   .SelLength = Len(cherche) + IIf(nbl = 0, 0, nbl / 2)
   Do While Len(.SelText) > Len(cherche)
     .SelLength = .SelLength - 1
   Loop
   .SetFocus
  End If
End With

Je sais :
1) elle est bâclée
2) elle sera du "chinois", mais
3) je n'ai absolument pas le temps de l'expliquer de A à Z. Désolé.

[patricktoulon]

re
j'avais deja essayé sur textbox multi ou monoligne avec enterkeybeviahor en true ou false ainsi de suite ,le resultat toujours pareil
le split oui est plus sur

ce qui etonnant c'est que le demandeur semble avoir un bon resultat

cette formule semble me donne un resultat correcte dans tout les cas

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Private Sub UserForm_Click()
cherche = "toto"
With TextBox1
  plus = UBound(Split(Split(.Text, cherche)(0), vbCrLf)) + 1
  pos = InStr(.Text, cherche)
  If pos > 0 Then
   .SelStart = pos - plus
   .SelLength = Len(cherche)
   .SetFocus
  End If
End With
End Sub

[unparia]

La propriété SelStart est fautive -->> un petit bug mis en évidence par ce code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
toto = "voyons donc la différence en cherchant " & vbCrLf & "la position de toto ici et là"
TextBox1.Text = toto
MsgBox InStr(toto, "toto") & vbCrLf & InStr(TextBox1.Text, "toto") '-->> aucun problème (identique)
TextBox1.SelStart = InStr(toto, "toto")
TextBox1.SetFocus '---->> la position du caret montre que la propriété selstart ne sait pas compter complètement le vbcrlf
' alors que VBA ne se trompe pas, lui --->>
MsgBox Mid(toto, InStr(toto, "toto"), 4)

[patricktoulon]

re
bonjour
Non seulement cela mais aussi la difference d'indexation dans le count (0/1)

demonstration

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
toto = "voyons donc la différence en toto  et titi"' pas de saut de ligne 
TextBox1.Text = toto
MsgBox Mid(toto, 1, 1)' ici j'aurais le "v" (la premiere lettre )
TextBox1.SelStart = 1 'ici le carret sera Apres!! le "v"

le selstart demarre donc son count a 0 tandis que mid lui a 1
donc dans tout les cas il y a forcement "-1" d'office( sans jeu de mots) et moins 1 fois (le nombre de saut de ligne avant le mot recherché)
c'est ce que donne mon double split

apres je ne sais pas si c'est un bug
mais il est tres etonnant qu'ils n'y ai pas pensé chez MS
en effet tout les fonctions string vba excel demarre leur indexation a 1
left(unparia,1) donnera "u" -
mid(unparia,1,1) donnera "u" -
InStr("unparia", "u") donnera 1
etc.....

[Bono1664]

Bonjour,

Merci encore à Unparia et à Patricktoulon, mais je n'ai pas trouvé, malgré toutes mes tentatives, le moyen de faire un "Find Next". Est-ce possible ?

Cordialement

Bono1664

[unparia]

je n'ai pas trouvé, malgré toutes mes tentatives, le moyen de faire un "Find Next

Le faire relève plus de la pensée d'un mécanisme qu'autre chose.
Je n'ai pas le temps de mettre en oeuvre du plus "fin" que ceci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
Private rang As Integer
 
Private Sub CommandButton1_Click()
  Dim cherche As String
  If rang = 0 Then rang = 1
  cherche = "toto"
  suivant cherche, rang
End Sub
Private Sub suivant(cherche As String, ByRef rang As Integer)
 With TextBox1
   plus = UBound(Split(Split(.Text, cherche)(0), vbCrLf)) + 1
   pos = InStr(rang, .Text, cherche)
   If pos > 0 Then
     .SelStart = pos - plus
     .SelLength = Len(cherche)
     .SetFocus
     rang = .SelStart + .SelLength
   Else
     rang = 0
   End If
 
 End With
End Sub

A chaque clic -->> le suivant est sélectionné.

A toi de t'en inspirer et d'inventer un meilleur mécanisme encore

[unparia]

Hé bé ! ...
Cette recherche itérative m'a permis de découvrir qu'aucun des deux codes (tant le mien que celui de patricktoulon) n'était exempt de failles.
Selstart se "plante" notamment si plusieurs retours charriot successifs, par exemple avec cette chaîne de caracrères :

aaaaaaaaaaaaaa
aaaaaatotoaaaaaaaafffffftotonnnnn

nnnnnnnnnnnnntotoz****************to

Je ne trouve pas d'autre remède que celui d'y aller alors "à la hussarde", ainsi :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
Private rang As Integer
Private Sub CommandButton1_Click()
  Dim cherche As String
  cherche = "toto"
  If rang = 0 Then rang = 1
  suivant cherche, rang
End Sub
Private Sub suivant(cherche As String, ByRef rang As Integer)
 Dim k As Integer
 With TextBox1
   If Left(.Text, Len(cherche)) = cherche And rang = 1 Then
      .SelStart = 0
      .SelLength = Len(cherche)
      rang = Len(cherche)
  Else
    For k = rang To Len(Mid(.Text, rang)) + 1000 ' -->>  carrément puisque ne mange pas de pain
      .SelStart = k
      .SelLength = Len(cherche)
      If .SelText = cherche Then rang = .SelStart + Len(cherche): Exit For
    Next
  End If
  .SetFocus
  If .SelText <> cherche Then rang = 0
 End With
End Sub

Et là : pas de faille apparemment, y compris en itératif.

EDIT : code corrigé/complété pour faire face au cas particulier d'un texte commençant par la chaîne recherchée.

[unparia]

Ah, voilà de quoi rester totalement puriste.
Remplacer + 1000 par + .TextLength

[unparia]

J'ai tenté de déceler des failles éventuelles à mon dernier code. Je n'en ai trouvé aucune.

La perfection serait de faire défiler le texte dans la textbox, de sorte à éviter que l'utilisateur ait à se servir de l'ascenseur vertical lorsqu'un nouveau mot est trouvé hors du "champ de vision" en cours.
La chose est réalisable. Je viendrai ajouter cette cerise sur le gâteau dès que mes autres occupations actuelles me laisseront "souffler" un peu.

[patricktoulon]

bonjour unparia
ca fonctionne bien
mais il y a des petites choses inutile dans ton code
notement le rang a 1 si 0 --> inutile
y compris le teste du premier "toto" en left(4)-->> de ce fait inutile

pour le scroll en cas de tres long texte tu n'a absolument rien a faire en selectionnant tu agit sur le scroll
j'ai a jouté le retour a zero de la scroll automatique simplement avec un selstart 0 et start 0 (pour toi c'est rang moi c'est start)
seul petit bemole a l'ouverture du userform la scroll est au max (je n'ai pas reussi a la mettre au min )
pourtant la scroll auto fonctionne fait plusieurs fois le tours en cliquant tu verra
ainsi la methode hussarde donne cela

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Private start As Long
Private Sub CommandButton1_Click()
    Dim cherche As String
    cherche = "toto"
     suivant cherche, start
End Sub
'
'
Private Sub suivant(cherche As String, start)
    Dim i As Integer
    With TextBox1
           If start = 0 Then .SelStart = 0: .SelLength = 0 'ne fonctionne pas au premier click apres ouverture de l'userform
           For i = start To Len(.Text)
            .SelStart = i
            .SelLength = Len(cherche)
            .SetFocus
            If .SelText = cherche Then start = .SelStart + Len(cherche): Exit Sub
            If i > Len(.Text) - 4 Then .SelStart = 0: start = 0'ici ca fonctionne, ca revient bien en haut du texte du textbox
        Next
    End With
End Sub

[unparia]

Pas d'accord.
C'est ce que j'avais d'abord fait, mais qui se mélangeait les pinceaux dans certains cas, notamment si suppressions de lignes au-dessus puis relance en cliquant.

J'ai fait ces gestes avec ton code -->> même punition

Je m'en tiens donc à ma prudence totale. Elle est sans faille et ne mange pas de pain.

[unparia]

Et qu'est devenu mon + 1000 (remplacé ensuite par + .TextLength) ?
Cela aussi, a été "nettoyé" ? -->> Grave erreur.

EDIT : après plusieurs tests (à ma manière de tester), je confirme : désolé, mais ton code génère plusieurs instabilités.

[patricktoulon]

a bon? j'en ai pas eu a part ce soucis de scroll au demarrage de l'usf
textlength a la place de len(.text) c'est ca ?

[unparia]

Ecoute,
Mon temps est REELLEMENT très précieux en ce moment et n'ai pas l'intention de le perdre pour un oui et pour un non ...
Je vais maintenant là où on m'attend avec impatience et à juste titre.
A toi de faire des tests exhaustifs et tu les découvriras, ces instabilités
Bye

[Bono1664]

Bonjour et merci à unparia et patricktoulon,

pour moi les deux propositions "fonctionnent" sans problème et c'est le principal, mais je suis bien incapable d'en évaluer les subtilités (peut-être dans quelques années ? )


Encore mille merci

Cordialement

Bono1664