Publipostage : Stocker l'adresse d'un document dans un string

**GaspardBarrier** · 08/01/2018, 15h49

Bonjour à tous,
Je suis en train de réaliser une macro d'automatisation de publipostage, et je souhaite pouvoir réaliser cette opération sur word, à partir de n'importe quel document excel. Pour cela j'ai créé une portion de code qui me permet d'ouvrir une boite de dialogue afin de sélectionner mon fichier source, et de stocker l'adresse de ce fichier dans un string.

Mon problème est donc d'utiliser cette variable dans la suite du code afin que mon ordinateur effectue l'opération de publipostage sur le bon fichier source. Autrement dit, transformer le code suivant :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Sub DocSource(Adresse)
 
    'activation du document, puis du format d'étiquette
    ActiveDocument.MailMerge.MainDocumentType = wdFormLetters
    ActiveDocument.MailMerge.MainDocumentType = wdFormLetters
    ActiveDocument.MailMerge.OpenDataSource Name:= _
        "F:\# 3 Courrier interne et Imprimés\Z (stage)\Gaspard BARRIER\publipostage\listing pour calendriers 2018 -revue du 011217.xls" _
        , ConfirmConversions:=False, ReadOnly:=False, LinkToSource:=True, _
        AddToRecentFiles:=False, PasswordDocument:="", PasswordTemplate:="", _
        WritePasswordDocument:="", WritePasswordTemplate:="", Revert:=False, _
        Format:=wdOpenFormatAuto, Connection:= _
        "Provider=Microsoft.ACE.OLEDB.12.0;User ID=Admin;Data Source=F:\# 3 Courrier interne et Imprimés\Z (stage)\Gaspard BARRIER\publipostage\listing pour calendriers 2018 -revue du 011217.xls;Mode=Read;Extended Properties=""HDR=YES;IMEX=1;"";Jet OLEDB:System data" _
        , SQLStatement:="SELECT * FROM `Feuil1$`", SQLStatement1:="", SubType:= _
        wdMergeSubTypeAccess
End Sub

en remplacant "F:\# 3 Courrier interne et Imprimés\Z (stage)\Gaspard BARRIER\publipostage\listing pour calendriers 2018 -revue du 011217.xls" par ma variable Adresse qui contient l'adresse du document source que je souhaite.

Vous me seriez d'une grande grande aide !

merci

Invité · 08/01/2018, 16h04

Envoyé par GaspardBarrier

Bonjour,

Une piste peut-être ici : Sauvegarder-lire-macro-infos-collection-variables-document-word

**GaspardBarrier** · 08/01/2018, 16h14

Merci beaucoup de ta réponse Eric,

Mon problème réside surtout dans la lisibilité de ma variable string par l'ordinateur, plus que par une message box... en fait je voudrais que la macro qui permet de fixer le format de l'étiquette (le code que j'ai mis au dessus en somme ...) puisse activer mon document dont l'adresse est contenue dans ma variable Adresse, plutôt que d'avoir à réécrire une macro spécifique pour chaque document (en changeant manuellement le nom de l'adresse).

merci

Invité · 08/01/2018, 16h23

Envoyé par GaspardBarrier

Si ton document source fait référence toujours au même fichier Excel pour alimenter ton publipostage, créer une variable dans la collection Variables de ton doc est un moyen de mémoriser l'info.
Je n'ai sans doute pas compris ce que tu voulais faire.

**GaspardBarrier** · 08/01/2018, 16h33

Ce que je veux faire, c'est pouvoir réaliser mon publipostage quel que soit le document excel source. Par exemple, si on le déplace (et que donc on change son adresse), je veux que la macro continue de marcher sans qu'on ait besoin d'y toucher (je suis stagiaire actuellement, et donc je ne serai plus dans mon entreprise dans quelques semaines : les gens avec qui je travaille demandent que je réalise une macro qu'ils n'auront plus besoin de toucher)

Pour arriver à ça, j'ai écrit un code permettant de sélectionner le document source (via une page "ouvrir") et j'ai stocké l'adresse du document sélectionné dans ma variable "Adresse". Maintenant il faut que je change le code que j'ai copié 3 messages au dessus, pour qu'il prenne en entrée l'adresse que l'utilisateur aura sélectionné.

Dis moi si c'est plus clair

Invité · 08/01/2018, 16h41

Envoyé par GaspardBarrier

Si les utilisateurs doivent aller chercher manuellement le fichier excel (emplacement et nom variables), une solution consisterait à passer par un userform pour alimenter ta variable.

**GaspardBarrier** · 08/01/2018, 16h45

moi je suis passé par une FileDialog : j'ai fait comme ça

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Function ShowFileDialog() As String
    Dim Adresse As String
    Dim dlgOpen As FileDialog
    Set dlgOpen = Application.FileDialog( _
        FileDialogType:=msoFileDialogOpen)
    With dlgOpen
        .AllowMultiSelect = False
        .Show
 
    End With
    Adresse = ActiveDocument.Path & Application.PathSeparator & _
    ActiveDocument.Name
    ShowFileDialog = Adresse
 
