Lire une table access

**keikoku84** · 05/02/2018, 00h07

Bonjour,
je rencontre une petite difficulté,
je me permets donc de vous demander de l'aide.

J'ai une base de donnée en access.
Je voudrais pouvoir la lire depuis un programme windev.

Les premières étapes sont je pense bonnes.
j'arrive à me connecter à la base access, je vois même la liste des tables.

Là ou je bute, c'est pour lire par exemple la valeur de la première ligne / première colonne d'une table en particulier.

voici le début de mon code (je vous passe la déclaration des variables)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
//===================================Ouverture de la DB Access===============================================================
HDécritConnexion("connexion","","",sfichier,"",hOledbAccess2000,hOLecture )
 
SI PAS (HOuvreConnexion("connexion")) ALORS
	Erreur("Erreur HyperFileSQL : " + HErreurInfo())
FIN
 
listetable=HListeFichier("","",sfichier,hOledbAccess2000, hOLecture)
Trace(listetable)

le trace de fin me met bien les tables comprises dans la base de données access.
je vois que j'ai bien une table qui s'appelle "Chantier", une autre qui s'appelle "Charge", etc

donc jusque là, je suis ok.

mais je ne trouve pas comment "rentrer" dans la table "Chantier" pour aller lire une donnée. par exemple la valeur de la première ligne première colonne.
surtout que certaines tables de la base access ont le même nom que des tables de ma base windev. donc tous mes essais de HlitPremier ou autre ont échoués.

Si vous avez une piste pour moi, je suis preneur

Merci

**Yusep** · 05/02/2018, 00h49

Bonsoir.
Il manque :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
HChangeConnexion("Chantier", ConexionAccess)
HLit(Chantier, 1)
Trace(Chantier.Champ1)

**keikoku84** · 05/02/2018, 19h03

Merci à toi pour ton aide.

