Discussion :

[hizoka]

Bonjour,

je suis dans la dernière ligne droite de mon fichier, mais je suis devant des difficultés qui sont au dessus de mes capacités...

Je fais un truc vraiment crados et loin d'être fiable...

Je vous explique via un exemple :

Date	Valeur
01/08/17	A
01/08/17	B
04/08/2017	C
06/08/2017	D
08/08/2017	E
10/08/2017	F
14/08/2017	G
17/08/2017	H
20/08/2017	I

Il faut que je récupère les valeurs de la date la plus ancienne ainsi que dans les 4 jours qui suivent, donc :

Date	Valeur
01/08/17	A
01/08/17	B
04/08/2017	C

Puis les valeurs pour la date suivant la plus petite + 4 jours, suivie de 4 jours :

Date	Valeur
06/08/2017	D
08/08/2017	E
10/08/2017	F

Et si possible la même chose encore une fois, donc :

Date	Valeur
14/08/2017	G
17/08/2017	H

Cela me semble vraiment compliqué...
Si quelqu'un en est capable et à la bonté de m'aider, je le remercie beaucoup !

Perso je passe par un système qui par de la 1ere date puis sur X lignes suivante, je regarde si la date est inférieure à la 1ere date + 4j.
Puis je refais la même chose mais en partant de la 2e ligne,
puis en partant de la 3e ligne...
Ce qui fait des tonnes de lignes et de conditions, c'est franchement compliqué de s'y retrouver...

Merci à vous.

[Philippe Tulliez]

Bonjour,
La solution vraisemblablement à l'aide du filtre avancé d'excel.

A lire Les filtres avancés ou élaborés dans Excel

[hizoka]

Le truc c'est qu'il faut que ça soit automatique car je refais d'autres commandes en fonction des résultats.

Et le fichier est à destination de personnes ne maîtrisant pas du tout excel.

Il me faut donc une formule.

[papouclo]

Bonjour,
Une proposition par formule.



Les plages A2:A10 et B2:B10 sont respectivement appelées dates et valeurs.
La formule en D2 est :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(LIGNE()-1<=NB.SI.ENS(dates;">="&PETITE.VALEUR(dates;NB($C:C)+1);dates;"<="&PETITE.VALEUR(dates;NB($C:C)+1)+4);PETITE.VALEUR(dates;NB($C:C)+LIGNE()-1);"")

Celle en E2 est :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SIERREUR(INDEX(valeurs;EQUIV(D2;dates;0)+NB.SI(D$1:D1;D2));"")

Ces deux formules sont à recopier sur toute la plage D2:E5 et sur les plages G2:H5 , J2:K5 , M2:N5 et P2:Q5.
Cordialement
Claude

[hizoka]

Merci pour la proposition

Mais j'obtiens un #Valeur ! en D2.

et je ne comprends pas d'où vient le $C.

[papouclo]

Re,
Je joins le fichier réalisé pour effectuer des copies d'écran. Sur ce fichier, la formule renvoie une valeur numérique en D2 et cela permettra de faire la comparaison entre les formules écrites.
Nb($C:C) est égal à 0 puisqu'il n'y a aucun nombre écrit dans la colonne C, mais cette astuce permet d'utiliser une seule formule à recopier sur toutes les plages.
En effet, en G2, avec l'incrémentation des références, on aura NB($C;F) , ce qui permettra de compter les nombres de la colonne D, donc les trois dates déjà écrites et de chercher ainsi la quatrième plus petite date du tableau source.
Cordialement
Claude

[hizoka]

Merci, je ne sais pas pourquoi ça ne fonctionnait pas...

Par contre je voudrais ajouter une colonne avec un tarif à droite des valeurs et ça gène dés que je rentre des chiffres.
En effet, les tableaux affichent moins de résultats.

Alors j'arrive à contourner le problème en reprenant ces valeurs dans un autre tableau dans le quel j'ajoute mes tarifs mais bon, je suis sûr qu'il serait possible de l'ajouter :p

En tout cas, merci beaucoup pour ce code actuel !

[papouclo]

Bonjour,
S'il s'agit de ne rajouter qu'une colonne tarif au seul tableau source (colonne C), il suffit de sélectionner la colonne C et de demander l'insertion d'une colonne. Les formules en E2 (ex D2) et F2(ex E2) se modifient d'elles-mêmes.
Si l'on rajoute une colonne tarif à chaque tableau partiel, il faut décider d'un autre moyen de décompter les dates déjà utilisées ( car l'emploi de la fonction NB supposait que les seuls nombres écrits dans la plage D: Q étaient des dates ).
Dans le classeur joint, pour tenir compte de l'ajout de tarifs, la formule en E2 a été modifiée en :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(LIGNE()-1<=NB.SI.ENS(dates;">="&PETITE.VALEUR(dates;NB.SI($D:D;">="&MIN(dates))+1);dates;"<="&PETITE.VALEUR(dates;NB.SI($D:D;">="&MIN(dates))+1)+4) ; PETITE.VALEUR(dates;NB.SI($D:D;">="&MIN(dates))+LIGNE()-1);"")

Mais j'ai supposé que tous les tarifs étaient inférieurs au numéro de série correspondant à la plus petite des dates écrites en colonne A.
Cordialement
Claude

[hizoka]

C'est génial !

Merci énormément !!