End Function

**GaspardBarrier** · 08/01/2018, 16h47

ce code permet d'ouvri une page FileDialog, de sélectionner un seul document (AllowMultiSelect = False) et de stocker l'adresse de ce document dans la variable "Adresse"

Invité · 08/01/2018, 17h04

Envoyé par GaspardBarrier

Ton code pointe sur le document Word en cours. J'imagine que ce n'est pas cela que tu souhaitais.

Invité · 08/01/2018, 17h19

Envoyé par GaspardBarrier

Il faut modifier ton code pour récupérer le nom du fichier et la variable Adresse doit être Public si cette variable doit être utilisée dans d'autres modules.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
 
Option Explicit
 
Public Adresse
 
Sub Test()
 
    Adresse = ShowFileDialog
    MsgBox Adresse
 
End Sub
 
Function ShowFileDialog() As String
 
Dim dlgOpen As FileDialog
 
    Set dlgOpen = Application.FileDialog(fileDialogType:=msoFileDialogOpen)
    With dlgOpen
         .AllowMultiSelect = False
         .Show
    End With
 
    ShowFileDialog = dlgOpen.SelectedItems(1)
 
End Function

**GaspardBarrier** · 08/01/2018, 17h35

C'est exactement ça, mais mon probleme à moi maintenant c'est de réutiliser l'adresse stockée dans ce code ci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Sub DocSource(Adresse)
 
    'activation du document, puis du format d'étiquette
    ActiveDocument.MailMerge.MainDocumentType = wdFormLetters
    ActiveDocument.MailMerge.MainDocumentType = wdFormLetters
    ActiveDocument.MailMerge.OpenDataSource Name:= _
        "F:\# 3 Courrier interne et Imprimés\Z (stage)\Gaspard BARRIER\publipostage\listing pour calendriers 2018 -revue du 011217.xls" _
        , ConfirmConversions:=False, ReadOnly:=False, LinkToSource:=True, _
        AddToRecentFiles:=False, PasswordDocument:="", PasswordTemplate:="", _
        WritePasswordDocument:="", WritePasswordTemplate:="", Revert:=False, _
        Format:=wdOpenFormatAuto, Connection:= _
        "Provider=Microsoft.ACE.OLEDB.12.0;User ID=Admin;Data Source=F:\# 3 Courrier interne et Imprimés\Z (stage)\Gaspard BARRIER\publipostage\listing pour calendriers 2018 -revue du 011217.xls;Mode=Read;Extended Properties=""HDR=YES;IMEX=1;"";Jet OLEDB:System data" _
        , SQLStatement:="SELECT * FROM `Feuil1$`", SQLStatement1:="", SubType:= _
        wdMergeSubTypeAccess
End Sub

dans l'optique que mon programme n'aille plus chercher à l'adresse "F:\# 3 Courrier interne et Imprimés\Z (stage)\Gaspard BARRIER\publipostage\listing pour calendriers 2018 -revue du 011217.xls" (qui est susceptible de disparaitre) mais à l'adresse' stockée dans la variable Adresse

merci beaucoup pour tes réponses

PS : est ce que tu peux me dire comme tu fais pour inserer des lignes de code proprement (pas comme ce que je fais dans ce message en somme)

Invité · 08/01/2018, 17h46

Envoyé par GaspardBarrier

Tu peux t'affranchir de la variable Adresse en utilisant directement ta fonction comme paramètre de DocSouce, comme ci-dessous.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
 
Option Explicit
 
Sub Test()
 
    DocSource AdresseFichierExcel
 
End Sub
 
Function AdresseFichierExcel() As String
 
Dim dlgOpen As FileDialog
 
    Set dlgOpen = Application.FileDialog(fileDialogType:=msoFileDialogOpen)
    With dlgOpen
         .AllowMultiSelect = False
         .Show
    End With
    AdresseFichierExcel = dlgOpen.SelectedItems(1)
    Set dlgOpen = Nothing
 
End Function
 
Sub DocSource(ByVal Adresse2 As String)
 
    'activation du document, puis du format d'étiquette
    ActiveDocument.MailMerge.MainDocumentType = wdFormLetters
    ActiveDocument.MailMerge.MainDocumentType = wdFormLetters
    ActiveDocument.MailMerge.OpenDataSource Name:=Adresse2, ConfirmConversions:=False, ReadOnly:=False, LinkToSource:=True, _
    AddToRecentFiles:=False, PasswordDocument:="", PasswordTemplate:="", _
       WritePasswordDocument:="", WritePasswordTemplate:="", Revert:=False, Format:=wdOpenFormatAuto, Connection:= _
       "Provider=Microsoft.ACE.OLEDB.12.0;User ID=Admin;Data Source=" & Adresse2 & ";Mode=Read;Extended Properties=""HDR=YES;IMEX=1;"";Jet OLEDB:System data" _
       , SQLStatement:="SELECT * FROM `Feuil1$`", SQLStatement1:="", SubType:=wdMergeSubTypeAccess
 
