Discussion :

[itfashiongirl]

Bonjour,
Dans une macro je pacours la boite mail afin d'enrengistre la pj spécifique d'un mail, or j'ai deux boites de réception une par défaut et une deuxième, or je ne veux pas que ma macro que cherche dans la boite mail par défault mais dans la deuxième. Je souhaitais savoir comment spécifier dans ma macro de ne chercher que dans ma deuxième boite mail, je présice que j'ai deux adresses mails différentes pour ces deux boites de réception. Il ne s'agit pas de sous dossier.

Merci d'avance.

[joe.levrai]

Bonjour,

tout dépend de la façon dont tu accèdes à tes boites mails (via l'objet Store, via l'objet Folder etc...)

peux-tu nous montrer ta procédure actuelle ?

[itfashiongirl]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Sub save_file()
 
Dim MaPj As Attachment, MonChemin As String
 
 Dim MonApp As Outlook.Application
 Dim MonMail As Object
 Dim MonNameSpace As Outlook.Namespace
 Dim MonDossier As Outlook.Folder
 Dim ns As Object
 Dim i As Variant
 
 
 Set MonApp = Outlook.Application
 Set ns = MonApp.GetNamespace("MAPI")
 Set MonDossier = ns.GetDefaultFolder(olFolderInbox).Folders(1)

[joe.levrai]

Alors dans ce cas

Vois tes "boites mails" comme un dossier "Folder" rattaché à ton NameSpace

Par exemple, le premier Dossier rattaché à la boite de réception de la boite mail "NomBoiteMail" peut se récupérer ainsi

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set MonDossier = ns.Folders("NomBoiteMail").Folders("Boîte de réception").Folders(1)

L'inconvénient de travailler avec l'objet Folder, c'est que tu ne peux plus utiliser la méthode GetDefaultFolder pour atteindre la boite de réception, tu es obligée de la cibler en écrivant en dur son nom ... ce qui pourrait poser problème si la langue n'est pas le français

Donc, on travaille sur l'objet Store pour la boite mail, ensuite on peut cibler le dossier de son choix
A noter que tu peux spécifier aussi le nom du dossier à atteindre

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Sub rtetd()
Dim Dossier As Folder, MaBoite As Store
 
'$$$$$$$$$$$$$
' ici tu initialise l'application et ton NameSpace ns
'$$$$$$$$$$$$$
 
Set MaBoite = ns.Stores("NomBoiteMail")
Set Dossier = MaBoite.GetDefaultFolder(olFolderInbox).Folders("NomDuDossier")  'ou Folders(1) pour le premier dossier de l'arborescence
MsgBox Dossier.Name & " " & Dossier.Items.Count
End Sub

Beaucoup de chemins mèneront à Rome, tout dépend de tes besoins, il existe d'autres méthodes encore

[itfashiongirl]

merci beaucoup je vais tester ça

[itfashiongirl]

Bonjour,
j'ai testé ton code, or il ne code ne marche en mettant le non de la boite mail il ne la reconnait pas, dois-je entré l'adresse mail ?

merci d'avance

[joe.levrai]

Le nom de la boite mail à indiquer est celui qui est affiché dans ton client Outlook dans le volet d'exploration
Il me semble (de mémoire) que c'est le .DisplayName de l'objet Store

[itfashiongirl]

Bonjour, il reconnait la boit mail mais ma macro plante après quand je veux parcourir les mails présent dans cette boite:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
Dim MonChemin As String
 Dim MonApp As Outlook.Application
 Dim MonMail As Object
 Dim MonNameSpace As Outlook.Namespace
 Dim MonDossier As Outlook.Folder
 Dim ns As Object
 'Dim MonDossier As Folder
 Dim i As Variant
 Dim ladate As String
 Dim item As Object
 Dim olMail As Outlook.MailItem
 
 
  ladate = Feuil10.Range("A7").Value
 
 Set MonApp = Outlook.Application
 Set ns = MonApp.GetNamespace("MAPI")
 'Set MonDossier = ns.GetDefaultFolder(olFolderInbox).Folders(2)
 Set MonDossier = ns.Folders("Structured Derivatives Funds").Folders("Boîte de réception").Folders(1)
 
'Set MonMail = ActiveExplorer.Selection.item(1)
 ' i = 1
'Set MonMail = ActiveExplorer.Selection.item(i)
 