Je rencontre néanmoins toujours une difficulté.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
//===================================================déclaration des variables============================================
listetable est une chaîne 
connexion est une Connexion
sfichier est une chaîne
 
 
//=======================================emplacement de la base access 2000================================
SI OuiNon(1,"Voulez vous lancer l'importation des données ?") ALORS 
	sfichier = fSélecteur("C:\","","","")
	SI Droite(sfichier,3) <> "mdb" ALORS
		Erreur("fichier non valide") 
		RETOUR
	FIN
SINON
	RETOUR
FIN
 
 
//===================================Ouverture de la base accesss===============================================================
HDécritConnexion("connexion","","",sfichier,"",hOledbAccess2000,hOLecture )
 
SI PAS (HOuvreConnexion("connexion")) ALORS
	Erreur("Erreur HyperFileSQL : " + HErreurInfo())
FIN
 
 
//===================================Lecture des données===============================================================
 
 
 
HChangeConnexion("Chantier", "connexion")
HLit(Chantier, 1)
Trace(Chantier.Champ1)

j'ai une erreur comme quoi l'élément Chantier est inconnu. ce qui me semble logique puisque je n'ai pas initialisé de variable chantier.

**midou23175** · 05/02/2018, 20h23

Envoyé par keikoku84

j'ai une erreur comme quoi l'élément Chantier est inconnu. ce qui me semble logique puisque je n'ai pas initialisé de variable chantier.

Chantier est un fichier ?
Ouvrir le fichier ?

**keikoku84** · 05/02/2018, 20h30

Bonsoir,

Chantier est le nom d'une des table de la base access

**Voroltinquo** · 05/02/2018, 20h31

Bonjour,
Dans ton analyse, as-tu importé la description de tes tables access ?

**keikoku84** · 05/02/2018, 20h46

Bonjour,

non, je ne l'ai pas fait, et je ne peux le faire.

Le programme existe déjà, et donc l'analyse également, et je n’ai pas la main dessus.

je veux simplement faire un état qui fera appel à des données de la base windev (ça, je sais récupérer, sans problème) et à partir de la base access.
j'ai "juste" besoin d'un accès en lecture aux tables de la bases access. Mais je n'arrive qu'a voir les tables, mais pas à entrer dedans.

**Voroltinquo** · 05/02/2018, 20h58

Y-a-t'il quelque chose qui t’empêche de créer une autre appli avec ta propre analyse ?
Tu récupère les tables HFSQL et access nécessaires à ton traitement dans l'analyse et hop ...

**midou23175** · 05/02/2018, 20h58

avec la fonction HDéclarationExterne, vous pouvez utiliser des tables access, pour cela utiliser un alias différent pour pouvoir les manipuler.
lien https://doc.pcsoft.fr/fr-FR/index.awp?3044204

**keikoku84** · 05/02/2018, 21h18

Envoyé par Voroltinquo

Y-a-t'il quelque chose qui t’empêche de créer une autre appli avec ta propre analyse ?
Tu récupère les tables HFSQL et access nécessaires à ton traitement dans l'analyse et hop ...

Bonjour, et bien la base HFSQL est utilisée et est alimentée en permanence par moultes utilisateurs. Idem pour la base access
de plus je n'ai pas de clé windev. Je n'ai à ma disposition que le wdetat.

Envoyé par midou23175

avec la fonction HDéclarationExterne, vous pouvez utiliser des tables access, pour cela utiliser un alias différent pour pouvoir les manipuler.
lien https://doc.pcsoft.fr/fr-FR/index.awp?3044204

bonjour,
je mets donc

HDéclareExterne(sfichier,"Chantier",connexion)

?

mais je ne vois pas trop comment l'exploiter après.

**Voroltinquo** · 05/02/2018, 21h32

En fait la question est : "Comment lire des données access avec WDETAT"

**keikoku84** · 05/02/2018, 21h52

oui, effectivement.

Désolé, je ne pensais pas que cela ajoutais une difficulté.

c'est vraiment embêtant cette histoire...
je sais aller lire dans un excel sans problème, mais je n'arrive pas à lire dans une table d'une base access... qui sont pourtant des fichiers excel également ...

**Voroltinquo** · 05/02/2018, 23h51

Il faut dans ce cas passer par des requêtes SQL
Par exemple, dans ton code d'initialisation d'état

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
 
cnxAccess est une Connexion
REQ_Chantier est une Source de Données
gsTxtRequete est chaîne
 
// Paramètres de la connexion
cnxAccess..Provider = hOledbAccess2000
cnxAccess..Utilisateur = ""
cnxAccess..MotDePasse = ""
cnxAccess..Source = "chemin du fichier mdb"
cnxAccess..BaseDeDonnées = ""
cnxAccess..Accès = hOLecture
 
// Ouverture de la connexion
HOuvreConnexion(cnxAccess)
 
gsTxtRequete=[
	SELECT *
	FROM Chantier
]
HExécuteRequêteSQL(REQ_Chantier,cnxAccess,hRequêteSansCorrection,gsTxtRequete)

Il ne reste plus qu'à faire un remplissage de l'état par programmation, cf https://doc.pcsoft.fr/fr-FR/?1011034...ees_programmee

**philouZ** · 06/02/2018, 04h33

Tu as la solution de passer par une requête qui est je pense la meilleure solution pour récupérer les infos.

Sinon si tu souhaites utiliser les ordres Hxxx, Tu vas être obligé d'utiliser les indirections. Quant au problème que tu rencontres de fichier non déclaré, il te suffit de mettre le fichier entre double quote.

**midou23175** · 06/02/2018, 14h25

Bonjour,
voila, je suis pas bien branché sur l'utilisation des connexions. ce que j'ai constaté lors d'une utilisation d'un fichier externe dbf.

j'ai un fichier : "C:\FIC\ECRITURES.DBF" La description de ce fichier n'existe pas l'analyse du projet
j'ai pu manipulé ce fichier avec :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
 
EXTERNE TECRITUREDB
 
HDBOuvre("TECRITUREDB", "KT", "C:\FIC\ECRITURES.DBF")
HLit(TECRITUREDB,1)
Info(TECRITUREDB.LIBELLE)

peut-être je vais dire des bêtises, mais bon... une fois la connexion décrite, essayer de

HDéclareExterne(<Nom du fichier> , <Nom alias> , <Nom de la connexion>)

nom physique du fichier de données, relatif à la base de données externe (extension comprise).
Exemple : "monfichier.mdb" (ou si la base a des sous-répertoires : ".\repertoire\monfichier.mdb").

Nom de la connexion, connexion décrite au préalable
en fonction du nom alias, le fichier va pouvoir être manipulé comme une source de données.

**Voroltinquo** · 06/02/2018, 14h56

Le problème de cette méthode est que contrairement à DBASE ou à HFSQL, toutes les tables sont regroupées dans le MDB. Elle ne sont pas accessibles par fichier physique.

**midou23175** · 06/02/2018, 15h33

Envoyé par Voroltinquo

Le problème de cette méthode est que contrairement à DBASE ou à HFSQL, toutes les tables sont regroupées dans le MDB. Elle ne sont pas accessibles par fichier physique.

Effectivement, ça me revient, c'est un fichier unique.
c'est avec access qu'on peut voir tous les objets, Tables ...
apparemment pas de solution... je pense à un passage par export de la table par exemple sous Excel, les récupérer par programmation, mais c'est pas pratique pour l'utilisateur

**Voroltinquo** · 06/02/2018, 15h43

Le code que j'ai proposé fonctionne parfaitement.
On a bien accès (sans mauvais jeu de mots) aux tuples des tables via les requêtes.
Pour la plupart des requêtes, il y a même la possibilité de passer par l'éditeur de requêtes ACCESS et de copier/coller le code SQL Nom : 2018-02-06_15h49_21.png
Affichages : 1704
Taille : 5,0 Ko

Nom : 2018-02-06_15h49_21.png
Affichages : 1704
Taille : 5,0 Ko

( en bas à droite)

**keikoku84** · 06/02/2018, 22h22

un merci à toi

je vais de ce pas me plonger dans les requêtes SQL

**midou23175** · 08/02/2018, 14h02

Bonjour,

Envoyé par Voroltinquo

Le code que j'ai proposé fonctionne parfaitement.

Oui parfaitement.

@keikoku84
mais pour les ordres Hxxx, comme souligné par philouZ, il va falloir passer par les indirections.
parcours d'un fichier :

- soit directement

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
 
 HLitPremier(CLIENT, IDClient)
 Trace(CLIENT.Nom)

- ou bien par indirection

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
 
 HLitPremier({"CLIENT",indFichier},"IDClient")
 Trace({"CLIENT.Nom",indRubrique})

idem pour la source de données.

Lire une table access

WinDev

Discussions similaires

Partager

Partager