End Sub

Pour mettre ton code entre balises, il te faut sélectionner ton code et cliquer sur #.

**GaspardBarrier** · 08/01/2018, 18h12

YESSS ça marche ! Merci beaucoup, tu gères de ouf !!!
doublement merci en fait, pour le #

Tu me retire une vraie épine du pieds ! merci beaucoup !!!

Invité · 09/01/2018, 04h43

Envoyé par GaspardBarrier

Bonjour,

Le dernier code fourni plante si l'utilisateur annule la boite de dialogue. Le code ci-dessous teste la valeur de la boite de dialogue et continue si la variable Adresse est différente de vide.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
 
Option Explicit
 
Public Adresse As String
 
Sub Test()
 
    Adresse = AdresseFichierExcel
    'Debug.Print "Adresse : " & Adresse
    If Adresse <> "" Then DocSource Adresse
 
End Sub
 
Function AdresseFichierExcel() As String
 
Dim dlgOpen As FileDialog
 
    AdresseFichierExcel = ""
    Set dlgOpen = Application.FileDialog(fileDialogType:=msoFileDialogOpen)
    With dlgOpen
         .AllowMultiSelect = False
         If .Show = 0 Then
 
         Else
            AdresseFichierExcel = dlgOpen.SelectedItems(1)
         End If
    End With
    Set dlgOpen = Nothing
 
End Function

**GaspardBarrier** · 16/01/2018, 16h48

Re !

Je reviens sur ce morceau de code parce qu'il ne fonctionne plus, depuis que j'ai fait quelques modification...

J'ai fait évoluer le dossier excel, (grâce à une macro) en un fichier comprenant 5 onglets. L'objectif de cette opération est d'appliquer le petit programme sur lequel je travaille, à tous les onlets de mon fichier.
(pour rappel : )

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Sub DocSource1(ByVal Adresse2 As String)
 
 'ByVal signifie que lors de la passation d’un argument, celui-ci est évalué, et que seule sa valeur est prise en compte.
    'activation du document, puis du format d'étiquette
    ActiveDocument.MailMerge.MainDocumentType = wdFormLetters
    ActiveDocument.MailMerge.MainDocumentType = wdFormLetters
    ActiveDocument.MailMerge.OpenDataSource Name:=Adresse2, ConfirmConversions:=False, ReadOnly:=False, LinkToSource:=True, _
    AddToRecentFiles:=False, PasswordDocument:="", PasswordTemplate:="", _
       WritePasswordDocument:="", WritePasswordTemplate:="", Revert:=False, Format:=wdOpenFormatAuto, Connection:= _
       "Provider=Microsoft.ACE.OLEDB.12.0;User ID=Admin;Data Source=" & Adresse2 & ";Mode=Read;Extended Properties=""HDR=YES;IMEX=1;"";Jet OLEDB:System data" _
       , SQLStatement:="SELECT * FROM `Feuil2$`", SQLStatement1:="", SubType:=wdMergeSubTypeAccess
 
End Sub

Mais pour l'instant, ça ne marche plus et Windows me renvoie le message d'erreur :

"Erreur d'exécution '9105':
La chaine compte plus de 255 caractères"

est ce que tu sais de quoi il s'agit ?

Invité · 16/01/2018, 17h22

Envoyé par GaspardBarrier

Bonjour,

Avez-vous essayé la manip en collant le fichier, actuellement sur le serveur, dans le même répertoire que votre fichier Word pour voir si votre problème vient de la longueur de l'adresse ?
Je ne peux pas vous répondre sans voir votre fichier.

**GaspardBarrier** · 16/01/2018, 18h03

Oui j'ai essayé, mais ça ne marche pas non plus.

Merci énormément pour vos conseils. Je vous envoie le fichier excel sur lequel je bosse. Je vous ai laissé les macros que j'utilise pour obtenir mes 5 onglets, en espérant que vous puissiez les lire.
Comme c'est un document de ma société dans lesquelles sont enregistrées les coordonnées des clients de ma boite, j'espère que vous comprendrez que j'ai du effacer quelques information

Merci beaucoup pour l'aide que vous m'apportez ! c'est vraiment cool

Cordialement

Invité · 16/01/2018, 18h04

Envoyé par GaspardBarrier

Je ne vous promets rien.

**GaspardBarrier** · 16/01/2018, 18h08

Vous en avez déjà fait beaucoup, et je vous suis déjà reconnaissant pour votre aide

Invité · 16/01/2018, 18h17

Envoyé par GaspardBarrier

Si vous simulez manuellement un publipostage sur votre fichier et que vous essayez de voir ce qu'il y a dans la source, que constatez-vous ? Avez vous la possibilité de choisir votre onglet ? Qu'en déduisez vous ?

Publipostage : Stocker l'adresse d'un document dans un string

Word

Discussions similaires

Partager

Partager