Discussion :

[Stardust31]

Je ne comprends pas l'utilité de tes tests dans la boucle, ni de l'addition à l'intérieur des IF, puisque tu additionnes une cellule non vide avec une cellule vide. Ca vient à passer la valeur de la non-vide dans la vide, non?

Dans le code suivant, si la condition est rencontrée, Cells(i-1,j) n'a pas été modifiée à la fin du IF...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
            If Cells(i - 1, j) <> "" And Cells(i, j) = "" Then
                Cells(i - 1, j) = Cells(i - 1, j) + Cells(i, j)

D'où ma demande: Explique stp en français ce que tu as et ce que tu souhaites obtenir.

j'avoue : un peu à l'arrache mon code ( t'as vu l'heure ??? ) depuis ce matin 7h je teste ma macro et comme elle "tourne" 40 min à chaque fois...
promis, j'affinerai mon code

post message :

voili :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
 
            If Cells(i - 1, j) = "" And Cells(i, j) <> "" Then
                Cells(i - 1, j) = Cells(i, j)
            End If

[Pierre Fauconnier]

Si j'ai bien compris, voici quelque chose qui pourrait convenir (à adapter à tes colonnes)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Sub Test1()
  Dim i As Long
  Dim j As Long
 
  For i = Range("a1048576").End(xlUp).Row To 2 Step -1
    If Cells(i, 1) = Cells(i - 1, 1) And Cells(i, 3) = Cells(i - 1, 3) Then
      For j = 5 To 9
        If Cells(i, j) = "" Or Cells(i - 1, j) = "" Then Cells(i - 1, j) = Cells(i, j) & Cells(i - 1, j)
      Next j
      Cells(i, 1).EntireRow.Delete
    End If
  Next i
End Sub

[Pierre Fauconnier]

[...]elle "tourne" 40 min à chaque fois...[...]

1. Désactiver le rafraîchissement d'écran en début de macro Application.Screenupdating = false
2. Passer le calcul en manuel en début de macro si tu as des formules qui utilisent la plage que tu manipules application.Calculation = xlCalculationManual
Faudrait voir à y aller par formule dans des colonnes de droite pour compléter la première ligne du doublon éventuel puis supprimer les lignes en doublons sur les colonnes 1 et 3. Ca pourrait être nettement plus rapide. Le tout pourrait se faire par macro, mais parfois, ça va plus vite ainsi.

Autre solution: charger la plage dans un tableau VBA et faire tourner le code sur le tableau plutôt que sur la plage (en remplissant les deux lignes), puis supprimer la plage et y coller le tableau puis supprimer les doublons.

En passant par des formules dans des colonnes à droite, on pourrait avoir un code du genre, à adapter sur une feuille qui ressemblerait à ceci (25 secondes sur 1 million de lignes testées):

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Sub TEst2()
  Dim Formula As String
  Dim myRange As Range
 
Application.ScreenUpdating = False
  Set myRange = Range("j1:n" & Range("a1048576").End(xlUp).Row)
  Formula = "=IF(AND($A2=$A1,$C1=$C2),IF(OR(E1="""",E2=""""),E1&E2,E1),E1&"""")"
  myRange.Formula = Formula
  myRange.Copy
  myRange.PasteSpecial xlPasteValues
  Columns("e:i").Delete xlToLeft
  Range("a1:i" & Range("a1048576").End(xlUp).Row).RemoveDuplicates Columns:=Array(1, 3), Header:=xlNo
  Application.ScreenUpdating = True
End Sub

[Stardust31]

bonjour Pierre
j'ai testé ta dernière proposition : c'est NICKEL !!

si tu avais 3 secondes de plus à m'accorder pour la question suivante...
je ne comprends pas la ligne suivante :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Formula = "=IF(AND($A2=$A1,$C1=$C2),IF(OR(E1="""",E2=""""),E1&E2,E1),E1&"""")"

comment elle prend en compte les cellules E à I ?
je comprends le critère AND($A2=$A1,$C1=$C2)... c'est après que je bugge

merci à toi pour le support

merci à tous des propositions

[mjpmjp]

bonjour,
E1="""" --> E1="" mais entre " et " --> "E1="""" ..."

@+JP

[Pierre Fauconnier]

C'est une formule Excel avec des références absolues et relatives. Comme cette formule est placée en J1:Nx, les $A restent des $A, mais E1 en J1 devient F9 en K9 etc. C'est là que les $ ont toute leur importance pour l'utilisation des références absolues et relatives dans la rédaction d'UNE formule que l'on valide sans boucle en VBA sur une grande plage.

Placer la formule comme je le fais sur toute la plage J1:Nx revient à sélectionner cette plage en Excel puis à saisir la formule en E1 et à valider avec CTRL+ENTER pour la placer dans chaque cellule de la plage sélectionnée en une seule passe.

Cest une méthode très rapide en Excel que l'on peut singer en vba et sui évite les boucles sur 200000 lignes. Pas de boucle est synonyme de gain de performance...

A nouveau, on fait d'abord de l'Excel puis du VBA (voir ma signature...) 😉