Discussion :

[capi81]

Bonsoir le forum
J'ai 1 classeur a partir duquel je soubaite effacer les plages de toutes les feuilles d'un classeur choisit.
Le nom du classeur est intitu "zombcap".
Voici le code que j'ai essayé de rédiger:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Dim wb as workbook
Dim sh as worksheet
Set wb = workbooks("zombcap.xlsx")
with wb
For each sh in worksheets
sh.range("c3:m54").clearcontents
next sh
end with

ce code ne finctionne pas bien.
Quelqu'un pourrait-il me donner 1coup de main avec si possible des explications afin que prochainement ke puisse m'y prendre seul?
Je travail avec un smartphone donc certaines option me manquent pour rendre plus lisibles mes codes.
Merci a tous

[anasecu]

Bonsoir,

ce code ne finctionne pas bien.

Comme ceci ce devrait être mieux

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Dim wb As Workbook
Dim sh As Worksheet
Set wb = Workbooks("zombcap.xlsx")
For Each sh In wb.Worksheets
    sh.Range("c3:m54").ClearContents
Next sh

[patricktoulon]

capi81
ton code aurait pu fonctionner si tu n'avais pas oublier que dans un "with/end with " les enfant sont toujours précédés d'un "."

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Dim wb as workbook
 Dim sh as worksheet
 Set wb = workbooks("zombcap.xlsx")
 with wb
 For each sh in .worksheets
 sh.range("c3:m54").clearcontents
 next sh
 end with

cela dit la versiond'anasecu est bien aussi

[capi81]

Bonjour a tous
Merci pour vos contributions.
Je viens de tester mais j'ai un message d'erreur: l'indice n'appartient pas à la sélection et cette partie du code est souligné:set wb=workbooks("zombcap.xlsx")

[kiki29]

Salut, à tester et adapter

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Option Explicit
 
Sub tst()
Dim wb As Workbook
Dim sh As Worksheet
Dim sFichier As String
    Application.ScreenUpdating = False
    sFichier = ThisWorkbook.Path & "\" & "zombcap.xlsx"
    Set wb = Workbooks.Open(sFichier)
    For Each sh In wb.Worksheets
        sh.Range("c3:m54").ClearContents
    Next sh
    wb.Close True
    Set sh = Nothing
    Set wb = Nothing
    Application.ScreenUpdating = True
End Sub

A lire également : Lire et écrire dans les classeurs Excel fermés

[capi81]

Bonjour kiki29 et le forum
Merci pour votre solution.
Elle fonctionne bien.
Je profite confirmer que les précédents codes ont fonctionné et m'excuse auprès de ceux qui ont été à leurs origines.