Discussion :

[orcinus]

bonjour,

je regarde partout mais je ne trouve pas de solution à mon problème.
j'ai une textbox avec une date d'embauche.
dans une autre texbox je souhaiterais calculer la différence en nombre d'année par rapport à la date du jour.
Si quelqu’un a la solution ou peux m'indiquer ou je peux me renseigner.
Merci d'avance

[kiki29]

Salut, formule plus complète que demandé, à adapter au contexte, à voir aussi pour l'histoire de +/- 1 ...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
Option Explicit
 
Function DiffDateAMJ(DateDebut As Date, DateFin As Date) As String
Dim NbAns As Long, NbMois As Long, NbJours As Long
Dim Tmp As Date, sA As String, sM As String, sJ As String
 
    Tmp = DateSerial(Year(DateFin), Month(DateDebut), Day(DateDebut))
    NbAns = Year(DateFin) - Year(DateDebut) + (Tmp > DateFin)
    NbMois = Month(DateFin) - Month(DateDebut) - (12 * (Tmp > DateFin))
    NbJours = Day(DateFin) - Day(DateDebut) + 1    ' [ Date Début, Date Fin ]
    'NbJours = Day(DateFin) - Day(DateDebut)       ' [ Date Début, Date Fin [
 
    If NbJours < 0 Then
        NbMois = NbMois - 1
        NbJours = Day(DateSerial(Year(DateFin), Month(DateFin), 0)) + NbJours
    End If
 
    If NbAns = 0 Then sA = "" Else sA = NbAns & "a "
    If NbMois = 0 Then sM = "" Else sM = NbMois & "m "
    If NbJours = 0 Then sJ = "" Else sJ = NbJours & "j"
 
    DiffDateAMJ = Trim$(sA & sM & sJ)
End Function

[orcinus]

bonjour,
déjà merci pour le temps que vous avez pris pour me répondre.
Je me permet de vous redemander une solution à mon problème.
Ma précédente demande n'était pas correct je pense.
Pour cela je met une capture d'écran de mon useform.
La date d'embauche sera rentrée manuellement, par contre le résultat doit s'afficher dans la texbox : ancienneté.
Le calcul devras être la différence entre (la date d'embauche et aujourd'hui) et le résultat en nombre d'année.
je sais le faire dans un tableau excel mais pas directement dans une userform.
Encore merci pour l'attention portée à ma demande.
Dans l'attente d'une future réponse.
Merci à vous

[kiki29]

Re, à adapter au contexte

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
Option Explicit
 
Private Function DiffDateAMJ(DateDebut As Date, DateFin As Date) As String
Dim NbAns As Long, NbMois As Long, NbJours As Long
Dim Tmp As Date, sA As String, sM As String, sJ As String
 
    Tmp = DateSerial(Year(DateFin), Month(DateDebut), Day(DateDebut))
    NbAns = Year(DateFin) - Year(DateDebut) + (Tmp > DateFin)
    NbMois = Month(DateFin) - Month(DateDebut) - (12 * (Tmp > DateFin))
    NbJours = Day(DateFin) - Day(DateDebut) + 1
 
    If NbJours < 0 Then
        NbMois = NbMois - 1
        NbJours = Day(DateSerial(Year(DateFin), Month(DateFin), 0)) + NbJours
    End If
 
    If NbAns = 0 Then sA = "" Else sA = NbAns & "a "
    If NbMois = 0 Then sM = "" Else sM = NbMois & "m "
    If NbJours = 0 Then sJ = "" Else sJ = NbJours & "j"
 
    DiffDateAMJ = Trim$(sA & sM & sJ)
End Function
 
Private Sub TextBox1_Change()
    If IsDate(TextBox1.Text) Then
        TextBox2.Text = DiffDateAMJ(TextBox1.Text, Date)
    End If
End Sub

[orcinus]

bonjour,
un grand merci pour votre contribution.
Le code fonctionne est j'ai pu l'adapter a ce que j'avais besoin.
Que demander de plus
je ne n'aurais jamais trouver seul je pense, pourtant je cherche.

[kiki29]

Re, beaucoup plus léger, sans fonction externe, si tu ne veux vraiment que l'année. Attention quand même au résultat ...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Private Sub TextBox1_Change()
    If IsDate(TextBox1.Text) Then
         TextBox3.Text = DateDiff("yyyy", TextBox1.Text, Date)
    End If
End Sub

[orcinus]

bonjour,
merci beaucoup.Je vais tester cela.