1. #1
    Futur Membre du Club
    Inscrit en
    décembre 2012
    Messages
    16
    Détails du profil
    Informations forums :
    Inscription : décembre 2012
    Messages : 16
    Points : 6
    Points
    6

    Par défaut Changer l'icone d'un répertoire

    Bonjour à tous,

    Je recherche le code VBS pour changer l'icone d'un répertoire.

    Merci pour votre aide.

  2. #2
    Futur Membre du Club
    Inscrit en
    décembre 2012
    Messages
    16
    Détails du profil
    Informations forums :
    Inscription : décembre 2012
    Messages : 16
    Points : 6
    Points
    6

    Par défaut

    Bonjour,

    Est-ce que quelqu'un aurait un code à me proposer ?

    Merci d'avance.

  3. #3
    Expert éminent sénior
    Avatar de Marc-L
    Homme Profil pro
    Développeur informatique
    Inscrit en
    avril 2013
    Messages
    9 488
    Détails du profil
    Informations personnelles :
    Sexe : Homme
    Localisation : France, Hauts de Seine (Île de France)

    Informations professionnelles :
    Activité : Développeur informatique
    Secteur : High Tech - Éditeur de logiciels

    Informations forums :
    Inscription : avril 2013
    Messages : 9 488
    Points : 18 989
    Points
    18 989

    Par défaut

    Bonjour,

    voir la réponse apportée sur un autre forum …

    ___________________________________________________________________________________________________________
    Je suis Paris, Egypte, Nigeria, New-York, Mogadicio, Barcelone, London, Manchester, Stockholm, Istanbul, Berlin, Nice, Bruxelles, Charlie, …
    . . . . . Comme la vitesse de la lumière est supérieure à celle du son, certains ont l'air brillant avant d'avoir l'air con !

  4. #4
    Membre émérite

    Homme Profil pro
    Responsable déploiement (SCCM, AirWatch, AMP)
    Inscrit en
    juillet 2014
    Messages
    1 236
    Détails du profil
    Informations personnelles :
    Sexe : Homme
    Âge : 39
    Localisation : France, Seine Saint Denis (Île de France)

    Informations professionnelles :
    Activité : Responsable déploiement (SCCM, AirWatch, AMP)
    Secteur : Transports

    Informations forums :
    Inscription : juillet 2014
    Messages : 1 236
    Points : 2 309
    Points
    2 309

  5. #5
    Expert éminent
    Avatar de hackoofr
    Homme Profil pro
    Enseignant
    Inscrit en
    juin 2009
    Messages
    3 494
    Détails du profil
    Informations personnelles :
    Sexe : Homme
    Âge : 43
    Localisation : Tunisie

    Informations professionnelles :
    Activité : Enseignant

    Informations forums :
    Inscription : juin 2009
    Messages : 3 494
    Points : 8 416
    Points
    8 416

  6. #6
    Expert éminent
    Avatar de hackoofr
    Homme Profil pro
    Enseignant
    Inscrit en
    juin 2009
    Messages
    3 494
    Détails du profil
    Informations personnelles :
    Sexe : Homme
    Âge : 43
    Localisation : Tunisie

    Informations professionnelles :
    Activité : Enseignant

    Informations forums :
    Inscription : juin 2009
    Messages : 3 494
    Points : 8 416
    Points
    8 416

    Par défaut


    Voici la version en vbscript qui vous permet de créer un répertoire dans votre bureau et de changer son icône.
    L'idée de base de ce script est basée principalement en deux :
    1. 1 ère condition : il faut créer un dossier et de le transformer en un dossier système.
    2. 2 ème condition : Créer le fichier système caché Desktop.ini avec les informations de l'icône dans ce dossier.


    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    3
    4
    5
    6
    7
    8
    9
    10
    11
    12
    13
    14
    15
    16
    17
    18
    19
    20
    21
    22
    23
    24
    25
    26
    27
    28
    29
    30
    31
    32
    33
    34
    35
    36
    37
    38
    39
    40
    41
    42
    43
    44
    45
    46
    47
    48
    49
    50
    51
    52
    53
    54
    55
    56
    57
    58
    Option Explicit
    Dim ws,Icon,strText,DesktopFolder,strFolder
    Set ws = CreateObject("wscript.Shell")
    DesktopFolder = ws.SpecialFolders("Desktop")
    strFolder = DesktopFolder & "\Hackoo Folder Icon Changer"
    Icon = "%systemroot%\system32\shell32.dll,-48"
    strText = "[.ShellClassInfo]" & vbCrLf &_
    "IconResource="& Icon & vbCrLf &_
    "IconFile=%systemroot%\system32\shell32.dll"
    'Create a folder on our desktop
    Call SmartCreateFolder(strFolder)
    'Transform our folder to a system folder
    Call Execute("attrib +s " & DblQuote(strFolder))
    Call Write_INI_File(strFolder,strText)
    '********************************************************************
    Sub SmartCreateFolder(strFolder)
        Dim oFSO:Set oFSO = CreateObject("Scripting.FileSystemObject")
        If oFSO.FolderExists(strFolder) Then
            Exit Sub
        Else
            SmartCreateFolder(oFSO.GetParentFolderName(strFolder))
        End If
        oFSO.CreateFolder(strFolder)
        Set oFSO = Nothing    
    End Sub
    '********************************************************************
    Function Execute(StrCmd)
        Dim ws,MyCmd,Resultat
        Set ws = CreateObject("wscript.Shell")
            MyCmd = "CMD /C " & StrCmd & ""
            Resultat = ws.run(MyCmd,0,True)
            If Resultat <> 0 Then
                MsgBox "Une erreur inconnue est survenue !",16,_
                "Une erreur inconnue est survenue !"
            End If
        Execute = Resultat
    End Function
    '********************************************************************
    Sub Write_INI_File(PathFolder,strText)
    Dim fs,ts,DesktopINI
    Const ForWriting = 2
        DesktopINI = PathFolder & "\Desktop.ini"
        Set fs = CreateObject("Scripting.FileSystemObject")
        if fs.FileExists(DesktopINI) Then 
            Call Execute("Attrib -R -H -S "& DblQuote(DesktopINI))
            fs.DeleteFile DesktopINI
        end If
        Set ts = fs.OpenTextFile(DesktopINI,ForWriting,True)
        ts.WriteLine strText
        ts.Close
    'Transform the file Desktop.ini to a hidden and system file
        Call Execute("Attrib +R +H +S "& DblQuote(DesktopINI))
    End Sub
    '********************************************************************
    Function DblQuote(Str)
        DblQuote = Chr(34) & Str & Chr(34)
    End Function
    '********************************************************************

Discussions similaires

  1. Réponses: 4
    Dernier message: 22/04/2005, 09h47
  2. [MFC]changer l'icone d'un éxécutable
    Par Blo0d4x3 dans le forum MFC
    Réponses: 3
    Dernier message: 31/08/2004, 18h20
  3. [C#] Changer l'icone dynamiquement
    Par Piolet dans le forum Windows Forms
    Réponses: 16
    Dernier message: 25/08/2004, 14h08
  4. [Swing]changer l'icone du hotjava
    Par juflata dans le forum AWT/Swing
    Réponses: 2
    Dernier message: 11/08/2004, 15h08
  5. Réponses: 4
    Dernier message: 16/02/2004, 16h55

Partager

Partager
  • Envoyer la discussion sur Viadeo
  • Envoyer la discussion sur Twitter
  • Envoyer la discussion sur Google
  • Envoyer la discussion sur Facebook
  • Envoyer la discussion sur Digg
  • Envoyer la discussion sur Delicious
  • Envoyer la discussion sur MySpace
  • Envoyer la discussion sur Yahoo