Discussion :

[cheblan]

Bonjour,
Je suis désolée si je pose une question à laquelle une réponse a déjà été donnée mais je ne la trouve pas par moi-même.
Mon problème est le suivant :
J'ai deux dossiers sur mon bureau. Le premier, appelons le "SOURCE" contient des photos au format .JPG avec les noms et prénoms des élèves de mon collège, mais les photos sont de mauvaises qualité. L'autre, appelons le "DEST" contient également des photos au format .JPG, les photos sont de bonne qualité, mais les fichiers ont un nom séquentiel dans le même ordre que l'ordre alphabétique, mais qui ne m'indique pas du tout qui est en photo.
Je souhaite renommer les fichiers de DEST en utilisant le nom des fichiers de SOURCE.
Je n'ai jamais programmé un seul Batch de ma vie, mais je programme dans plusieurs langages, donc je pense pouvoir suivre si vous m'expliquez pas trop vite.
Je vous remercie beaucoup des réponses que vous m'apporterez.
Au plaisir de vous lire,
cheblan (#FFFFFF)

[cheblan]

En fait, je continue à chercher dans mon coin en attendant de trouver une soluce, éventuellement avec votre aide.
J'ai imaginé un batch composé de 3 boucles for successives

Première boucle : on remplit un tableau avec tous les noms de fichiers du dossier SOURCE.
Deuxième boucle : on remplit un tableau avec tous les noms de fichiers du dossier DEST.
Troisième boucle : on renomme

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
for /l %%i in (0,1,%taille%) do
(
ren source[i] dest[i]
echo %%i
)

Je suis incapable d'aller plus loin sans votre aide.
Merci de me donner un coup de pouce s'il vous plaît.
cheblan #FFFFFF

[ericlm128]

Voici un exemple basé sur ton raisonnement qui me parait bon.

J'ai un "renome.bat". Au même niveau 2 dossiers "source" et "dest".
Contenu de source :

bleu.jpg
orange.jpg
rouge.jpg
vert.jpg
violet.jpg

Contenu de dest :

1.jpg
2.jpg
3.jpg
4.jpg
5.jpg

Le script renome.bat :

Code batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
@echo off
 
set source=.\source
set dest=.\dest
 
set /A sourcecount=0
set /A destcount=0
 
SETLOCAL ENABLEDELAYEDEXPANSION
 
REM récupère les items de la source
FOR /F "tokens=*" %%a IN ('dir "%source%\*.jpg" /ogne-d /b 2^>nul') DO (
	set /A sourcecount+=1
	set sourceitem[!sourcecount!]=%%~a
)
 
REM récupère les items de la destination
FOR /F "tokens=*" %%a IN ('dir "%dest%\*.jpg" /ogne-d /b 2^>nul') DO (
	set /A destcount+=1
	set destitem[!destcount!]=%%~a
)
 
REM vérifie si il y à le même nombre d'items
if NOT %sourcecount% EQU %destcount% (
	echo Nombre d element different entre source et destination [%sourcecount%, %destcount%]
	pause
	goto :EOF
)
 
REM vérifie si il y a des items à traiter
if %sourcecount% EQU 0 (
	echo Il n y a aucun item a traiter
	pause
	goto :EOF
)
 
REM pour chaque index
FOR /L %%a IN (1, 1, %sourcecount%) DO (
	ren "%dest%\!destitem[%%a]!" "!sourceitem[%%a]!"
)
 
pause

[cheblan]

Ca marche du tonnerre !!!! Bravo et merci beaucoup