Discussion :

[Bugmacro]

Bonjour à tous,

Je suis vraiment bloqué par mes connaissances en EXCEL.

Voici mon Exemple :

Dans la colonne A on retrouve les numéros d'emplacement unique où sont stocké des pièces.

Dans la colonne B on a la quantité de pièces réelles dans cet emplacement.

Et enfin dans la colonne C est associé à la colonne A un numéro de transfert.

Ce que je dois faire c'est associé à 1 emplacement avec un seul numéro de transfert.

Comment puis-je faire, à par la rechercheV et supprimer les doublons je ne maitrise pas les formules du type : Index; Equiv ; Decaler?

J'ai réalisé un tableau de départ et ce que j'attends en résultat, si quelqu'un peux m'aider.

Merci beaucoup pour votre aide

[Pierre Fauconnier]

Salut.

C'est toujours le même décalage? Qu'en est-il pour les valeurs au delà de celles illustrées? Ici, tu montres les valeurs reprises 3 fois. C'est toujours ainsi?

Autrement dit, c'est le même mécanisme par groupe de 9 lignes (A2 avec C2, A4 avec C5, A7 avec C9, puis on recommence A10 avec C10, A13 avec C14, A16 avec C18?

[Ben_L]

Bonjour à vous,

Je suppose que votre tableau initial, celui qui contient les doublons, se trouve sur l'onglet "Feuil1", en colonnes A à C, lignes 2 à 10.
Le traitement proposé vous fournira une "copie post-" de ce tableau dans les colonnes E à G.

En cellule E2, utilisez la formule suivante, qui permet de récupérer le contenu de la colonne A en supprimant les doublons :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=INDEX($A:$A;MIN(SI(NB.SI(E$1:E1;$A$2:$A$10)=0;LIGNE($A$2:$A$10);NBVAL(A:A)+1)))&""

Cette formule est à valider en matriciel (avec Ctrl+Shift+Entree) et à étirer jusqu'à la ligne 10 (dans mon exemple).

En cellule G2, on va récupérer le premier n° de transfert valable :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=INDEX($C:$C;MIN(SI(ESTERREUR(EQUIV(C$2:C$10;G$1:G1;0));SI(A$2:A$10=E2;LIGNE(A$2:A$10);NBVAL(C:C)+1);NBVAL(C:C)+1)))&""

toujours à valider en matriciel est à étirer autant que nécessaire.

Enfin, en cellule F2, on peut récupérer la quantité correspondante :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(E2<>"";SOMME.SI.ENS(B$2:B$10;A$2:A$10;E2;C$2:C$10;G2);"")

cette formule n'étant, elle, pas matricielle. A étirer également verticalement.

Voilà, si j'ai bien compris votre besoin, cela devrait y répondre.
Cordialement

[Bugmacro]

Merci pour votre aide.

Voici les réponses à tes questions Pierre :

Ce n'est pas toujours le même décalage.
Les valeurs au delà de celles illustrées peuvent parfois déjà être Ok car elles n'ont pas forcément de doublon.
C'est plus aléatoire que cela du coup.


Pour Ben_L

Je suis toujours un peu embêté.



Ce que tu as fais semble fonctionner mais que pour la première ligne

Je ne sais pas utiliser cette formule on dirait : en E10 j'ai ceci : =INDEX($A:$A;MIN(SI(NB.SI(E$1:E9;$A$2:$A$10)=0;LIGNE($A$2:$A$10);NBVAL(A:A)+1)))&""

[Ben_L]

Voici ce que j'obtiens :

Avez-vous bien validé les formules des colonnes F, G et H par un appui sur 'Ctrl+Shift+Entree' pour obtenir des formules matricielles ?

[Ben_L]

Concernant la formule que vous citez à la fin de votre post, elle devrait apparaître en cellule E10, pas en E9 (si elle est en E9, vous devriez avoir un avertissement de référence circulaire...).

Et pour vérifier que vos formules sont bien matricielles, placez vous sur une cellule (par exemple en E9). Dans la barre de formule, vous devriez voir des accolades autour de la formule de la cellule, comme ci-dessous :

[Bugmacro]

Ben_L

Cela a super bien fonctionné pour la colonne E (je n'avais pas bien fait le CTRL SHIFT ENTRER car les accolades n'apparaissait pas)

Par contre la formule en G2 je ne retrouve pas comme l'exemple.



Merci

[Ben_L]

Très étrange... j'ai pourtant la même formule que vous.
Quelle formule avez-vous en G3 ?
Personnellement, ça me donne ça :

[Bugmacro]

Ca semble être différent en effet. Par contre je ne sais pas le corriger car je ne comprend pas tout ce qui est fait.

[Ben_L]

Vous montrez la formule en G4, celle que j'ai donnée est en G3.
L'écart vient uniquement de là. Nous avons la même formule... et des résultats différents !

Je suis sur Excel 2010. Et vous ?

Sinon, qu'obtenez si vous tapez la formule suivante en H3 :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=EQUIV(C3;G$2;0)

Cela devrait retourner une erreur #N/A.

[Bugmacro]

A oui c'est nulle ça.

J'ai bien le #N/A et je suis sous Excel 2010

[Bugmacro]

Voici mon fichier avec une nouvelle feuille comprenant tout le tableau de données.

J'aimerais pouvoir réussir cela moi même. Comment comprendre les différentes formules imbriqués que tu as utilisés ?

[Ben_L]

Je vais avoir du mal à répondre de façon réactive, j'ai un problème à traiter au boulot et ça prend malheureusement la priorité...

Ce que je peux dire, c'est que l'écart semble être dû au fait que les valeurs que vous utilisez en colonne C sont numériques, alors que j'ai pris dans mon exemple des valeurs texte.
J'ai essayé de prendre des valeurs numériques et j'ai le même problème que vous, même en passant le format des cellules en format texte.

Je n'ai pour l'instant pas le temps de vous fournir des explications détaillées sur la logique utilisée dans les formules.
Si vous êtes pressés, n'hésitez pas à solliciter d'autres contributeurs du forum.
Sinon, je dois pouvoir vous répondre dans le week-end.

Cordialement

[Bugmacro]

Je comprend, il n'y a pas de problème je peux attendre.

Merci encore.

Je vous ai transmis le fichier pour faire les tests si pouvez regarder

Merci encore pour tout

[Ben_L]

Problèmes réglés ! (le votre comme le mien )

Pour la formule en colonne G, il est possible d'utiliser :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(E2="";"";INDEX($C:$C;MIN(SI(ESTERREUR(EQUIV(C$2:C$10;G$1:G1;0));SI(A$2:A$10=E2;LIGNE(A$2:A$10))))))

(formule pour la cellule G2, à valider en matriciel et à étirer jusqu'en G10)

Concernant les explications, quelle pratique avez-vous des formules matricielles dans Excel ?
Le plus important est de comprendre comment Excel gère ce type de formule. Pour cela, je vous invite à rechercher sur internet des explications/tutoriels.
Une fois cela fait, n'hésitez pas à revenir vers moi pour que nous échangions plus particulièrement sur les formules que j'ai proposées ici.