Discussion :

[pat1965]

Bonjour,
Je suis à la recherche d'un contrôle me permettant de choisir des plages horaires sur une période de 24h00
J'ai un exemple ci-dessous, mais je n'arrive pas à trouver un équivalent qui me permette de faire cela sous VB.net
Je ne fais sans doute pas mes recherches avec les bons termes.

Dans l'exemple ci-dessous, il me suffit de faire glisser la souris sur la barre pour activer ou désactiver certaines zones.
Dans mon cas je cherche ceci pour mettre les plages horaires où mon chauffage sera actif ou pas.



Quelqu'un pourrait me dire si ce contrôle existe quelque part ou vers quoi je dois m'orienter pour obtenir quelque chose de similaire.

Merci d'avance pour vos réponses

[Pol63]

windows form ? wpf ? uwp ? asp.net ?

si tu ne trouves pas ca doit pouvoir se coder rapidement quand même ...

[pat1965]

windows form ? wpf ? uwp ? asp.net ?

si tu ne trouves pas ca doit pouvoir se coder rapidement quand même ...

Merci,
c'est sur un windows form.
Je me disais que c'était plutôt courant et que je ne devais pas réinventer la roue

[Pol63]

c'est sympa de réinventer des roues, l'avantage c'est que la roue conviendra parfaitement
ca doit prendre quelques dizaines de minutes pour avoir le truc parfait
tu veux quoi en sortie ? une list(of boolean) ou une liste(of intervalle (2xtimespan))

[pat1965]

c'est sympa de réinventer des roues, l'avantage c'est que la roue conviendra parfaitement
ca doit prendre quelques dizaines de minutes pour avoir le truc parfait
tu veux quoi en sortie ? une list(of boolean) ou une liste(of intervalle (2xtimespan))

Oui c'est sympa, mais moi ça me prend beaucoup de temps je ne programme pas assez souvent.
Juste une liste de boolean me suffirait en sortie.

[Pol63]

clic gauche pour mettre en vert et droit pour mettre en gris ? ou autre ?

[pat1965]

clic gauche pour mettre en vert et droit pour mettre en gris ? ou autre ?

Cela a peu d'importance, dans l'exemple que je montre, je clique gauche sur une des cellules, fais glisser la souris jusqu'à une heure désirée et cela inverse la couleur de la sélection des cellules parcourues.
Donc autant le faire avec le clic gauche
Je cherche un truc simple et intuitif.

[Pol63]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
Public Class PlagesHoraires
    Inherits Control
 
 
    Public Sub New()
        For i As Integer = 1 To 24 * 4
            _QuartsDheures.Add(False)
        Next
        Me.DoubleBuffered = True
        Me.MinimumSize = New System.Drawing.Size(730, 34)
        _BrushOn = New SolidBrush(_ColorOn)
        _BrushOff = New SolidBrush(_ColorOff)
    End Sub
 
    Private _rectsQH As New List(Of Rectangle)
 
    Private _BrushOn As SolidBrush
    Private _BrushOff As SolidBrush
    Private _borderPen As New Pen(Color.Black)
    Private _brushHours As New SolidBrush(Color.Black)
 
 
 
    ' properties
 
    Private _QuartsDheures As New List(Of Boolean)
 
    Public ReadOnly Property QuartsDheures As IEnumerable(Of Boolean)
        Get
            Return _QuartsDheures
        End Get
    End Property
 
    Public Property QuartDheureValue(index As Integer) As Boolean
        Get
            Return _QuartsDheures(index)
        End Get
        Set(value As Boolean)
            _QuartsDheures(index) = value
            Me.Invalidate()
        End Set
    End Property
 
 
    Private _ColorOn As Color = Color.Green
    Public Property ColorOn As Color
        Get
            Return _ColorOn
        End Get
        Set(value As Color)
            _ColorOn = value
            _BrushOn = New SolidBrush(value)
            Me.Invalidate()
        End Set
    End Property
 
    Private _ColorOff As Color = Color.DarkGray
    Public Property ColorOff As Color
        Get
            Return _ColorOff
        End Get
        Set(value As Color)
            _ColorOff = value
            _BrushOff = New SolidBrush(value)
            Me.Invalidate()
        End Set
    End Property
 
    Private _TextWidth As Integer = 40
    Public Property TextWidth As Integer
        Get
            Return _TextWidth
        End Get
        Set(value As Integer)
            _TextWidth = value
            RecalcRects()
            Me.Invalidate()
        End Set
    End Property
 
 
 
    ' calc and draw
 
    Protected Overrides Sub OnSizeChanged(e As EventArgs)
        MyBase.OnSizeChanged(e)
 
        RecalcRects()
    End Sub
 
    Private Sub RecalcRects()
        _rectsQH.Clear()
        Dim widthQh = (Me.Width - Me.Margin.Horizontal - Me.TextWidth) \ 24 * 4
        Dim heightRect = Math.Max(widthQh, 16)
 
        For i As Integer = 0 To _QuartsDheures.Count - 1
            Dim b = Me._BrushOff
            If _QuartsDheures(i) Then b = Me._BrushOn
 
            _rectsQH.Add(New System.Drawing.Rectangle(Me.TextWidth + Me.Margin.Left + i * widthQh, Me.Height - heightRect - 1, widthQh, heightRect))
        Next
    End Sub
 
 
 
 
 
    Protected Overrides Sub OnPaintBackground(pevent As PaintEventArgs)
        pevent.Graphics.Clear(Me.BackColor)
    End Sub
 
 
    Protected Overrides Sub OnPaint(e As PaintEventArgs)
 
        If Me.Text <> "" Then
            Using b As New SolidBrush(Me.ForeColor)
                Dim p As New System.Drawing.Point(Me.Margin.Left, _rectsQH(0).Y + 1)
                e.Graphics.DrawString(Me.Text, Me.Font, b, p)
            End Using
        End If
 
 
 
        For i As Integer = 0 To _rectsQH.Count - 1
            Dim b = Me._BrushOff
            If _QuartsDheures(i) Then b = Me._BrushOn
 
            Dim rect = _rectsQH(i)
 
            e.Graphics.FillRectangle(b, rect)
            e.Graphics.DrawRectangle(_borderPen, rect)
            If i / 4 = i \ 4 Then
                e.Graphics.DrawLine(_borderPen, rect.X, rect.Y - 4, rect.X, rect.Y + 4)
            End If
            If i / 12 = i \ 12 Then
                Dim midWidth = 4
                If (i / 4) > 9 Then midWidth = 8
                Dim p As New System.Drawing.Point(rect.X - midWidth, rect.Y - 18)
                e.Graphics.DrawString((i / 4).ToString, Me.Font, _brushHours, p)
            End If
        Next
        Dim p24 As New System.Drawing.Point(_rectsQH.Last.X + _rectsQH.Last.Width - 8, _rectsQH.Last.Y - 18)
        e.Graphics.DrawString("24", Me.Font, _brushHours, p24)
    End Sub
 
 
 
 
    ' change color
 
    Protected Overrides Sub OnMouseDown(e As MouseEventArgs)
        MyBase.OnMouseDown(e)
        GestionClick(e)
    End Sub
 
    Protected Overrides Sub OnMouseMove(e As MouseEventArgs)
        MyBase.OnMouseMove(e)
        GestionClick(e)
    End Sub
 
    Private Sub GestionClick(e As MouseEventArgs)
        Dim newValue As Boolean
        Select Case e.Button
            Case MouseButtons.Left
                newValue = True
            Case MouseButtons.Right
                newValue = False
            Case Else
                Exit Sub
        End Select
 
        For i As Integer = 0 To _QuartsDheures.Count - 1
            If _rectsQH(i).Contains(e.Location) Then
                If _QuartsDheures(i) = newValue Then Continue For
                _QuartsDheures(i) = newValue
                Me.Invalidate()
            End If
        Next
    End Sub
 