For Each item In MonDossier.items
 
 'For Each olMail In MonDossier.items
  Debug.Print olMail.Subject
 
 If MonMail.SenderEmailAddress = "Michael.Cima@ipsi.ie" Then
  'ElseIf MonMail.Attachments = "AXA" Then
   If MonMail.Subject = "FW: AXA MPS DPI Trade ladate" Then
     'If MonMail.Body = "MonMail.Body = "*" & "THIS EMAIL MUST BE ACKNOWLEDGED TO $IPSIAMFFundAccounting@ipsi.ie IMMEDIATELY UPON RECEIPT ** Please note there is no trade for DPI 6 Thanks " Then
     MsgBox "mail trouvé"
      'If MonMail.Attachments.Count > 0 Then
 
    ' on prend la première PJ (à adapter !)
    Set MaPj = MonMail.Attachments(1)
 
 
    ' on construit le chemin d'enregistrement
   MonChemin = "L:\PC Fonds Structurés\Fonds CPPI\ITALY\Ordes SR\" & MaPj.Filename
 
    ' on enregistre la PJ
        MaPj.SaveAsFile MonChemin & " AMFDPIUnittrade" & Format(ladate, "ddmmaaaa") & ".xlsm"
 
       End If
 
     Exit For
      Else
End If
 
Next item
 
End Sub

ma macro plante à l'érape du début de ma boucle sur le for each

[joe.levrai]

Bonjour,

sur quelle ligne exactement ? Quel est le message d'erreur ?

tu utilises des variables typées (liaison précoce) et génériques "Object" (liaison tardive). Il est préférable de toujours travailler d'un seul côté de la Force

Tu as également des variables déclarées et non utilisées, et des variables utilisées et non déclarées

Évite de nommer tes variables comme des objets déjà existants (item par exemple)

Ta boucle For Each boucle sur des "item" mais au sein de la boucle du utilises l'objet MonMail ...

Etant donné que je suspecte également des problèmes d'agencement de tes lignes (le Exit For me semble plutôt à mettre avant le premier End If), voici une rédaction à la volée de ce que je pense avoir compris, pour te remettre sur les bons rails

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
Dim MonApp As Object, ns As Object
Dim MonDossier As Object, LesMails As Object
 
Dim ladate As String  ' Normal que ça soit du format Texte et pas du format date ?
Dim MonChemin As String
Dim m As Long
 
ladate = Feuil10.Range("A7").Value
 
' ici on tente de chopper l'instance outlook si elle est ouverte, sinon on la crée
On Error Resume Next: Set MonApp = GetObject(, "Outlook.Application"): On Error GoTo 0
If MonApp Is Nothing Then Set MonApp = CreateObject("Outlook.Application")
 
Set ns = MonApp.GetNamespace("MAPI")
Set MonDossier = ns.Folders("Structured Derivatives Funds").Folders("Boîte de réception").Folders(1)
Set LesMails = MonDossier.Items
    For m = 1 To LesMails.Count
        If LesMails(m).SenderEmailAddress = "Michael.Cima@ipsi.ie" And LesMails(m).Subject = "FW: AXA MPS DPI Trade ladate" Then
            MsgBox "mail trouvé"
            Set MaPj = MonMail.Attachments(1)
            MonChemin = "L:\PC Fonds Structurés\Fonds CPPI\ITALY\Ordes SR\" & MaPj.Filename
            MaPj.SaveAsFile MonChemin & " AMFDPIUnittrade" & Format(ladate, "ddmmaaaa") & ".xlsm"
            Exit For
        End If
    Next m
End Sub

[itfashiongirl]

Merci beaucoup pour ton aide pour le code, par contrez le if ne fonctionne pas il passe du for au end sub, je vais essayer de creuser ç

[itfashiongirl]

Merci beaucoup pour ton aide pour le code, par contrez le if ne fonctionne pas il passe du for au end sub, je vais essayer de creuser ça

[joe.levrai]

Est-ce bien le "premier" dossier en dessous de la boite de réception que tu cibles ? Plutôt que de le chercher via Folders(1), indique son nom à la place du chiffre 1

Ensuite, y a-t-il des mails dans ce dossier ??


Pour voir si tu es sur le bon dossier, ajoute cette ligne entre la ligne 15 et 16

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

MsgBox "Le Dossier est " & MonDossier.Name & " || Nombre de Mails : " & MonDossier.Items.Count

[itfashiongirl]

j'ai deux boites mails, je veux accéder à la deuxièmes dont, j'ai bien indiqué son nom dans le code et je souhaite accéder dossier principale qui se nomme boite de réception

voici ce que ton bou de code me donne le dossier est sss et nombre de mails : 0

[joe.levrai]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set MonDossier = ns.Folders("Structured Derivatives Funds").Folders("Boîte de réception").Folders(1)

Accès au premier dossier Enfant situé dans l'arborescence sous "Boîte de réception" ==> CADRE VERT

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set MonDossier = ns.Folders("Structured Derivatives Funds").Folders("Boîte de réception")

Accès à la Boîte de réception ==> CADRE ROUGE

[itfashiongirl]

J'ai enlever le folders 1 et ça fonctionne désormais merci beaoucoup

[GregCompta]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Sub rtetd()
Dim Dossier As Folder, MaBoite As Store
 
'$$$$$$$$$$$$$
' ici tu initialise l'application et ton NameSpace ns
'$$$$$$$$$$$$$
 
