Discussion :

[jojo86]

Bonjour,
J'ai une macro sous excel qui récupéré le contenu de plusieurs fichiers excel. Je dois réaliser plusieurs contrôle/modification/compilation des données sur ces fichiers pour ensuite les insérer dans Access.
Je ne peu donc pas insérer directement les fichiers dans Access.

J'utilises une boucle sur le recordset de mon classeur pour faire un Insert Into vers access.
Lorsque la base access est sur mon disque local tout vas bien, ça met moins de 30 secondes pour insérer 100 000 lignes.

Dès que je place la base de données sur un disque réseau de l'entreprise, le temps est ingérable. (Plusieurs heures)
Le temps d'accès au réseau est très lent. Savez-vous s'il existe une méthode d'importation plus rapide que de faire du ligne à ligne?

J'avais lu un jour qu'il existait une méthode pour importer un classeur en entier dans access et que c'était très rapide. Je n'ai pas retrouvé cette méthode.
Mon idée serait de modifier/compiler mes données, de générer un classeur et d'insérer ce classeur dans access avec une autre méthode que celle du ligne à ligne...


Merci d'avance pour vos idées.

Jojo

[Invité]

Bonsoir,

https://www.developpez.net/forums/d1...t/#post9666110

[jojo86]

Bonsoir,

https://www.developpez.net/forums/d1...t/#post9666110

Salut merci de ta visite.
Par contre, je ne pige pas comment l’exploiter car je suis sous excel et je veux insérer dans access depuis excel.

Dans le lien que tu m’as donné, le code s’execute depuis access.

Est-ce que ca va fonctionner si depuis excel je fais un insert de cette manière :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Insert Into MyTableAccess (champ1, champ2, etc...) select * from  (Select * from [Feuil1$] in 'C:\rep\Classeur1.xls' 'Excel 12.0;HDR=Yes')

Je testerai ca demain.

[Invité]

Oui bien sur! TU prépares ta requête dans Access comme dans le petit film du lien; ensuite tu copie colle le script sql dans Excel. Dans Excel tu fais une connexion Adodb sur ta base Access!

Après tu pourras modifier dynamiquement les fichiers sources dans Excel vba.

[jojo86]

Oui bien sur! TU prépares ta requête dans Access comme dans le petit film du lien; ensuite tu copie colle le script sql dans Excel. Dans Excel tu fais une connexion Adodb sur ta base Access!

Après tu pourras modifier dynamiquement les fichiers sources dans Excel vba.

Super c'est exactement ce que je souhaitais faire !!!
Je dois juste adapter mon code pour ne plus envoyer directement les données dans access, mais les stocker dans une feuille excel temporaire.
Merci beaucoup de ton aide.

[jojo86]

Salut, j'ai un message d'erreur depuis excel lors de l'ajout dans ma table access.

J'ai bien respecté cette formulation :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
Connexion.Execute "Insert Into Table ([Champ1], [Champ2]) Select * from (Select distinct [ChampExcel1] as Champ1, [ChampExcel2] as Champ2 from [FeuilExcel$] In 'Chemin\Complet\Vers\Fichier.xls' 'Excel 12.0;HDR=Yes')"

J'ai le message : "La méthode 'Execute' de l'objet _Connection' a échoué

J'ai du louper un truc mais je ne sais pas quoi...

[jojo86]

Non en fait c'est bon, j'avais juste oublié de mettre entre crochets les noms de champs access lors du changement de nom

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

ChampExcel as [ChampAccess]

C'est hallucinant la rapidité du truc pour l'ajout de donnée ! Je retombe sur des temps beaucoup plus cohérents, moins d'une minute !!!

Merci beaucoup !

[Invité]

Code Pour la culture! :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
Public Connexion As Object
Private Sub test()
Const BaseAccess = "C:\Users\xxx\Documents\Base de données6.accdb"
Const Xls = "C:\MyRepertoire2\MyFichier.xlsx"
Set Connexion = CreateObject("Adodb.connection")
With Connexion
  .Open "Provider=Microsoft.ACE.OLEDB.12.0;Data Source=" & BaseAccess & ";"
  MsgBox "toto Existe " & TableExiste("toto")
  If TableExiste("toto") Then
    .Execute "Insert into [toto] select * from (select * from [Feuil1$] in '" & Xls & "' 'Excel 12.0;HDR=Yes')"
  Else
      .Execute "select * into [toto] from (select * from [Feuil1$] in '" & Xls & "' 'Excel 12.0;HDR=Yes')"
  End If
  ThisWorkbook.Sheets("BD").Range("A2").CopyFromRecordset .Execute("Select * from [toto]")
 MsgBox "toto Existe " & TableExiste("toto")
  .Execute "Drop table [toto]"
  MsgBox "toto Existe " & TableExiste("toto")
     .Close
End With
 
 
 
 
End Sub
 
 
Public Property Get TableExiste(TableName As String) As Boolean
With Connexion.OpenSchema(20)
    If Not .EOF Then
      .Filter = "TABLE_NAME ='" & TableName & "'"
       TableExiste = Not .EOF
    End If
    .Close
End With
End Property

dans ta méthode précédant tu sollicitais énormément le réseau c'est comme si tu envoyais 100 000 fichier de 1 Ko! dans ma méthode tu envois 1 fichier de 1 Ko et c'est Access qui gère!

[jojo86]

C'est vraiment une super méthode, je n'étais jamais tombé dessus sur le net, pourtant j'en ai parcouru des forums...
Cette méthode est bien plus rapide, je vais en profiter pour reprendre des macros déjà existantes pour optimiser les temps de réponse.

Merci beaucoup !