End Class

après compilation de cette classe le control apparaitra dans la boite à outils dans "nom_de_ton_projets composants"

une fois posé les propriétés suivantes sont prises en comptes :
ColorOn ColorOff TextWidth Text

par code on peut aussi manipuler les booléens :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
' set
Me.PlagesHoraires1.QuartDheureValue(1) = True
 
' lecture globale
For Each qh In Me.PlagesHoraires1.QuartsDheures
    If qh = True Then
 
    End If
Next

[pat1965]

Pol63, C'est Magnifique,
j'ai du m'absenter deux heures, je viens de rentrer et de tester, c'est exactement ce que je recherchais.
Je vais me plonger dans ce code pour le comprendre à fond (je ne suis pas trop habitué avec les classes).
En tout cas grand merci, je n'en demandais pas autant.
Chapeau bas en si peu de temps !

Un Grand Merciiii !

[Pol63]

pour l'explication :
inherits control c'est de l'héritage
ca veut dire que la classe hérite de tout ce qu'est un control
visual studio a la bonne idée de rajouter tous les controles qu'on fait dans la boite à outils
après un control définit comment il apparait (dessin) dans la méthode onpaint (+ onpaintbackground)
un bouton par exemple fait un drawrectangle et un drawstring en gros

après on rajoute toutes les propriétés et le fonctionnement qu'on a besoin
ici y a le calcul de la taille idéale pour les rectangles, modifiés en cas de redimensionnement du control ; utilisés pour le dessin et pour le hittest (détection de clic)
sur certaines propriétés je fais me.invalidate pour dire que le dessin doit être refait (ca fait que onpaint va être appelé de nouveau)

le mot clé overrides signifie qu'on redéfinit la méthode qui existait dans la classe de base de l'héritage
onresize par exemple est la méthode qui déclenche l'évènement sizechanged, ca m'évite de m'abonner


y a un petit défaut quand même, si on déplace la souris vite, ca peut zapper des cases, si ca t'embête je pourrais corriger pour prendre en compte le point de départ et d'arrivée pour être sûr de balayer toutes les cases entre

[pat1965]

Cerise sur le gâteau, tu donnes les explications.
Un grand merci.
J'avais déjà testé quelques classes mais d'un niveau beaucoup plus simple.
Ton code me fait découvrir pas mal de choses que je ne connaissais pas.
Pour le déplacement trop rapide de la souris ce n'est absolument pas grave. Je l'avais remarqué mais je pensais que ma souris sortait des cases par moment.
Mais pas de soucis, c'est parfait pour moi comme cela.
Tu m'as fait gagner un temps précieux, que je vais "perdre" en analysant le code et en essayant d'évoluer dans la catégorie "dessin" et classes.
La partie dessin n'est pas mon fort et la partie détection de clic va m'en apprendre beaucoup (c'est pas des plus simple les clics quand on entre en profondeur)
En tout cas : rapidité, pédagogie, clarté et efficacité !

Merci

[pat1965]

J'ai fait une toute petite modif.
J'ai créé une fonction pour le calcul de la taille des blocs.
et mis ainsi la petite barre verticale qui manquait à 24h00.
Je pense avoir compris toutes les lignes de code.
compris mais certainement pas capable de transformer la barre en un cercle dans les heures qui suivent (ce qui ne servirait à rien dans ce cas ci) !
C'est très instructif.
Re merci encore.