Discussion :

[enicnath]

Bonjour,

Je souhaiterais affecter à une variable, les valeurs dépendant d'une autre variable dont le nom est donné par une troisième.

Par exemple, supposons qu'il existe une fonction (appelons-la "fonction"), telle que X=fonction(Y), où Y désigne une troisième variable quelconque.

Est-ce possible sous SAS ?

[mgdondon]

Bonjour enicnath,

Est-ce que le programme suivant répond à votre question ou est-ce que le nom de la variable est lui aussi dans la table ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
data test;
  input V1 V2;
  cards;
2 3
4 5
6 7
8 9
;
run;
 
%macro test(var);
  data test;
    set test;
    valeur=&var;
  run;
 
  proc print data=test noobs;
  run;
%mend;

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
%test(V1);

V1    V2   valeur
 2     3      2
 4     5      4
 6     7      6
 8     9      8

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
%test(V2);

V1    V2   valeur
 2     3      3
 4     5      5
 6     7      7
 8     9      9

Cordialement,

[enicnath]

Bonjour mgdondon,

Merci de votre réponse.
L'idée est un peu celle-là, mais ma question portait plutôt sur une possibilité hors macro-sas.
L'instruction X=fonction(Y) aurait un peu le rôle d'une instruction du genre :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
select (Y);
    when ('A') X=A;
    when ('B') X=B;
....
end;

où A, B, ... sont des variables.

Mais je n'ai rien vu dans la doc qui permette de réaliser ce genre d'instruction (sauf effectivement en passant par une macro) ; je ne serais pas étonné que ça ne soit pas possible

[mgdondon]

Bonjour eninath,

Si le nom de la variable est dans la table, vous pouvez utiliser la fonction vvaluex() :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
data test;
  input V1 V2 nomvar $2.;
  cards;
2 3 V1
4 5 V1
6 7 V2
8 9 V2
;
run;
 
data test;
  set test;
  valeur = vvaluex(nomvar);
run;

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
V1    V2    nomvar   valeur
 2     3      V1       2
 4     5      V1       4
 6     7      V2       7
 8     9      V2       9

Cordialement,

[enicnath]

Bonjour mgdondon,
C'est exactement ce que je recherche.
Mon objectif est de traiter cette question dans une instruction array. Voici un exemple

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
data test (drop=V1 V2 NV1 NV2);
  input V1 V2 NV1 NV2;
	array MesVar V1 V2;
	do over MesVar; 
		NomVar=vname(MesVar); 
		Valeur=vvaluex(compress('N'!!NomVar)); 
		output;
	end;
  cards;
3 4 2 3
4 3 4 5
3 3 6 7
4 4 8 9
;
run;
proc print data=Test; run;

L'avantage est que le nom de la variable en paramètre de la fonction vvaluex est complètement paramétrable.
Super !