Set MaBoite = ns.Stores("NomBoiteMail")
Set Dossier = MaBoite.GetDefaultFolder(olFolderInbox).Folders("NomDuDossier")  'ou Folders(1) pour le premier dossier de l'arborescence
MsgBox Dossier.Name & " " & Dossier.Items.Count
End Sub

Hello,

Un grand merci pour ton aide !!! Cela m'a permis de conclure une macro sur laquelle j'ai passé bien 2 journées pleines ! ! ! :O

J'ai ajouté ces lignes en les modifiant pour les adapter à mes variables et donc différents comptes et cela marche NICKEL (!) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Dim MaBoite As Store
    Set MaBoite = ns.Stores("Adresse mail de la boite concernée")
    Set olDossier = MaBoite.GetDefaultFolder("NomDuDossier")

1e MODIFICATION :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set MaBoite = ns.Stores("NomBoiteMail")

en :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set MaBoite = olNameSpace.Stores(Compte)

2e MODIFICATION

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set olDossier = MaBoite.GetDefaultFolder("NomDuDossier")

en :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set olDossier = MaBoite.GetDefaultFolder(olFolderInbox)

Du coup, tout est très bien lu ! J'extraits les informations relatives à chacune des PJ incluses dans chacune de mes boites de réception de chacun de mes comptes:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
'Défini la boite qui doit être rafraîchie : 1 seule ou toutes
Sub ImportationPJ()
Dim Ws As Worksheet
Dim Compte As String, WsI As Integer
Compte = ThisWorkbook.ActiveSheet.Name
WsI = ThisWorkbook.ActiveSheet.Index - 1
Select Case Compte
    Case "TdB" 'Si je suis sur la page Tableau de Bord où sont répertoriés mes PJ en fonction de mes besoins
        For Each Ws In ThisWorkbook.Worksheets
            If Ws.Name <> "TdB" Then
                Compte = Ws.Name
                WsI = Ws.Index - 1
                Call Import_Pj(Compte, WsI)
            End If
        Next
    Case Else 'Si je suis sur l'une des feuilles correspondant à une boite en particulier (ex : Feuil(2) = BoiteMail(2)
        Call Import_Pj(Compte, WsI) 'Va chercher les infos et les intègre au tableau spécifique
End Select
End Sub
 
'Macro qui m'extrait les informations PJ selon le compte voulu
Sub Import_Pj(Compte As String, WsI As Integer)
'Importations des PJ d'Outlook et de ses infos mail
Dim olApp As Outlook.Application
    Set olApp = New Outlook.Application
Dim olNameSpace As Outlook.Namespace
    Set olNameSpace = olApp.GetNamespace("MAPI")
Dim olDossier As Outlook.Folder
 
Dim MaBoite As Store 'ici se trouve les 3 lignes 1/3
    Set MaBoite = olNameSpace.Stores(Compte) 'ici se trouve les 3 lignes 2/3
    Set olDossier = MaBoite.GetDefaultFolder(olFolderInbox) 'ici se trouve les 3 lignes 3/3
 
Dim oMail As Object
Dim PieceJointe As Outlook.Attachment
Dim ligne As Long, compteur As Integer
Dim iType As String
Application.ScreenUpdating = False
ligne = 3
With ThisWorkbook.Sheets(Compte)
If .Range("A" & ligne).Value <> "" Then .Range("Tableau" & WsI).Delete
    For Each oMail In olDossier.Items
        iType = TypeName(oMail)
        If iType = "MailItem" Or iType = "MeetingItem" Then
            compteur = 1
            If oMail.Attachments.Count > 0 Then
                For Each PieceJointe In oMail.Attachments
                    .Cells(ligne, 1).Value = oMail.SentOn
                    .Cells(ligne, 2).Value = oMail.SenderEmailAddress
                    .Cells(ligne, 3).Value = oMail.Subject
                    .Cells(ligne, 4).Value = PieceJointe.Filename
                    .Cells(ligne, 5).Value = compteur
                compteur = compteur + 1
                ligne = ligne + 1
                Next
            End If
        End If
    Next
End With
Call Tri(Compte, WsI)
    Set olApp = Nothing
    Set olNameSpace = Nothing
    Set olDossier = Nothing
    Set oMail = Nothing
ThisWorkbook.RefreshAll
Application.ScreenUpdating = True
End Sub
 
'Me permet de trier mes tableaux
Sub Tri(Compte As String, WsI As Integer)
With ActiveWorkbook.Worksheets(Compte).ListObjects("Tableau" & WsI).Sort
    .SortFields.Clear
    .SortFields.Add Key:=Range("Tableau" & WsI & "[[#All],[Date]]"), SortOn:=xlSortOnValues, Order _
        :=xlDescending, DataOption:=xlSortNormal
    .Header = xlYes
    .MatchCase = False
    .Orientation = xlTopToBottom
    .SortMethod = xlPinYin
    .Apply
End With
End Sub

En espérant pouvoir également aider à mon tour !
See you..