Discussion :

[Doltd]

Bonjour,

Je possède actuellement un fichier excel avec 3 colonnes :
A → Date (jj/mm/aaa)
B → Valeur (débits)
C → Sines complémentaires (#, !, ... en utilisations avec une légende)

Les données débutent du 24/08/1999 jusqu'à aujourd'hui (beaucoup de jours ne sont pas affiché du fait qu'il n'y a pas eu de relevé)

Afin de classer ces valeurs je souhaiterais réaliser un tableau dans ce style :
E F G H I J
1 | 1999 | 2000 | 2001 | ...
2 Janvier
3 Février
4 Mars
5 ...

Les mois sont intégrés en date (01/01/1900, 01/02/1900, ...) et mis en forme pour n'afficher que le mois (janvier, Février, ...).
Ce tableau regrouperais les moyennes des valeurs du mois en questions.

J'ai pu essayer ces formules (testées en format normal et matriciel):
=MOYENNE(SI(($A$2:$A$4813<DATE(G$1;MOIS($E3);1))*($A$2:$A$4813>DATE(G$1;MOIS($E2);1)*($B$2:$B$4813<>""));$B$2:$B$4813))

(voici d'autres essais sous une autre forme de tableau
F
30 janv-99
31 fév-99
32 ...
) :

=MOYENNE(SI(($A$1:$A$4813<F31)*($A$1:$A$4813>F30)*($B$1:$B$4813<>"");$B$1:$B$4813))

=MOYENNE.SI.ENS($B$2:$B$4813;$A$2:$A$4813;">="&F30;$A$2:$A$4813;"<"&F31)

=SOMMEPROD(($A$2:$C$4813>=F30)*($A$2:$C$4813<F31)*$B$2:$B$4813)

=MOYENNE(SI(($A$2:$A$4813>=F30)*($A$2:$A$4813<F31);$B$2:$B$4813))

Malheureusement elle me retourne soit "#DIV/0!" soit "#VALEUR!" soit "0".

Pouvez-vous m'aider à trouver une formule fonctionnelle dans ces deux cas :
1. Dans le premier style de tableau, réaliser une moyenne des valeurs en fonction du mois ?
2. Toujours dans le premier style de tableau, réaliser une moyenne des valeurs en fonction du moi ET des signes complémentaires ?

Si pour une meilleure compréhension un fichier est nécessaire n'hésitez pas à me demander.

Cordialement,
Dorian

[jerome.vaussenat]

Salut,

Pour moi, c'est un TCD.

En plus comme tu es sur la version 2016. Quand tu va mettre les dates "en ligne" Excel va automatiquement faire les groupes Année, Trimestre et Mois.

pour en savoir plus sur les tcd
http://silkyroad.developpez.com/excel/tcd/

[Menhir]

Remplace Janvier, Février, Mars, etc. de ton tableau de synthèse par 1, 2, 3, etc. (quitte à rajouter une colonne et à masquer celle-ci si tu le souhaite).

Mets en F2 :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=MOYENNE(SI(ET(MOIS($A$2:$A$4813)=$E2;ANNEE($A$2:$A$4813)=F$1);$B$2:$B$4813;""))

Valide en fonction matricielle et copie la cellule sur les autres cellules du tableau.

[Doltd]

En ce qui concerne les TCD j'ai pas trop l'habitude de m'en servir encore, faut que j'y bosse dessus, je ferais un retour plus tard sur ce point là.

Par contre en ce qui concerne ta solution Menhir, la formule me renvoi quand même "#VALEUR!". J'ai bien compris ce que tu as tenté mais malheureusement rien n'y fait.

Dorian

[Doltd]

Je tien à demander pardon pour cet affront :
J'ai pas fait attention mais mais nombres sont au format texte car ils sont composé de "." et non pas de ",".

*Toujours faire attentions aux bases!!!!*

Du coup les formules que j'ai indiqué dans mon premier post fonctionnent par contre la formule de Menhir n'a pas l'air de vouloir fonctionner.

Un grand merci à vous tous

Dorian

[Menhir]

Il faut décomposer pour comprendre d'où vient le problème.

Essaye de mettre dans n'importe quelle cellule les formules suivantes (une par cellule) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
=MOIS($A$2)
=MOIS($A$2)=$E2
=ANNEE($A$2)
=ANNEE($A$2)=F$1
=MOYENNE($B$2:$B$4813)

Qu'est-ce que ça renvoie comme valeurs ?

[Doltd]

Pour correspondre correctement j'ai pris la donnée en a3 (24/08/1999) et je l'ai fait correspondre avec la cellule E10(8) et F2(1999)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
=MOIS($A$3)
8
 
=MOIS($A$3)=$E10
VRAI
 
=ANNEE($A$3)
1999
 
=ANNEE($A$3)=F$2
VRAI
 
=MOYENNE($B$3:$B$4814)
25,08...

A coté j'ai réalisé ces essais ci (en matriciel):

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
 
=MOIS($A$3:$A$4814)=$E10
VRAI
 
=ANNEE($A$3:$A$4814)=F$2
VRAI
 
=ET(MOIS($A$3:$A$4814)=$E10;ANNEE($A$3:$A$4814)=F$2)
FAUX

En espérant que ça peut t'aider.
En attendant moi ce que je comprends c'est qu'il trouve pas de date en août ET en 1999 alors qu'il y en a 7 dans mon fichier!

Dorian

[Menhir]

Ca signifierait que c'est le ET() qui n'apprécie pas le passage en matriciel ???
Etonnant mais pas impossible.

Peut-être alors que ceci fonctionnera :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=MOYENNE(SI(MOIS($A$2:$A$4813)=$E2;SI(ANNEE($A$2:$A$4813)=F$1;$B$2:$B$4813;"");""))

[Doltd]

Effectivement cette formule fonctionne.

Tu dois avoir raison a propos de la non-compatibilité du ET().

Un grand merci pour ces réponses rapide et en plus qui fonctionnent

Dorian